mudsync/gameobj.scm

   1 ;;; Mudsync --- Live hackable MUD
   2 ;;; Copyright © 2016 Christopher Allan Webber <cwebber@dustycloud.org>
   3 ;;;
   4 ;;; This file is part of Mudsync.
   5 ;;;
   6 ;;; Mudsync is free software; you can redistribute it and/or modify it
   7 ;;; under the terms of the GNU General Public License as published by
   8 ;;; the Free Software Foundation; either version 3 of the License, or
   9 ;;; (at your option) any later version.
  10 ;;;
  11 ;;; Mudsync is distributed in the hope that it will be useful, but
  12 ;;; WITHOUT ANY WARRANTY; without even the implied warranty of
  13 ;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  14 ;;; General Public License for more details.
  15 ;;;
  16 ;;; You should have received a copy of the GNU General Public License
  17 ;;; along with Mudsync.  If not, see <http://www.gnu.org/licenses/>.
  18
  19 ;;; Game actor
  20 ;;; ==========
  21
  22 (define-module (mudsync gameobj)
  23   #:use-module (mudsync command)
  24   #:use-module (8sync systems actors)
  25   #:use-module (8sync agenda)
  26   #:use-module (srfi srfi-1)
  27   #:use-module (ice-9 match)
  28   #:use-module (oop goops)
  29   #:export (<gameobj>
  30             gameobj-simple-name-f
  31
  32             gameobj-loc
  33             gameobj-gm
  34             gameobj-name
  35             gameobj-name-f
  36
  37             gameobj-actions))
  38
  39 ;;; Gameobj
  40 ;;; =======
  41
  42
  43 ;;; Actions supported by all gameobj
  44 (define gameobj-actions
  45   (build-actions
  46    (init (wrap-apply gameobj-init))
  47    (get-commands (wrap-apply gameobj-get-commands))
  48    (get-container-commands (wrap-apply gameobj-get-container-commands))
  49    (get-occupants (wrap-apply gameobj-get-occupants))
  50    (add-occupant! (wrap-apply gameobj-add-occupant!))
  51    (remove-occupant! (wrap-apply gameobj-remove-occupant!))
  52    (set-loc! (wrap-apply gameobj-set-loc!))
  53    (get-name (wrap-apply gameobj-get-name))
  54    (get-desc (wrap-apply gameobj-get-desc))
  55    (goes-by (wrap-apply gameobj-act-goes-by))
  56    (visible-name (wrap-apply gameobj-visible-name))))
  57
  58 ;;; *all* game components that talk to players should somehow
  59 ;;; derive from this class.
  60 ;;; And all of them need a GM!
  61
  62 (define-class <gameobj> (<actor>)
  63   ;; location id
  64   (loc #:init-value #f
  65        #:getter gameobj-loc)
  66
  67   ;; Uses a hash table like a set (values ignored)
  68   (occupants #:init-thunk make-hash-table
  69              #:getter gameobj-occupants)
  70
  71   ;; game master id
  72   (gm #:init-keyword #:gm
  73       #:getter gameobj-gm)
  74   ;; a name to be known by
  75   (name #:init-keyword #:name
  76         #:init-value #f)
  77   (goes-by #:init-keyword #:goes-by
  78            #:init-value #f)
  79
  80   (desc #:init-value #f
  81         #:init-keyword #:desc)
  82
  83   ;; how to print our name
  84   (name-f #:init-keyword #:name-f
  85           #:getter gameobj-name-f
  86           #:init-value (wrap gameobj-simple-name-f))
  87
  88   ;; Commands we can handle
  89   (commands #:init-value '())
  90
  91   ;; Commands we can handle by being something's container
  92   (container-commands #:init-value '())
  93   (message-handler
  94    #:init-value
  95    (simple-dispatcher gameobj-actions))
  96
  97   ;; Most objects are generally visible by default
  98   (generally-visible #:init-value #t)
  99   ;; @@: Would be preferable to be using generic methods for this...
 100   ;;   Hopefully we can port this to Guile 2.2 soon...
 101   (visible-to-player?
 102    #:init-value (wrap-apply gameobj-visible-to-player?)))
 103
 104
 105 ;;; gameobj message handlers
 106 ;;; ========================
 107
 108 ;; Kind of a useful utility, maybe?
 109 (define (simple-slot-getter slot)
 110   (lambda (actor message)
 111     (reply-message actor message
 112                    #:val (slot-ref actor slot))))
 113
 114
 115 ;; @@: This could be kind of a messy way of doing gameobj-init
 116 ;;   stuff.  If only we had generic methods :(
 117 (define-mhandler (gameobj-init actor message)
 118   "Your most basic game object init procedure.  Does nothing."
 119   #f)
 120
 121 (define (gameobj-goes-by gameobj)
 122   "Find the name we go by.  Defaults to #:name if nothing else provided."
 123   (cond ((slot-ref gameobj 'goes-by) =>
 124          identity)
 125         ((slot-ref gameobj 'name) =>
 126          (lambda (name)
 127            (list name)))
 128         (else '())))
 129
 130 (define (gameobj-act-goes-by actor message)
 131   "Reply to a message requesting what we go by."
 132   (<-reply actor message
 133            #:goes-by (gameobj-goes-by actor)))
 134
 135 (define (val-or-run val-or-proc)
 136   "Evaluate if a procedure, or just return otherwise"
 137   (if (procedure? val-or-proc)
 138       (val-or-proc)
 139       val-or-proc))
 140
 141 (define (filter-commands commands verb)
 142   (filter
 143    (lambda (cmd)
 144      (equal? (command-verbs cmd)
 145              verb))
 146    commands))
 147
 148 (define-mhandler (gameobj-get-commands actor message verb)
 149   "Get commands a co-occupant of the room might execute for VERB"
 150   (define filtered-commands
 151     (filter-commands (val-or-run (slot-ref actor 'commands))
 152                      verb))
 153   (<-reply actor message
 154            #:commands filtered-commands
 155            #:goes-by (gameobj-goes-by actor)))
 156
 157 (define-mhandler (gameobj-get-container-commands actor message verb)
 158   "Get commands as the container / room of message's sender"
 159   (define filtered-commands
 160     (filter-commands (val-or-run (slot-ref actor 'container-commands))
 161                      verb))
 162   (<-reply actor message #:commands filtered-commands))
 163
 164 (define-mhandler (gameobj-add-occupant! actor message who)
 165   "Add an actor to our list of present occupants"
 166   (hash-set! (slot-ref actor 'occupants)
 167              who #t))
 168
 169 (define-mhandler (gameobj-remove-occupant! actor message who)
 170   "Remove an occupant from the room."
 171   (hash-remove! (slot-ref actor 'occupants) who))
 172
 173 (define-mhandler (gameobj-get-occupants actor message)
 174   "Get all present occupants of the room."
 175   (define occupants
 176     (hash-map->list (lambda (key val) key)
 177                     (gameobj-occupants actor)))
 178
 179   (<-reply actor message
 180            #:occupants occupants))
 181
 182 ;; @@: Should it really be #:id ?  Maybe #:loc-id or #:loc?
 183 (define-mhandler (gameobj-set-loc! actor message loc)
 184   "Set the location of this object."
 185   (define old-loc (gameobj-loc actor))
 186   (format #t "DEBUG: Location set to ~s for ~s\n"
 187           loc (actor-id-actor actor))
 188
 189   (slot-set! actor 'loc loc)
 190   ;; Change registation of where we currently are
 191   (if loc
 192       (<-wait actor loc 'add-occupant! #:who (actor-id actor)))
 193   (if old-loc
 194       (<-wait actor old-loc 'remove-occupant! #:who (actor-id actor))))
 195
 196 (define gameobj-get-name (simple-slot-getter 'name))
 197 (define gameobj-get-desc (simple-slot-getter 'desc))
 198
 199 (define (gameobj-simple-name-f gameobj)
 200   "Simplest version: return ourselves for our name."
 201   (gameobj-name gameobj))
 202
 203 (define (gameobj-visible-to-player? gameobj whos-looking)
 204   "Check to see whether we're visible to the player or not.
 205 By default, this is whether or not the generally-visible flag is set."
 206   (slot-ref gameobj 'generally-visible))
 207
 208 (define-mhandler (gameobj-visible-name actor message whos-looking)
 209   ;; Are we visible?
 210   (define we-are-visible
 211     ((slot-ref actor 'visible-to-player?) actor whos-looking))
 212
 213   (define name-to-return
 214     (if we-are-visible
 215         ;; Return our name
 216         (match (slot-ref actor 'name)
 217           ((? procedure? name-proc)
 218            (name-proc actor whos-looking))
 219           ((? string? name)
 220            name)
 221           (#f #f))
 222         #f))
 223   (<-reply actor message #:text name-to-return))