MPFR v4.0.2
[mpfr.git] / configure.ac
1 dnl Process this file with autoconf to produce a configure script.
2
3 dnl WARNING! C code starting with # (preprocessor directives) must not
4 dnl be indented!
5
6 AC_COPYRIGHT([
7 Copyright 1999-2019 Free Software Foundation, Inc.
8 Contributed by the AriC and Caramba projects, INRIA.
9
10 This file is part of the GNU MPFR Library.
11
12 The GNU MPFR Library is free software; you can redistribute it and/or modify
13 it under the terms of the GNU Lesser General Public License as published
14 by the Free Software Foundation; either version 3 of the License, or (at
15 your option) any later version.
16
17 The GNU MPFR Library is distributed in the hope that it will be useful, but
18 WITHOUT ANY WARRANTY; without even the implied warranty of MERCHANTABILITY
19 or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU Lesser General Public
20 License for more details.
21
22 You should have received a copy of the GNU Lesser General Public License
23 along with the GNU MPFR Library; see the file COPYING.LESSER.  If not, see
24 https://www.gnu.org/licenses/ or write to the Free Software Foundation, Inc.,
25 51 Franklin St, Fifth Floor, Boston, MA 02110-1301, USA.
26 ])
27
28 dnl Add check-news when it checks for more than 15 lines
29 AC_INIT([MPFR],[4.0.2])
30
31 dnl Older Automake versions than 1.13 may still be supported, but no longer
32 dnl tested, and many things have changed in 1.13. Moreover the INSTALL file
33 dnl and MPFR manual assume that MPFR has been built using Automake 1.13+
34 dnl (due to parallel tests, introduced by default in Automake 1.13).
35 AM_INIT_AUTOMAKE([1.13 no-define dist-bzip2 dist-xz dist-zip])
36 AM_MAINTAINER_MODE(enable)
37
38 AC_CONFIG_MACRO_DIR([m4])
39
40 dnl FIXME: Several AC_RUN_IFELSE programs can return several values
41 dnl (one for each format to be detected), but the Autoconf manual says:
42 dnl "This exit status might be that of a failed compilation, or it might
43 dnl be that of a failed program execution." Unfortunately, we cannot
44 dnl know whether a non-zero exit status comes from a failed compilation,
45 dnl so that the detection may be incorrect. To avoid this problem, write
46 dnl a test program for each possible format? Alternatively, the test
47 dnl program could output the result of the format detection to a file
48 dnl and return with the 0 exit status if it could do that successfully.
49
50 test_CFLAGS=${CFLAGS+set}
51
52 dnl Check if user request its CC and CFLAGS
53 if test -n "$CFLAGS" || test -n "$CC" ; then
54  user_redefine_cc=yes
55 fi
56
57 dnl Basic Autoconf macros. At this point, they must not make Autoconf
58 dnl choose a compiler because of the CC and CFLAGS setup from gmp.h!
59
60 AC_CANONICAL_HOST
61
62 AC_PROG_EGREP
63 AC_PROG_SED
64
65 dnl To use a separate config header.
66 dnl There is still some problem with GMP's HAVE_CONFIG
67 dnl AC_CONFIG_HEADERS([mpfrconf.h:mpfrconf.in])
68
69 dnl Extra arguments to configure
70
71 unset gmp_lib_path GMP_CFLAGS GMP_CC
72
73 AC_ARG_WITH(gmp_include,
74    [  --with-gmp-include=DIR  GMP include directory ],
75    MPFR_PARSE_DIRECTORY(["$withval"],[withval])
76    CPPFLAGS="$CPPFLAGS -I$withval")
77
78 AC_ARG_WITH(gmp_lib,
79    [  --with-gmp-lib=DIR      GMP lib directory ], [
80    MPFR_PARSE_DIRECTORY(["$withval"],[withval])
81    LDFLAGS="$LDFLAGS -L$withval"
82    gmp_lib_path="$withval"
83   ])
84
85 AC_ARG_WITH(gmp,
86    [  --with-gmp=DIR          GMP install directory ], [
87    MPFR_PARSE_DIRECTORY(["$withval"],[withval])
88    if test -z "$with_gmp_lib" && test -z "$with_gmp_include" ; then
89       CPPFLAGS="$CPPFLAGS -I$withval/include"
90       LDFLAGS="$LDFLAGS -L$withval/lib"
91       gmp_lib_path="$withval/lib"
92    else
93       AC_MSG_FAILURE([Do not use --with-gmp and --with-gmp-include/--with-gmp-lib options simultaneously.])
94    fi
95   ])
96
97 AC_ARG_WITH(gmp_build,
98    [  --with-gmp-build=DIR    GMP build directory (please read INSTALL file)],
99    [
100    MPFR_PARSE_DIRECTORY(["$withval"],[withval])
101    if test -z "$gmp_lib_path" && test -z "$with_gmp_include" ; then
102       CPPFLAGS="$CPPFLAGS -I$withval -I$withval/tune"
103       LDFLAGS="$LDFLAGS -L$withval -L$withval/.libs -L$withval/tune"
104       gmp_lib_path="$withval$PATH_SEPARATOR$withval/.libs$PATH_SEPARATOR$withval/tune"
105       if test -r $withval/Makefile ; then
106          GMP_CFLAGS=`$SED -n 's/^CFLAGS = //p' $withval/Makefile`
107          GMP_CC=`$SED -n 's/^CC = //p' $withval/Makefile`
108          GMP_SOURCE=`$SED -n 's/^srcdir = *//p' $withval/Makefile`
109          case "$GMP_SOURCE" in
110            .)  GMP_SOURCE="" ;;
111            /*) ;;
112            ?*) GMP_SOURCE="$withval/$GMP_SOURCE" ;;
113          esac
114          if test -d "$GMP_SOURCE" ; then
115             CPPFLAGS="$CPPFLAGS -I$GMP_SOURCE -I$GMP_SOURCE/tune"
116          fi
117       fi
118       use_gmp_build=yes
119    else
120       AC_MSG_FAILURE([Do not use --with-gmp-build and other --with-gmp options simultaneously.])
121    fi
122    ])
123
124 AC_ARG_WITH(mulhigh_size,
125    [  --with-mulhigh-size=NUM internal threshold table for mulhigh],
126    AC_DEFINE_UNQUOTED([MPFR_MULHIGH_SIZE],$withval, [Mulhigh size]))
127
128 AC_ARG_ENABLE(gmp-internals,
129    [  --enable-gmp-internals  enable use of GMP undocumented functions [[default=no]]],
130    [ case $enableval in
131       yes) AC_DEFINE([WANT_GMP_INTERNALS],1,[Want GMP internals]) ;;
132       no)  ;;
133       *) AC_MSG_ERROR([bad value for --enable-gmp-internals: yes or no]) ;;
134      esac])
135
136 AC_ARG_ENABLE(assert,
137    [  --enable-assert         enable ASSERT checking [[default=no]]],
138    [ case $enableval in
139       yes) AC_DEFINE([MPFR_WANT_ASSERT],1,[Want all simple assertions]) ;;
140       none) AC_DEFINE([MPFR_WANT_ASSERT],-1,[Do no want any assertion]) ;;
141       no)  ;;
142       full) AC_DEFINE([MPFR_WANT_ASSERT],2,[Want full assertions]) ;;
143       *) AC_MSG_ERROR([bad value for --enable-assert: yes, no, none or full]) ;;
144      esac])
145
146 AC_ARG_ENABLE(logging,
147    [  --enable-logging        enable MPFR logging (the system must support it)
148                           [[default=no]]],
149    [ case $enableval in
150       yes) AC_DEFINE([MPFR_USE_LOGGING],1,[Enable MPFR logging support]) ;;
151       no)  ;;
152       *)   AC_MSG_ERROR([bad value for --enable-logging: yes or no]) ;;
153      esac])
154
155 AC_ARG_ENABLE(thread-safe,
156    [  --disable-thread-safe   explicitly disable TLS support
157   --enable-thread-safe    build MPFR as thread safe, i.e. with TLS support
158                           (the system must support it) [[default=autodetect]]],
159    [ case $enableval in
160       yes) ;;
161       no)  ;;
162       *)   AC_MSG_ERROR([bad value for --enable-thread-safe: yes or no]) ;;
163      esac])
164
165 AC_ARG_ENABLE(shared-cache,
166    [  --enable-shared-cache   enable use of caches shared by all threads,
167                           for all MPFR constants.  It usually makes MPFR
168                           dependent on PTHREAD [[default=no]]],
169    [ case $enableval in
170       yes)
171          AC_DEFINE([MPFR_WANT_SHARED_CACHE],1,[Want shared cache]) ;;
172       no)  ;;
173       *) AC_MSG_ERROR([bad value for --enable-shared-cache: yes or no]) ;;
174      esac])
175
176 AC_ARG_ENABLE(warnings,
177    [  --enable-warnings       allow MPFR to output warnings to stderr [[default=no]]],
178    [ case $enableval in
179       yes) AC_DEFINE([MPFR_USE_WARNINGS],1,[Allow MPFR to output warnings to stderr]) ;;
180       no)  ;;
181       *)   AC_MSG_ERROR([bad value for --enable-warnings: yes or no]) ;;
182      esac])
183
184 AC_ARG_ENABLE(tests-timeout,
185    [  --enable-tests-timeout=NUM
186                           [[for developers]] enable timeout for test programs
187                           (NUM seconds, <= 9999) [[default=no]]; if this is
188                           enabled, the environment variable $MPFR_TESTS_TIMEOUT
189                           overrides NUM (0: no timeout)],
190    [ case $enableval in
191       no)   ;;
192       yes)  AC_DEFINE([MPFR_TESTS_TIMEOUT], 0, [timeout limit]) ;;
193       [[0-9]]|[[0-9]][[0-9]]|[[0-9]][[0-9]][[0-9]]|[[0-9]][[0-9]][[0-9]][[0-9]])
194        AC_DEFINE_UNQUOTED([MPFR_TESTS_TIMEOUT], $enableval, [timeout limit]) ;;
195       *)    AC_MSG_ERROR([bad value for --enable-tests-timeout]) ;;
196      esac])
197
198 AC_ARG_ENABLE(tune-for-coverage,
199    [  --enable-tune-for-coverage
200                           [[for developers]] tune MPFR for coverage tests],
201    [ case $enableval in
202       no)   ;;
203       yes)  AC_DEFINE([MPFR_TUNE_COVERAGE], 1, [tune for coverage]) ;;
204       *)    AC_MSG_ERROR([bad value for --enable-tune-for-coverage]) ;;
205      esac])
206
207 dnl First, detect incompatibilities between the above configure options.
208 AC_MSG_CHECKING([whether configure options are compatible])
209 if test "$enable_logging" = yes; then
210   if test "$enable_thread_safe" = yes; then
211     AC_MSG_RESULT([no])
212     AC_MSG_ERROR([enable either logging or thread-safe, not both])
213   fi
214 dnl The following test is done only to output a specific error message,
215 dnl as there would otherwise be an error due to enable_thread_safe=no.
216   if test "$enable_shared_cache" = yes; then
217     AC_MSG_RESULT([no])
218     AC_MSG_ERROR([shared cache does not work with logging support])
219   fi
220   enable_thread_safe=no
221 fi
222 if test "$enable_shared_cache" = yes; then
223   if test "$enable_thread_safe" = no; then
224     AC_MSG_RESULT([no])
225     AC_MSG_ERROR([shared cache needs thread-safe support])
226   fi
227   enable_thread_safe=yes
228 fi
229 AC_MSG_RESULT([yes])
230
231
232 dnl
233 dnl Setup CC and CFLAGS
234 dnl
235
236 dnl ********************************************************************
237 dnl Check for CC and CFLAGS in gmp.h
238
239 dnl Warning! The following tests must be done before Autoconf selects
240 dnl a compiler. This means that some macros such as AC_PROG_CC and
241 dnl AM_PROG_AR must be put after the following code.
242
243 if test -z "$user_redefine_cc" && test "$cross_compiling" != yes ; then
244
245 dnl We need to guess the C preprocessor instead of using AC_PROG_CPP,
246 dnl since AC_PROG_CPP implies AC_PROG_CC, which chooses a compiler
247 dnl (before we have the chance to get it from gmp.h) and does some
248 dnl checking related to this compiler (such as dependency tracking
249 dnl options); if the compiler changes due to __GMP_CC in gmp.h, one
250 dnl would have incorrect settings.
251 dnl FIXME: Move this in acinclude.m4 ?
252 if test -z "$GMP_CC$GMP_CFLAGS" ; then
253    AC_MSG_CHECKING(for CC and CFLAGS in gmp.h)
254    GMP_CC=__GMP_CC
255    GMP_CFLAGS=__GMP_CFLAGS
256    # /lib/cpp under Solaris doesn't support some environment variables
257    # used by GCC, such as C_INCLUDE_PATH. If the user has set up such
258    # environment variables, he probably wants to use them. So, let us
259    # prefer cpp and gcc to /lib/cpp. However, note that this won't
260    # work if GCC has been installed with versioned names only (e.g.
261    # with cpp-5 and gcc-5).
262    for cpp in "cpp -P" "cpp" "gcc -P -E" "gcc -E" "/lib/cpp -P" "/lib/cpp" "cc -P -E" "cc -E" "c99 -P -E" "c99 -E" "clang -E" "cl -E" "icl -E"
263    do
264      # Get CC
265      echo "#include \"gmp.h\"" > conftest.c
266      echo "MPFR_OPTION __GMP_CC" >> conftest.c
267      $cpp $CPPFLAGS conftest.c 2> /dev/null > conftest.txt
268      test $? -ne 0 && continue
269      GMP_CC=`$EGREP MPFR_OPTION conftest.txt | $SED -e 's/MPFR_OPTION //g;s/ *" *//g'`
270      # Get CFLAGS
271      echo "#include \"gmp.h\"" >  conftest.c
272      echo "MPFR_OPTION __GMP_CFLAGS" >> conftest.c
273      $cpp $CPPFLAGS conftest.c 2> /dev/null > conftest.txt
274      test $? -ne 0 && continue
275      [GMP_CFLAGS=`$EGREP MPFR_OPTION conftest.txt | $SED -e 's/[ "]-pedantic[ "]/ /g;s/MPFR_OPTION //g;s/ *" *//g'`]
276      break
277    done
278    rm -f conftest*
279    if test "x$GMP_CC" = "x__GMP_CC" || test "x$GMP_CFLAGS" = "x__GMP_CFLAGS" ; then
280       AC_MSG_RESULT(failed)
281       GMP_CFLAGS=
282       GMP_CC=
283    else
284       AC_MSG_RESULT([CC=$GMP_CC CFLAGS=$GMP_CFLAGS])
285    fi
286 fi
287
288 dnl But these variables may be invalid, so we must check them first.
289 dnl Note: we do not use AC_RUN_IFELSE, as it implies AC_PROG_CC.
290 if test -n "$GMP_CC$GMP_CFLAGS" ; then
291    AC_MSG_CHECKING(for CC=$GMP_CC and CFLAGS=$GMP_CFLAGS)
292    echo "int main (void) { return 0; }" > conftest.c
293    if $GMP_CC $GMP_CFLAGS -o conftest conftest.c 2> /dev/null ; then
294      AC_MSG_RESULT(yes)
295      CFLAGS=$GMP_CFLAGS
296      CC=$GMP_CC
297    else
298      AC_MSG_RESULT(no)
299    fi
300    rm -f conftest*
301 fi
302
303 fi
304
305 dnl ********************************************************************
306
307 AC_PROG_CC
308 AC_PROG_CPP
309 AC_LANG(C)
310
311 dnl AM_PROG_AR is needed so that ar-lib (wrapper for Microsoft lib.exe)
312 dnl gets installed by "automake -i" (if absent, "automake --warnings=all"
313 dnl gives a warning).
314 AM_PROG_AR
315
316 dnl This must done before MPFR_CONFIGS.
317 LT_INIT(win32-dll)
318
319 dnl Try to determine the double format
320 AC_MSG_CHECKING(format of `double' floating point)
321 AC_RUN_IFELSE([AC_LANG_PROGRAM([[
322 ]], [[
323 union ieee_double_extract
324 {
325   double d;
326   unsigned char x[8];
327 } t;
328 t.d = 2.877939254133025759330166692961938679218292236328125; /* exact */
329 if (sizeof (double) != 8)
330    return 0;
331 if (sizeof (unsigned char) != 1)
332    return 0;
333 if (t.x[0] == 1 && t.x[1] == 2 && t.x[2] == 3 && t.x[3] == 4 &&
334     t.x[4] == 5 && t.x[5] == 6 && t.x[6] == 7 && t.x[7] == 64)
335    return 1; /* little endian */
336 else if (t.x[7] == 1 && t.x[6] == 2 && t.x[5] == 3 && t.x[4] == 4 &&
337     t.x[3] == 5 && t.x[2] == 6 && t.x[1] == 7 && t.x[0] == 64)
338    return 2; /* big endian */
339 else
340    return 0; /* unknown */
341 ]])],
342    [mpfr_ieee_double=$?],
343    [mpfr_ieee_double=$?],
344    [mpfr_ieee_double=0])
345 case "$mpfr_ieee_double" in
346   1) AC_MSG_RESULT([IEEE little endian])
347      AC_DEFINE(HAVE_DOUBLE_IEEE_LITTLE_ENDIAN) ;;
348   2) AC_MSG_RESULT([IEEE big endian])
349      AC_DEFINE(HAVE_DOUBLE_IEEE_BIG_ENDIAN) ;;
350   *) AC_MSG_WARN([format of `double' floating-point not recognized]) ;;
351 esac
352
353 dnl For GCC, _Decimal64 was introduced in GCC 4.3 for some targets
354 dnl (note that it is not guaranteed to be available because it may
355 dnl be disabled in the GCC build). See:
356 dnl   https://gcc.gnu.org/gcc-4.3/changes.html
357 dnl _Decimal64 is not yet defined in GCC for C++:
358 dnl   https://gcc.gnu.org/bugzilla/show_bug.cgi?id=51364
359 dnl _Decimal64 support is broken with GCC 4.6.3 and 4.7.2 on powerpc64
360 dnl with the mode32 ABI, e.g. "-m32 -mpowerpc64 -mtune=970 -O3"; this
361 dnl is detected by the x != x test below.
362 AC_ARG_ENABLE(decimal-float,
363    [  --disable-decimal-float explicitly disable decimal floats support
364   --enable-decimal-float  build conversion functions from/to decimal floats
365                           [[default=autodetect]]],
366    [ case $enableval in
367       yes) ;;
368       no)  ;;
369       *)   AC_MSG_ERROR([bad value for --enable-decimal-float: yes or no]) ;;
370      esac])
371
372 dnl GCC >= 4.3 provides __float128, but since this is not standard,
373 dnl the default is "autodetect" and not "yes"
374 AC_ARG_ENABLE(float128,
375    [  --disable-float128      explicitly disable __float128 support
376   --enable-float128       build conversion functions from/to __float128
377                           [[default=autodetect]]],
378    [ case $enableval in
379       yes) ;;
380       no)  ;;
381       *)   AC_MSG_ERROR([bad value for --enable-float128: yes or no]) ;;
382      esac])
383
384 test_libgmp=__gmpz_init
385
386 AC_ARG_ENABLE(mini-gmp,
387    [  --enable-mini-gmp       build MPFR with mini-gmp (experimental) [[default=no]]],
388    [ case $enableval in
389       yes) AC_DEFINE([MPFR_USE_MINI_GMP],1,[Use mini-gmp])
390            # With mini-gmp, mp_limb_t is always unsigned long.
391            AC_COMPUTE_INT(nettle_cv_gmp_numb_bits, [(sizeof(unsigned long) * CHAR_BIT)],
392               [#include <limits.h>],
393               [AC_MSG_FAILURE([cannot find value of GMP_NUMB_BITS])])
394            AC_MSG_RESULT([$nettle_cv_gmp_numb_bits bits])
395            AC_DEFINE_UNQUOTED([GMP_NUMB_BITS], $nettle_cv_gmp_numb_bits, [number of bits in a limb])
396            AC_DEFINE([GMP_NAIL_BITS], 0, [number of nails in a limb])
397            test_libgmp=mpz_init;;
398       no)  ;;
399       *) AC_MSG_ERROR([bad value for --enable-mini-gmp: yes or no]) ;;
400      esac])
401
402 AC_ARG_ENABLE(debug-prediction,
403    [  --enable-debug-prediction
404                           [[for developers]] enable debug of branch prediction
405                           (for x86 and x86-64 with GCC, static libs)],
406    [ case $enableval in
407       yes)  if test "$enable_shared" != no; then
408               AC_MSG_ERROR([--enable-debug-prediction can only work in static mode (--disable-shared)])
409             fi
410             AC_DEFINE([MPFR_DEBUG_PREDICTION],1,
411                [Enable debug of branch prediction]) ;;
412       no)   ;;
413       *)    AC_MSG_ERROR([bad value for --enable-debug-prediction: yes or no]) ;;
414      esac])
415
416 AC_ARG_ENABLE(lto,
417    [  --enable-lto            build MPFR with link-time-optimization
418                           (experimental) [[default: no]]],
419    [ case $enableval in
420       yes)  if test "$enable_shared" != "no"; then
421               AC_MSG_ERROR([--enable-lto can only work in static mode (--disable-shared)])
422             fi
423             enable_lto=yes
424             ;;
425       no)   ;;
426       *)    AC_MSG_ERROR([bad value for --enable-lto: yes or no]) ;;
427      esac])
428
429 dnl Check if compiler is ICC, and if such a case, disable GCC
430 dnl And add some specific flags.
431 dnl Don't add Warnings Flags (Otherwise you'll get more than 20000 warnings).
432 dnl Add -long_double flags? Don't use -pc64 !
433 dnl Notes (VL):
434 dnl   * With icc 10.1 20080212 on itanium, the __ICC macro is not defined,
435 dnl     even when the -icc option is used (contrary to what is documented
436 dnl     on the icc man page).
437 dnl   * When ICC is correctly detected (__ICC macro defined), unsetting
438 dnl     the GCC variable confuses libtool. See:
439 dnl       https://bugs.debian.org/cgi-bin/bugreport.cgi?bug=485421
440 dnl   * If need be, the gcc predefined macros __GNUC_* can be disabled
441 dnl     thanks to the -no-gcc option.
442 dnl   * Now use -mieee-fp instead of -mp (ICC 13 says: option '-mp' is
443 dnl     deprecated and will be removed in a future release.). According
444 dnl     to "icc -help", both options are equivalent; it also suggests
445 dnl     to use -fp-model <arg> instead of -mp, but what is <arg>? Anyway
446 dnl     -mieee-fp solves the tset_d failure due to a negative zero. This
447 dnl     option has been introduced in ICC 9.0 for Linux (2005-06):
448 dnl     http://www.ncsa.illinois.edu/UserInfo/Resources/Software/Intel/Compilers/9.0/C_ReleaseNotes.htm
449 AC_MSG_CHECKING(for ICC)
450 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
451 #if !defined(__ICC)
452 # error "Not ICC"
453 error
454 #endif
455 ]], [[]])],[
456  AC_MSG_RESULT(yes)
457  CFLAGS="-fp_port -mieee-fp -wd1572 -wd265 -wd186 -wd239 $CFLAGS"
458 ],[AC_MSG_RESULT(no)])
459
460 dnl If CFLAGS has not been set explicitly and the compiler is GCC, then
461 dnl use some specific flags. But don't touch user other flags.
462 dnl Note: This is done even when CFLAGS has been set from GMP's CFLAGS
463 dnl (__GMP_CFLAGS macro in gmp.h) above. The consequence is that this
464 dnl might yield a compilation failure if the -Werror option appears in
465 dnl __GMP_CFLAGS. But in this case, since -Werror is not used by default,
466 dnl one may expect that the user would also set CFLAGS for MPFR.
467 if test "$test_CFLAGS" != set && test -n "$GCC"; then
468   CFLAGS="-Wpointer-arith $CFLAGS"
469   AC_MSG_CHECKING(whether the selected language is C++)
470   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
471 #if defined (__cplusplus)
472 # error "C++"
473 error
474 #endif
475   ]], [[]])],[
476     AC_MSG_RESULT(no)
477     CFLAGS="-Wmissing-prototypes -Wc++-compat $CFLAGS"
478   ],[
479     AC_MSG_RESULT(yes)
480     CFLAGS="-Wmissing-declarations -Wno-sign-compare $CFLAGS"
481   ])
482   CFLAGS="-Wall $CFLAGS"
483 fi
484
485 AM_PROG_CC_C_O
486
487 case $host in
488   *-apple-darwin*)
489 dnl This allows to take the first GMP library in the library paths,
490 dnl whether it is dynamic or static. This behavior is more sensible,
491 dnl in particular because it is the only way to link with a version
492 dnl only available in static form when another version is available
493 dnl in dynamic, and also for consistency, because the compiler will
494 dnl take the first gmp.h found in the include paths (so, we need to
495 dnl take a library that corresponds to this header file). This is a
496 dnl common problem with darwin.
497     MPFR_LD_SEARCH_PATHS_FIRST ;;
498 esac
499
500 AC_C_CONST
501 AC_C_VOLATILE
502 dnl Determine the endianness of integer. But since MPFR doesn't use
503 dnl AC_CONFIG_HEADERS, configure cannot provide such information for
504 dnl universal binaries containing variants with different endianness
505 dnl (i.e. generic code must be used).
506 AC_C_BIGENDIAN([AC_DEFINE(HAVE_BIG_ENDIAN)],[AC_DEFINE(HAVE_LITTLE_ENDIAN)],
507 [true],[true])
508
509 MPFR_CONFIGS
510
511 # (Based on GMP 5.1)
512 # clock_gettime is in librt on *-*-osf5.1 and on glibc < 2.17, so add -lrt to
513 # TUNE_LIBS if needed (e.g. if clock_gettime is not already in the C library).
514 # On linux (tested on x86_32, 2.6.26), clock_getres reports ns accuracy,
515 # while in a quick test on osf, clock_getres said only 1 millisecond.
516 old_LIBS="$LIBS"
517 AC_SEARCH_LIBS(clock_gettime, rt, [
518   AC_DEFINE([HAVE_CLOCK_GETTIME],1,[Define to 1 if you have the `clock_gettime' function])])
519 TUNE_LIBS="$LIBS"
520 LIBS="$old_LIBS"
521 AC_SUBST(TUNE_LIBS)
522
523 dnl
524 dnl Setup GMP detection
525 dnl
526
527 dnl Check GMP Header
528 AC_MSG_CHECKING(for gmp.h)
529 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
530 #include "gmp.h"
531 ]])],[AC_MSG_RESULT(yes)],[
532  AC_MSG_RESULT(no)
533  AC_MSG_ERROR([gmp.h can't be found, or is unusable.])
534 ])
535
536 dnl Configs for Windows DLLs.
537 dnl libtool requires "-no-undefined" for win32 dll
538 dnl
539 dnl "-Wl,output-def" is used to get a .def file for use by MS lib to make
540 dnl a .lib import library, described in the manual.
541 dnl
542 dnl Incidentally, libtool does generate an import library libmpfr.dll.a,
543 dnl but it's "ar" format and cannot be used by the MS linker.  There
544 dnl doesn't seem to be any GNU tool for generating or converting to .lib.
545 dnl
546 dnl The DLL version (the number in libmpfr-*.dll.def below) must be the
547 dnl version of the oldest supported interface (i.e. CURRENT - AGE in
548 dnl src/Makefile.am).
549 AC_SUBST(MPFR_LDFLAGS)
550 AC_SUBST(LIBMPFR_LDFLAGS)
551 case $host in
552   *-*-cygwin* | *-*-mingw* | *-*-pw32* | *-*-os2*)
553    AC_MSG_CHECKING(for DLL/static GMP)
554    if test "$enable_shared" = yes; then
555      MPFR_LDFLAGS="$MPFR_LDFLAGS -no-undefined"
556      LIBMPFR_LDFLAGS="$LIBMPFR_LDFLAGS -Wl,--output-def,.libs/libmpfr-6.dll.def"
557      AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
558 #include "gmp.h"
559 #if !__GMP_LIBGMP_DLL
560 # error "Dead man"
561 error
562 #endif
563      ]], [[]])],[AC_MSG_RESULT(DLL)],[
564   AC_MSG_RESULT(static)
565   AC_MSG_ERROR([libgmp isn't provided as a DLL: use --enable-static --disable-shared]) ])
566    else
567      AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
568 #include "gmp.h"
569 #if __GMP_LIBGMP_DLL
570 # error "Dead man"
571 error
572 #endif
573      ]], [[]])],[AC_MSG_RESULT(static)],[
574   AC_MSG_RESULT(DLL)
575   AC_MSG_ERROR([libgmp is provided as a DLL: use --disable-static --enable-shared]) ])
576   fi
577   ;;
578 esac
579
580 dnl Under Linux, make sure that the old dtags are used if LD_LIBRARY_PATH
581 dnl is defined. The issue is that with the new dtags, LD_LIBRARY_PATH has
582 dnl the precedence over the run path, so that if a compatible MPFR library
583 dnl is installed in some directory from $LD_LIBRARY_PATH, then the tested
584 dnl MPFR library will be this library instead of the MPFR library from the
585 dnl build tree. Other OS with the same issue might be added later.
586 dnl
587 dnl References:
588 dnl   https://bugs.debian.org/cgi-bin/bugreport.cgi?bug=859732
589 dnl   http://lists.gnu.org/archive/html/libtool/2017-05/msg00000.html
590 dnl
591 dnl We need to check whether --disable-new-dtags is supported as alternate
592 dnl linkers may be used (e.g., with tcc: CC=tcc LD=tcc).
593 dnl
594 case $host in
595   *-*-linux*)
596     if test -n "$LD_LIBRARY_PATH"; then
597       saved_LDFLAGS="$LDFLAGS"
598       LDFLAGS="$LDFLAGS -Wl,--disable-new-dtags"
599       AC_MSG_CHECKING(whether --disable-new-dtags is supported by the linker)
600       AC_LINK_IFELSE([AC_LANG_SOURCE([[
601 int main (void) { return 0; }
602       ]])],
603       [AC_MSG_RESULT(yes (use it since LD_LIBRARY_PATH is set))],
604       [AC_MSG_RESULT(no)
605        LDFLAGS="$saved_LDFLAGS"
606       ])
607     fi
608     ;;
609 esac
610
611 dnl
612 dnl For mpfr-longlong.h - TODO: should be replaced (see acinclude.m4).
613 dnl
614
615 GMP_C_ATTRIBUTE_MODE
616
617
618 dnl
619 dnl Setup GMP detection (continued)
620 dnl
621
622 dnl Check minimal GMP version
623 dnl We only guarantee that with a *functional* and recent enough GMP version,
624 dnl MPFR will compile; we do not guarantee that GMP will compile.
625 dnl In particular fat builds are broken in GMP 4.3.2 and GMP 5.0.0
626 dnl (at least on 64-bit Core 2 under Linux),
627 dnl see <https://gmplib.org/list-archives/gmp-bugs/2011-August/002345.html>.
628 if test -z "$enable_mini_gmp" ; then
629   AC_MSG_CHECKING(for recent GMP)
630   AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
631 #include "gmp.h"
632 #if (__GNU_MP_VERSION*100+__GNU_MP_VERSION_MINOR*10 < 500)
633 # error "GMP 5.0.0 or newer is required"
634 error
635 #endif
636   ]])],[AC_MSG_RESULT(yes)],[
637    AC_MSG_RESULT(no)
638    AC_MSG_ERROR([GMP 5.0.0 or newer is required])
639 ])
640 fi
641
642 dnl Check if gmp.h is usable at link time; this may detect errors such as
643 dnl with GMP 4.1, which uses "extern __inline__" unconditionally with all
644 dnl GCC versions, which breaks by default with GCC 5 (this problem with
645 dnl GMP 4.1 is no longer possible as we now require GMP 5.0.0 or newer,
646 dnl but the same kind of problem may occur in the future).
647 dnl Note: No linking is done against the GMP library at this time, as we
648 dnl do not use any GMP symbol. The goal of this test is to avoid obscure
649 dnl errors with the following gmp.h tests.
650 AC_MSG_CHECKING(usable gmp.h at link time)
651 AC_LINK_IFELSE([AC_LANG_PROGRAM([[
652 #include "gmp.h"
653 ]],[[]])],[AC_MSG_RESULT(yes)],[
654  AC_MSG_RESULT(no)
655  AC_MSG_ERROR([there is an incompatibility between gmp.h and the compiler.
656 See 'config.log' for details.])
657 ])
658
659 dnl Check if we can use internal header files of GMP (only --with-gmp-build)
660 if test "$use_gmp_build" = yes ; then
661    AC_MSG_CHECKING(for gmp internal files)
662    AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
663    #include "gmp.h"
664    #include "gmp-impl.h"
665    #include "longlong.h"
666    ]])],[
667      AC_MSG_RESULT(yes)
668      AC_DEFINE([MPFR_HAVE_GMP_IMPL],1,[Use GMP Internal Files])
669    ],[
670      AC_MSG_ERROR([header files gmp-impl.h and longlong.h not found])
671    ])
672 fi
673
674 dnl Check for GMP_NUMB_BITS and sizeof(mp_limb_t) consistency.
675 dnl Problems may occur if gmp.h was generated with some ABI
676 dnl and is used with another ABI (or if nails are used).
677 dnl This test doesn't need to link with libgmp (at least it shouldn't).
678 AC_MSG_CHECKING(for GMP_NUMB_BITS and sizeof(mp_limb_t) consistency)
679 AC_RUN_IFELSE([AC_LANG_PROGRAM([[
680 #include <stdio.h>
681 #include <limits.h>
682 #include "gmp.h"
683 ]], [[
684   if (GMP_NUMB_BITS == sizeof(mp_limb_t) * CHAR_BIT)
685     return 0;
686   fprintf (stderr, "GMP_NUMB_BITS     = %ld\n", (long) GMP_NUMB_BITS);
687   fprintf (stderr, "sizeof(mp_limb_t) = %ld\n", (long) sizeof(mp_limb_t));
688   fprintf (stderr, "sizeof(mp_limb_t) * CHAR_BIT = %ld != GMP_NUMB_BITS\n",
689            (long) (sizeof(mp_limb_t) * CHAR_BIT));
690   return 1;
691 ]])], [AC_MSG_RESULT(yes)], [
692        AC_MSG_RESULT(no)
693        AC_MSG_ERROR([GMP_NUMB_BITS and sizeof(mp_limb_t) are not consistent.
694 You probably need to change some of the GMP or MPFR compile options.
695 See 'config.log' for details (search for GMP_NUMB_BITS).])],
696        [AC_MSG_RESULT([cannot test])])
697
698 dnl Check if we can link with GMP
699 AC_CHECK_LIB(gmp, $test_libgmp, [LIBS="-lgmp $LIBS"],
700  [AC_MSG_ERROR([libgmp not found or uses a different ABI (including static vs shared).
701 Please read the INSTALL file -- see "In case of problem".])])
702
703 dnl Check for corresponding 'gmp.h' and libgmp
704 AC_MSG_CHECKING(if gmp.h version and libgmp version are the same)
705 dnl We do not set LD_LIBRARY_PATH, as it is not possible to set it just
706 dnl before the test program is run, and we do not want to affect other
707 dnl programs (such as the compiler), because the behavior could be
708 dnl incorrect and even have security implications.
709 dnl WARNING! LD_RUN_PATH is not taken into account by the GNU gold ld,
710 dnl e.g. from binutils-gold 2.22-5 under Debian; see
711 dnl   https://bugs.debian.org/cgi-bin/bugreport.cgi?bug=660813
712 if test -z "$enable_mini_gmp" ; then
713   saved_LD_RUN_PATH="$LD_RUN_PATH"
714   LD_RUN_PATH="${LD_RUN_PATH:+$LD_RUN_PATH$PATH_SEPARATOR}$gmp_lib_path"
715   export LD_RUN_PATH
716   AC_RUN_IFELSE([AC_LANG_PROGRAM([[
717 #include <stdio.h>
718 #include <string.h>
719 #include "gmp.h"
720   ]], [[
721   char buffer[100];
722   sprintf (buffer, "%d.%d.%d", __GNU_MP_VERSION, __GNU_MP_VERSION_MINOR,
723            __GNU_MP_VERSION_PATCHLEVEL);
724   printf ("(%s/%s) ", buffer, gmp_version);
725   fflush (stdout);
726   /* Also put information in config.log (stderr) */
727   fprintf (stderr, "gmp.h: %s / libgmp: %s\n", buffer, gmp_version);
728   if (strcmp (buffer, gmp_version) == 0)
729     return 0;
730   if (__GNU_MP_VERSION_PATCHLEVEL != 0)
731     return 1;
732   sprintf (buffer, "%d.%d", __GNU_MP_VERSION, __GNU_MP_VERSION_MINOR);
733   return (strcmp (buffer, gmp_version) != 0) ? 1 : 0;
734   ]])],
735    [AC_MSG_RESULT(yes)
736     MPFR_CHECK_GMP
737     MPFR_CHECK_DBL2INT_BUG
738     MPFR_CHECK_PRINTF_SPEC
739     MPFR_CHECK_PRINTF_GROUPFLAG],
740    [AC_MSG_RESULT(no)
741     AC_MSG_WARN([==========================================================])
742     AC_MSG_WARN(['gmp.h' and 'libgmp' seem to have different versions or])
743     AC_MSG_WARN([we cannot run a program linked with GMP (if you cannot])
744     AC_MSG_WARN([see the version numbers above). A cause may be different])
745     AC_MSG_WARN([GMP versions with different ABI's or the use of --with-gmp])
746     AC_MSG_WARN([or --with-gmp-include with a system include directory])
747     AC_MSG_WARN([(such as /usr/include or /usr/local/include).])
748     AC_MSG_WARN([However since we can't use 'libtool' inside the configure,])
749     AC_MSG_WARN([we can't be sure. See 'config.log' for details.])
750     AC_MSG_WARN([CC="$CC"])
751     AC_MSG_WARN([CFLAGS="$CFLAGS"])
752     AC_MSG_WARN([CPPFLAGS="$CPPFLAGS"])
753     AC_MSG_WARN([LDFLAGS="$LDFLAGS"])
754     AC_MSG_WARN([LIBS="$LIBS"])
755     AC_MSG_WARN([Temporary LD_RUN_PATH was "$LD_RUN_PATH".])
756     AC_MSG_WARN([==========================================================])
757     ],AC_MSG_RESULT([cannot test])
758   )
759   LD_RUN_PATH="$saved_LD_RUN_PATH"
760 fi
761
762 dnl __gmpn_sbpi1_divappr_q is an internal GMP symbol; thus its behavior
763 dnl may change or this symbol may be removed in the future (without being
764 dnl handled by the library versioning system, which is even worse, as this
765 dnl can mean undetected incompatibilities in case of GMP library upgrade,
766 dnl without rebuilding MPFR). So, this symbol must not be used, unless
767 dnl WANT_GMP_INTERNALS is defined. Only the GMP public API should be used
768 dnl by default, in particular by binary distributions. Moreover the check
769 dnl below may yield an incorrect result as libtool isn't used in configure
770 dnl (see above).
771 AC_CHECK_FUNCS([__gmpn_sbpi1_divappr_q])
772 dnl same for other GMP internal functions
773 AC_CHECK_FUNCS([__gmpn_invert_limb])
774 AC_CHECK_FUNCS([__gmpn_rsblsh_n])
775
776 MPFR_CHECK_MP_LIMB_T_VS_LONG
777
778 dnl The getrusage function is needed for MPFR bench (cf tools/bench)
779 AC_CHECK_FUNCS([getrusage])
780
781 dnl Remove also many MACROS (AC_DEFINE) which are unused by MPFR
782 dnl and polluate (and slow down because libtool has to parse them) the build.
783 if test -f confdefs.h; then
784   $SED '/#define PACKAGE_/d' <confdefs.h >confdefs.tmp
785   $SED '/#define HAVE_STRING/d' <confdefs.tmp >confdefs.h
786   $SED '/#define HAVE_ALLOCA /d' <confdefs.h >confdefs.tmp
787   $SED '/#define HAVE_DLFCN_H/d' <confdefs.tmp >confdefs.h
788   $SED '/#define HAVE_MEM/d' <confdefs.h >confdefs.tmp
789   $SED '/#define STDC_HEADERS/d' <confdefs.tmp >confdefs.h
790   $SED '/#define HAVE_STRTOL/d' <confdefs.h >confdefs.tmp
791   $SED '/#define HAVE_STDLIB_H/d' <confdefs.tmp >confdefs.h
792   $SED '/#define HAVE_UNISTD_H/d' <confdefs.h >confdefs.tmp
793   $SED '/#define HAVE_STDC_HEADERS/d' <confdefs.tmp >confdefs.h
794   $SED '/#define HAVE_LONG_DOUBLE/d' <confdefs.h >confdefs.tmp
795   $SED '/#define HAVE_SYS_STAT_H/d' <confdefs.tmp >confdefs.h
796   $SED '/#define HAVE_SYS_TYPES_H/d' <confdefs.h >confdefs.tmp
797   $SED '/#define PROTOTYPES/d' <confdefs.tmp >confdefs.h
798   $SED '/#define __PROTOTYPES/d' <confdefs.h >confdefs.tmp
799
800   mv confdefs.tmp confdefs.h
801 fi
802
803 if $EGREP -q -e '-dev$' $srcdir/VERSION; then
804   AC_SUBST([DATAFILES])dnl
805   DATAFILES=`echo \`$SED -n \
806     's/^ *data_check *("\(data\/[[^"]]*\)".*/tests\/\1/p' \
807     $srcdir/tests/*.c\``
808 fi
809
810 dnl Output
811 AC_CONFIG_FILES([Makefile mpfr.pc doc/Makefile src/Makefile tests/Makefile tune/Makefile src/mparam.h:src/mparam_h.in tools/bench/Makefile])
812 AC_OUTPUT
813
814 dnl NEWS README AUTHORS Changelog