e4520e8e06cefd2c6bba25d3ad31a43197e16e4f
[mes.git] / scm.mes
1 ;;; -*-scheme-*-
2
3 ;;; Mes --- Maxwell Equations of Software
4 ;;; Copyright © 2016 Jan Nieuwenhuizen <janneke@gnu.org>
5 ;;;
6 ;;; scm.mes: This file is part of Mes.
7 ;;;
8 ;;; Mes is free software; you can redistribute it and/or modify it
9 ;;; under the terms of the GNU General Public License as published by
10 ;;; the Free Software Foundation; either version 3 of the License, or (at
11 ;;; your option) any later version.
12 ;;;
13 ;;; Mes is distributed in the hope that it will be useful, but
14 ;;; WITHOUT ANY WARRANTY; without even the implied warranty of
15 ;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
16 ;;; GNU General Public License for more details.
17 ;;;
18 ;;; You should have received a copy of the GNU General Public License
19 ;;; along with Mes.  If not, see <http://www.gnu.org/licenses/>.
20
21 ;; The Maxwell Equations of Software -- John McCarthy page 13
22 ;; http://www.softwarepreservation.org/projects/LISP/book/LISP%201.5%20Programmers%20Manual.pdf
23
24 (define-macro (if expr then . else)
25   `(cond
26     (,expr ,then)
27     (#t (cond (,(pair? else) ((lambda () ,@else)))))))
28
29 (define-macro (when expr . body)
30   `(if ,expr
31        ((lambda () ,@body))))
32
33 (define (list . rest) rest)
34
35 (define (split-params bindings params)
36   (cond ((null? bindings) params)
37         (#t (split-params (cdr bindings)
38                           (append params (cons (caar bindings) '()))))))
39
40 (define (split-values bindings values)
41   (cond ((null? bindings) values)
42         (#t (split-values (cdr bindings)
43                           (append values (cdar bindings) '())))))
44
45 (define-macro (simple-let bindings rest)
46   `((lambda ,(split-params bindings '()) ,@rest)
47     ,@(split-values bindings '())))
48
49 (define-macro (let-loop label bindings . rest)
50   `(let ((,label *unspecified*))
51      (let ((,label (lambda ,(split-params bindings '()) ,@rest)))
52        (,label ,@(split-values bindings '())))))
53
54 (define-macro (let-loop label bindings rest)
55   `((lambda (,label)
56       (set! ,label (lambda ,(split-params bindings '()) ,@rest))
57       (,label ,@(split-values bindings '())))
58     *unspecified*))
59
60 (define-macro (let bindings-or-label . rest)
61   `(cond (,(symbol? bindings-or-label)
62           (let-loop ,bindings-or-label ,(car rest) ,(cdr rest)))
63          (#t (simple-let ,bindings-or-label ,rest))))
64
65 (define-macro (or2 x y)
66   `(cond (,x ,x) (#t ,y)))
67
68 (define-macro (and2 x y)
69   `(cond (,x ,y) (#t #f)))
70
71 (define-macro (or . x)
72   (cond
73    ((null? x) #f)
74    ((null? (cdr x)) (car x))
75    (#t `(cond (,(car x))
76               (#t (or ,@(cdr x)))))))
77
78 (define-macro (and . x)
79   (cond ((null? x) #t)
80         ((null? (cdr x)) (car x))
81         (#t `(cond (,(car x) (and ,@(cdr x)))
82                    (#t #f)))))
83
84 (define (expand-let* bindings body)
85   (cond ((null? bindings)
86          `((lambda () ,@body)))
87         (#t `((lambda (,(caar bindings))
88                 ,(expand-let* (cdr bindings) body))
89               ,@(cdar bindings)))))
90
91 (define-macro (let* bindings . body)
92   (expand-let* bindings body))
93
94 (define (equal? a b) ;; FIXME: only 2 arg
95   (cond ((and (null? a) (null? b)) #t)
96         ((and (pair? a) (pair? b))
97          (and (equal? (car a) (car b))
98               (equal? (cdr a) (cdr b))))
99         ((and (string? a) (string? b))
100          (eq? (string->symbol a) (string->symbol b)))
101         ((and (vector? a) (vector? b))
102          (equal? (vector->list a) (vector->list b)))
103         (#t (eq? a b))))
104
105 (define (vector . rest) (list->vector rest))
106 (define (make-vector n . x)
107   (let ((fill (if (pair? x) (car x) *unspecified*)))
108     (list->vector (let loop ((n n))
109                     (if (= 0 n) '()
110                         (cons fill (loop (- n 1))))))))
111
112 (define-macro (defined? x)
113   `(assq ,x (cddr (current-module))))
114
115 (define (procedure? p)
116   (cond ((builtin? p) #t)
117         ((and (pair? p) (eq? (car p) 'lambda)))
118         ((and (pair? p) (eq? (car p) '*closure*)))
119         (#t #f)))
120
121 (define integer? number?)
122
123 (define (assq-set! alist key val)
124   (let ((entry (assq key alist)))
125     (cond (entry (set-cdr! entry val)
126                  alist)
127           (#t (cons (cons key val) alist)))))
128
129 (define (assq-ref alist key)
130   (let ((entry (assq key alist)))
131     (if entry (cdr entry)
132         #f)))
133
134 (define assv assq)
135
136 (define (assoc key alist)
137   (cond ((null? alist) #f)
138         ((equal? key (caar alist)) (car alist))
139         (#t (assoc key (cdr alist)))))
140
141 (define (memq x lst)
142   (cond ((null? lst) #f)
143         ((eq? x (car lst)) lst)
144         (#t (memq x (cdr lst)))))
145 (define memv memq)
146
147 (define (member x lst)
148   (cond ((null? lst) #f)
149         ((equal? x (car lst)) lst)
150         (#t (member x (cdr lst)))))
151
152 (define (map f l . r)
153   (cond ((null? l) '())
154         ((null? r) (cons (f (car l)) (map f (cdr l))))
155         ((null? (cdr r))
156          (cons (f (car l) (caar r)) (map f (cdr l) (cdar r))))))
157
158 (define (identity x) x)
159 (define (for-each f l . r)
160   (cond ((null? l) '())
161         ((null? r) (f (car l)) (for-each f (cdr l)))
162         ((null? (cdr r))
163          (for-each f (cdr l) (cdar r)))))
164
165 (define (not x)
166   (cond (x #f)
167         (#t #t)))
168
169 (define (<= a b) ;; FIXME: only 2 arg
170   (or (< a b)
171       (= a b)))
172
173 (define (>= a b) ;; FIXME: only 2 arg
174   (or (> a b)
175       (= a b)))
176
177 (define (list? x)
178   (or (null? x)
179       (and (pair? x) (list? (cdr x)))))
180
181 (define (unspecified-bindings bindings params)
182   (cond ((null? bindings) params)
183         (#t (unspecified-bindings
184              (cdr bindings)
185              (append params (cons (cons (caar bindings) '(*unspecified*)) '()))))))
186
187 (define (letrec-setters bindings setters)
188   (cond ((null? bindings) setters)
189         (#t (letrec-setters (cdr bindings)
190                             (append setters
191                                     (cons (cons 'set! (car bindings)) '()))))))
192
193 (define-macro (letrec bindings . body)
194   `(let ,(unspecified-bindings bindings '())
195      ,@(letrec-setters bindings '())
196      ,@body))
197
198 (define gensym
199   (let ((counter 0))
200     (lambda (. rest)
201       (let ((value (number->string counter)))
202         (set! counter (+ counter 1))
203         (string->symbol (string-append "g" value))))))
204
205 (define else #t)
206
207 (define (error who . rest)
208   (display "error:")
209   (display who)
210   (display ":")
211   (display rest)
212   (display newline))
213
214 (define (syntax-error message . rest)
215   (display "syntax-error:")
216   (display message)
217   (display ":")
218   (display rest)
219   (newline))
220
221 ;; srfi-1
222 (define (last-pair lst)
223   (let loop ((lst lst))
224     (if (or (null? lst) (null? (cdr lst))) lst
225         (loop (cdr lst)))))
226
227 (define (reverse lst)
228   (if (null? lst) '()
229       (append (reverse (cdr lst)) (cons (car lst) '()))))