mudsync/player.scm

   1 ;;; Mudsync --- Live hackable MUD
   2 ;;; Copyright © 2016 Christopher Allan Webber <cwebber@dustycloud.org>
   3 ;;;
   4 ;;; This file is part of Mudsync.
   5 ;;;
   6 ;;; Mudsync is free software; you can redistribute it and/or modify it
   7 ;;; under the terms of the GNU General Public License as published by
   8 ;;; the Free Software Foundation; either version 3 of the License, or
   9 ;;; (at your option) any later version.
  10 ;;;
  11 ;;; Mudsync is distributed in the hope that it will be useful, but
  12 ;;; WITHOUT ANY WARRANTY; without even the implied warranty of
  13 ;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  14 ;;; General Public License for more details.
  15 ;;;
  16 ;;; You should have received a copy of the GNU General Public License
  17 ;;; along with Mudsync.  If not, see <http://www.gnu.org/licenses/>.
  18
  19 (define-module (mudsync player)
  20   #:use-module (mudsync command)
  21   #:use-module (mudsync gameobj)
  22   #:use-module (mudsync game-master)
  23   #:use-module (mudsync parser)
  24   #:use-module (8sync systems actors)
  25   #:use-module (8sync agenda)
  26   #:use-module (ice-9 control)
  27   #:use-module (ice-9 format)
  28   #:use-module (ice-9 match)
  29   #:use-module (oop goops)
  30   #:use-module (srfi srfi-1)
  31   #:use-module (srfi srfi-9)
  32   #:export (<player>
  33             player-self-commands))
  34
  35 ;;; Players
  36 ;;; =======
  37
  38 (define player-actions
  39   (build-actions
  40    (init (wrap-apply player-init))
  41    (handle-input (wrap-apply player-handle-input))
  42    (tell (wrap-apply player-tell))))
  43
  44 (define player-actions*
  45   (append player-actions
  46           gameobj-actions))
  47
  48 (define player-dispatcher
  49   (simple-dispatcher player-actions*))
  50
  51 (define-class <player> (<gameobj>)
  52   (username #:init-keyword #:username
  53             #:accessor player-username)
  54   ;; Connection id
  55   (client #:accessor player-client)
  56
  57   (self-commands
  58    #:init-value '()
  59    #:accessor player-self-commands)
  60
  61   (message-handler
  62    #:init-value
  63    ;; @@: We're gonna need action inheritance real awful soon, huh?
  64    (wrap-apply player-dispatcher)))
  65
  66
  67 ;;; player message handlers
  68
  69 (define-mhandler (player-init player message)
  70   ;; Look around the room we're in
  71   (<- player (gameobj-loc player) 'look-room))
  72
  73
  74 (define-mhandler (player-handle-input player message input)
  75   (define split-input (split-verb-and-rest input))
  76   (define input-verb (pk 'input-verb (car split-input)))
  77   (define input-rest (pk 'input-rest (cdr split-input)))
  78
  79   (define command-candidates
  80     (pk 'candidates
  81         (player-gather-command-handlers player input-verb)))
  82
  83   (define winner
  84     (pk 'winner (find-command-winner command-candidates input-rest)))
  85
  86   (match winner
  87     ((cmd-action winner-id message-args)
  88      (apply send-message player (pk 'winner-id winner-id) (pk 'cmd-action cmd-action) (pk 'message-args message-args)))
  89     (#f
  90      (<- player (gameobj-gm player) 'write-home
  91          #:text "Huh?\n"))))
  92
  93 (define-mhandler (player-tell player message text)
  94   (<- player (gameobj-gm player) 'write-home
  95       #:text text))
  96
  97
  98 ;;; Command handling
  99 ;;; ================
 100
 101 ;; @@: Hard to know whether this should be in player.scm or here...
 102 ;; @@: This could be more efficient as a stream...!?
 103 (define (player-gather-command-handlers player verb)
 104   (define player-loc
 105     (let ((result (gameobj-loc player)))
 106       (if result
 107           result
 108           (throw 'player-has-no-location
 109                  "Player ~a has no location!  How'd that happen?\n"
 110                  #:player-id (actor-id player)))))
 111
 112   ;; Ask the room for its commands
 113   (define room-commands
 114     ;; TODO: Map room id and sort
 115     (message-ref
 116      (<-wait player player-loc
 117              'get-container-commands
 118              #:verb verb)
 119      'commands))
 120
 121   ;; All the co-occupants of the room (not including ourself)
 122   (define co-occupants
 123     (remove
 124      (lambda (x) (equal? x (actor-id player)))
 125      (message-ref
 126       (<-wait player player-loc 'get-occupants)
 127       'occupants)))
 128
 129   ;; @@: There's a race condition here if someone leaves the room
 130   ;;   during this, heh...
 131   ;;   I'm not sure it can be solved, but "lag" on the race can be
 132   ;;   reduced maybe?
 133
 134   ;; Get all the co-occupants' commands
 135   (define co-occupant-commands
 136     ;; TODO: Switch this to a fold.  Ignore a result if it
 137     ;;   returns false for in the command response
 138     (fold
 139      (lambda (co-occupant prev)
 140        (display "pre-message\n")
 141        (let* ((result (<-wait player co-occupant 'get-commands
 142                               #:verb verb))
 143               (commands (message-ref result 'commands))
 144               (goes-by (message-ref result 'goes-by)))
 145          (display "post-message\n")
 146          (append
 147           (map (lambda (command)
 148                  (list command goes-by co-occupant))
 149                commands)
 150           prev)))
 151      '()
 152      co-occupants))
 153
 154   ;; Append our own command handlers
 155   (define our-commands
 156     (player-self-commands player))
 157
 158   ;; TODO: Append our inventory's relevant command handlers
 159
 160   ;; Now return a big ol sorted list of ((actor-id . command))
 161   (append
 162    (sort-commands-append-actor (pk 'room-commands room-commands)
 163                                player-loc '()) ; room doesn't go by anything
 164    (sort-commands-multi-actors co-occupant-commands)
 165    (sort-commands-append-actor our-commands
 166                                (actor-id player) '()))) ; nor does player
 167
 168 (define (sort-commands-append-actor commands actor-id goes-by)
 169   (sort-commands-multi-actors
 170    (map (lambda (command) (list command goes-by actor-id)) commands)))
 171
 172 (define (sort-commands-multi-actors actors-and-commands)
 173   (sort
 174    actors-and-commands
 175    (lambda (x y)
 176      (pk 'x x)
 177      (pk 'y y)
 178      (> (command-priority (car x))
 179         (command-priority (car y))))))
 180
 181
 182 (define (find-command-winner sorted-candidates line)
 183   "Find a command winner from a sorted list of candidates"
 184   ;; A cache of results from matchers we've already seen
 185   ;; TODO: fill this in
 186   (define matcher-cache '())
 187   (call/ec
 188    (lambda (return)
 189      (for-each
 190       (match-lambda
 191         ((command actor-goes-by actor-id)
 192          (let* ((matcher (command-matcher command))
 193                 (matched (matcher line)))
 194            (if (and matched
 195                     ;; Great, it matched, but does it also pass
 196                     ;; should-handle?
 197                     (apply (command-should-handle command)
 198                            actor-goes-by
 199                            matched))  ; matched is kwargs if truthy
 200                (return (list (command-action command)
 201                              (pk 'earlier-actor-id actor-id) matched))
 202                #f))))
 203       sorted-candidates)
 204      #f)))