eb7d4b9be83dc0c8e58f1f203b7791cb49d4301c
[mes.git] / scripts / mescc
1 #! /bin/sh
2 # -*-scheme-*-
3 mes_p=$(type -p mes)
4 if [ '(' -z "$mes_p" -a -z "$MES" ')' -o "$MES" = "guile" -o "$MES" = "mes.guile" ]; then
5     GODIR=${GODIR-@GODIR@}
6     GUILEDIR=${GUILEDIR-@GUILEDIR@}
7     [ "$GODIR" = @"GODIR"@ ] && GODIR=$(dirname $0)
8     [ "$GUILEDIR" = @"GUILEDIR"@ ] && GUILEDIR=$(dirname $0)/../guile
9     export GUILE_AUTO_COMPILE=${GUILE_AUTO_COMPILE-0}
10     GUILE_LOAD_COMPILED_PATH=$GODIR:$GUILE_LOAD_COMPILED_PATH
11     exec ${GUILE-guile} -L $GUILEDIR -e '(mescc)' -s "$0" "$@"
12 else
13     MES=${MES-$(dirname $0)/mes}
14     PREFIX=${PREFIX-@PREFIX@}
15     MES_PREFIX=${MES_PREFIX-$PREFIX}
16     if [ "$MES_PREFIX" = @PREFIX""@ ]
17     then
18         MES_PREFIX=$(cd $(dirname $0)/.. && pwd)
19         export MES_PREFIX
20     fi
21     MES_MODULEDIR=${MES_MODULEDIR-$MES_PREFIX/"module"}
22     export MES_MODULEDIR
23     $MES -s $0 "$@"
24     exit $?
25 fi
26 !#
27
28 ;;; Mes --- Maxwell Equations of Software
29 ;;; Copyright © 2016,2017,2018 Jan (janneke) Nieuwenhuizen <janneke@gnu.org>
30 ;;;
31 ;;; This file is part of Mes.
32 ;;;
33 ;;; Mes is free software; you can redistribute it and/or modify it
34 ;;; under the terms of the GNU General Public License as published by
35 ;;; the Free Software Foundation; either version 3 of the License, or (at
36 ;;; your option) any later version.
37 ;;;
38 ;;; Mes is distributed in the hope that it will be useful, but
39 ;;; WITHOUT ANY WARRANTY; without even the implied warranty of
40 ;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
41 ;;; GNU General Public License for more details.
42 ;;;
43 ;;; You should have received a copy of the GNU General Public License
44 ;;; along with Mes.  If not, see <http://www.gnu.org/licenses/>.
45
46 #!
47 Run with Guile-1.8:
48 GUILE='~/src/guile-1.8/build/pre-inst-guile --debug -q' scripts/mescc
49 !#
50
51 (define-module (mescc)
52   #:use-module (language c99 info)
53   #:use-module (language c99 compiler)
54   #:use-module (mes elf)
55   #:use-module (mes M1)
56   #:use-module (ice-9 getopt-long)
57   #:use-module (ice-9 pretty-print)
58   #:use-module (srfi srfi-1)
59   #:use-module (srfi srfi-26)
60   #:export (main))
61
62 (define %prefix (if (string-prefix? "@PREFIX" "@PREFIX@") (or (getenv "MES_PREFIX") "") "@PREFIX@"))
63
64 (cond-expand
65  (mes
66   (define %scheme "mes"))
67  (guile-2
68   (define %scheme "guile")
69   (define-macro (mes-use-module . rest) #t)
70   (module-define! (resolve-module '(language c99 compiler)) '%prefix %prefix))
71  (guile
72   (use-modules (ice-9 syncase))
73   (define %scheme "guile")
74   (define-macro (mes-use-module . rest) #t)
75   (module-define! (resolve-module '(language c99 compiler)) '%prefix %prefix)))
76
77 (define guile? (equal? %scheme "guile"))
78
79 (mes-use-module (mes guile))
80 (mes-use-module (mes getopt-long))
81 (mes-use-module (mes pretty-print))
82 (mes-use-module (language c99 info))
83 (mes-use-module (language c99 compiler))
84 (mes-use-module (mes display))
85 (mes-use-module (mes elf))
86 (mes-use-module (mes M1))
87 (mes-use-module (srfi srfi-1))
88 (mes-use-module (srfi srfi-26))
89
90 (format (current-error-port) "mescc[~a]...\n" %scheme)
91
92 (define (parse-opts args)
93   (let* ((option-spec
94           '((c (single-char #\c))
95             (define (single-char #\D) (value #t))
96             (E (single-char #\E))
97             (g (single-char #\g))
98             (help (single-char #\h))
99             (include (single-char #\I) (value #t))
100             (o (single-char #\o) (value #t))
101             (version (single-char #\V))
102             (write (single-char #\w) (value #t))))
103          (options (getopt-long args option-spec))
104          (help? (option-ref options 'help #f))
105          (files (option-ref options '() '()))
106          (usage? (and (not help?) (null? files)))
107          (version? (option-ref options 'version #f)))
108     (or
109      (and version?
110           (format (current-output-port) "mescc (mes) ~a\n" %version))
111      (and (or help? usage?)
112           (format (or (and usage? (current-error-port)) (current-output-port)) "\
113 Usage: mescc [OPTION]... FILE...
114   -c                 compile and assemble, but do not link
115   -D DEFINE          define DEFINE
116   -E                 preprocess only; do not compile, assemble or link
117   -g                 add debug info [GDB, objdump] TODO: hex2 footer
118   -h, --help         display this help and exit
119   -I DIR             append DIR to include path
120   -o FILE            write output to FILE
121   -v, --version      display version and exit
122   -w,--write=TYPE    dump Nyacc AST using TYPE {pretty-print,write}
123
124 Environment variables:
125
126   MES=BINARY         run on mes-executable BINARY {mes,guile}
127   MES_DEBUG=LEVEL    show debug output with verbosity LEVEL {0..5}
128   NYACC_TRACE=1      show Nyacc progress
129 ")
130           (exit (or (and usage? 2) 0)))
131      options)))
132
133 (define (read-object file)
134   (let ((char (with-input-from-file file read-char)))
135     (if (eq? char #\#) (error "hex2 format not supported:" file)))
136   (with-input-from-file file read))
137
138 (define (main:ast->info file)
139   (let ((ast (with-input-from-file file read)))
140     (c99-ast->info ast)))
141
142 (define (source->ast write defines includes)
143   (lambda (file)
144     (with-input-from-file file
145       (lambda ()
146         (write (c99-input->ast #:defines defines #:includes includes))))))
147
148 (define (source->info defines includes)
149   (lambda (file)
150     (with-input-from-file file
151       (lambda ()
152         ((c99-input->info #:defines defines #:includes includes))))))
153
154 (define (ast? o)
155   (or (string-suffix? ".E" o)
156       (string-suffix? (string-append "." %scheme "-E") o)))
157
158 (define (object? o)
159   (or (string-suffix? ".o" o)
160       (string-suffix? (string-append "." %scheme "-o") o)))
161
162 (define (main args)
163   (let* ((options (parse-opts args))
164          (files (option-ref options '() '()))
165          (file (car files))
166          (preprocess? (option-ref options 'E #f))
167          (compile? (option-ref options 'c #f))
168          (debug-info? (option-ref options 'g #f))
169          (asts (filter ast? files))
170          (objects (filter object? files))
171          (sources (filter (cut string-suffix? ".c" <>) files))
172          (base (substring file (1+ (or (string-rindex file #\/) -1)) (- (string-length file) 2)))
173          (out (option-ref options 'o (cond (compile? (string-append base ".o"))
174                                            (preprocess? (string-append base ".E"))
175                                            (else "a.out"))))
176          (multi-opt (lambda (option) (lambda (o) (and (eq? (car o) option) (cdr o)))))
177          (defines (reverse (filter-map (multi-opt 'define) options)))
178          (includes (reverse (filter-map (multi-opt 'include) options)))
179          (pretty-print/write (string->symbol (option-ref options 'write (if guile? "pretty-print" "write"))))
180          (pretty-print/write (if (eq? pretty-print/write 'pretty-print) pretty-print write)))
181     (when (getenv "MES_DEBUG")
182       (setenv "NYACC_TRACE" "yes")
183       (format (current-error-port) "options=~s\n" options)
184       (format (current-error-port) "output: ~a\n" out))
185     (if (and (pair? sources) (pair? objects)) (error "cannot mix source and object files:" files))
186     (with-output-to-file out
187       (lambda ()
188         (if (and (not compile?)
189                  (not preprocess?)) (set-port-encoding! (current-output-port) "ISO-8859-1"))
190         (cond ((pair? objects) (let ((objects (map read-object objects)))
191                                  (if compile? (objects->M1 objects)
192                                      (objects->elf objects))))
193               ((pair? asts) (let* ((infos (map main:ast->info asts))
194                                    (objects (map info->object infos)))
195                               (if compile? (objects->M1 objects)
196                                   (objects->elf objects))))
197               ((pair? sources) (if preprocess? (map (source->ast pretty-print/write defines includes) sources)
198                                    (let* ((infos (map (source->info defines includes) sources))
199                                           (objects (map info->object infos)))
200                                      (if compile? (objects->M1 objects)
201                                          (objects->elf objects))))))))))
202
203 (main (command-line))
204 'done