mescc: mes parses simplest main with lalr.
[mes.git] / scm.mes
1 ;;; -*-scheme-*-
2
3 ;;; Mes --- Maxwell Equations of Software
4 ;;; Copyright © 2016 Jan Nieuwenhuizen <janneke@gnu.org>
5 ;;;
6 ;;; scm.mes: This file is part of Mes.
7 ;;;
8 ;;; Mes is free software; you can redistribute it and/or modify it
9 ;;; under the terms of the GNU General Public License as published by
10 ;;; the Free Software Foundation; either version 3 of the License, or (at
11 ;;; your option) any later version.
12 ;;;
13 ;;; Mes is distributed in the hope that it will be useful, but
14 ;;; WITHOUT ANY WARRANTY; without even the implied warranty of
15 ;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
16 ;;; GNU General Public License for more details.
17 ;;;
18 ;;; You should have received a copy of the GNU General Public License
19 ;;; along with Mes.  If not, see <http://www.gnu.org/licenses/>.
20
21 ;; The Maxwell Equations of Software -- John McCarthy page 13
22 ;; http://www.softwarepreservation.org/projects/LISP/book/LISP%201.5%20Programmers%20Manual.pdf
23
24 (define-macro (if expr then . else)
25   `(cond
26     (,expr ,then)
27     (#t (cond (,(pair? else) ((lambda () ,@else)))))))
28
29 (define-macro (when expr . body)
30   `(if ,expr
31        ((lambda () ,@body))))
32
33 (define (list . rest) rest)
34
35 (define (split-params bindings params)
36   (cond ((null? bindings) params)
37         (#t (split-params (cdr bindings)
38                           (append params (cons (caar bindings) '()))))))
39
40 (define (split-values bindings values)
41   (cond ((null? bindings) values)
42         (#t (split-values (cdr bindings)
43                           (append values (cdar bindings) '())))))
44
45 (define-macro (simple-let bindings rest)
46   `((lambda ,(split-params bindings '()) ,@rest)
47     ,@(split-values bindings '())))
48
49 (define-macro (let-loop label bindings . rest)
50   `(let ((,label *unspecified*))
51      (let ((,label (lambda ,(split-params bindings '()) ,@rest)))
52        (,label ,@(split-values bindings '())))))
53
54 (define-macro (let-loop label bindings rest)
55   `((lambda (,label)
56       (set! ,label (lambda ,(split-params bindings '()) ,@rest))
57       (,label ,@(split-values bindings '())))
58     *unspecified*))
59
60 (define-macro (let bindings-or-label . rest)
61   `(cond (,(symbol? bindings-or-label)
62           (let-loop ,bindings-or-label ,(car rest) ,(cdr rest)))
63          (#t (simple-let ,bindings-or-label ,rest))))
64
65 (define-macro (do init test . body)
66   `(let loop ((,(caar init) ,(cadar init)))
67      (when (not ,@test)
68        ,@body
69        (loop ,@(cddar init)))))
70
71 (define-macro (case val . args)
72   (if (null? args)
73       #f
74       (let* ((clause (car args))
75              (pred (car clause))
76              (body (cdr clause)))
77         (if (pair? pred)
78             `(if ,(if (null? (cdr pred))
79                       `(eq? ,val ',(car pred))
80                            `(member ,val ',pred))
81                  (begin ,@body)
82                  (case ,val ,@(cdr args)))
83             `(begin ,@body)))))  ; else clause
84
85 (define-macro (or2 x y)
86   `(cond (,x ,x) (#t ,y)))
87
88 (define-macro (and2 x y)
89   `(cond (,x ,y) (#t #f)))
90
91 (define-macro (or . x)
92   (cond
93    ((null? x) #f)
94    ((null? (cdr x)) (car x))
95    (#t `(cond (,(car x))
96               (#t (or ,@(cdr x)))))))
97
98 (define-macro (and . x)
99   (cond ((null? x) #t)
100         ((null? (cdr x)) (car x))
101         (#t `(cond (,(car x) (and ,@(cdr x)))
102                    (#t #f)))))
103
104 (define (expand-let* bindings body)
105   (cond ((null? bindings)
106          `((lambda () ,@body)))
107         (#t `((lambda (,(caar bindings))
108                 ,(expand-let* (cdr bindings) body))
109               ,@(cdar bindings)))))
110
111 (define-macro (let* bindings . body)
112   (expand-let* bindings body))
113
114 (define (equal? a b) ;; FIXME: only 2 arg
115   (cond ((and (null? a) (null? b)) #t)
116         ((and (pair? a) (pair? b))
117          (and (equal? (car a) (car b))
118               (equal? (cdr a) (cdr b))))
119         ((and (string? a) (string? b))
120          (eq? (string->symbol a) (string->symbol b)))
121         ((and (vector? a) (vector? b))
122          (equal? (vector->list a) (vector->list b)))
123         (#t (eq? a b))))
124
125 (define (vector . rest) (list->vector rest))
126 (define (make-vector n . x)
127   (let ((fill (if (pair? x) (car x) *unspecified*)))
128     (list->vector (let loop ((n n))
129                     (if (= 0 n) '()
130                         (cons fill (loop (- n 1))))))))
131
132 (define-macro (defined? x)
133   `(assq ,x (cddr (current-module))))
134
135 (define (procedure? p)
136   (cond ((builtin? p) #t)
137         ((and (pair? p) (eq? (car p) 'lambda)))
138         ((and (pair? p) (eq? (car p) '*closure*)))
139         (#t #f)))
140
141 (define integer? number?)
142
143 (define (assq-set! alist key val)
144   (let ((entry (assq key alist)))
145     (cond (entry (set-cdr! entry val)
146                  alist)
147           (#t (cons (cons key val) alist)))))
148
149 (define (assq-ref alist key)
150   (let ((entry (assq key alist)))
151     (if entry (cdr entry)
152         #f)))
153
154 (define assv assq)
155 (define assv-ref assq-ref)
156
157 (define (assoc key alist)
158   (cond ((null? alist) #f)
159         ((equal? key (caar alist)) (car alist))
160         (#t (assoc key (cdr alist)))))
161
162 (define (assoc-ref alist key)
163   (let ((entry (assoc key alist)))
164     (if entry (cdr entry)
165         #f)))
166
167 (define (memq x lst)
168   (cond ((null? lst) #f)
169         ((eq? x (car lst)) lst)
170         (#t (memq x (cdr lst)))))
171 (define memv memq)
172
173 (define (member x lst)
174   (cond ((null? lst) #f)
175         ((equal? x (car lst)) lst)
176         (#t (member x (cdr lst)))))
177
178 (define (map f l . r)
179   (cond ((null? l) '())
180         ((null? r) (cons (f (car l)) (map f (cdr l))))
181         ((null? (cdr r))
182          (cons (f (car l) (caar r)) (map f (cdr l) (cdar r))))))
183
184 (define (identity x) x)
185 (define (for-each f l . r)
186   (cond ((null? l) '())
187         ((null? r) (f (car l)) (for-each f (cdr l)))
188         ((null? (cdr r))
189          (for-each f (cdr l) (cdar r)))))
190
191 (define (not x)
192   (cond (x #f)
193         (#t #t)))
194
195 (define (<= . rest)
196   (or (apply < rest)
197       (apply = rest)))
198
199 (define (>= . rest)
200   (or (apply > rest)
201       (apply = rest)))
202
203 (define quotient /)
204
205 (define (remainder x y)
206   (- x (* (/ x y) y)))
207
208 (define (expt x y)
209   (let loop ((s 1) (count y))
210     (if (= 0 count) s
211         (loop (* s x) (- count 1)))))
212
213 (define (max x . rest)
214   (if (null? rest) x
215       (let* ((y (car rest))
216              (z (if (> x y) x y)))
217         (apply max (cons z (cdr rest))))))
218
219 (define (min x . rest)
220   (if (null? rest) x
221       (let* ((y (car rest))
222              (z (if (< x y) x y)))
223         (apply min (cons z (cdr rest))))))
224
225 (define (list? x)
226   (or (null? x)
227       (and (pair? x) (list? (cdr x)))))
228
229 (define (unspecified-bindings bindings params)
230   (cond ((null? bindings) params)
231         (#t (unspecified-bindings
232              (cdr bindings)
233              (append params (cons (cons (caar bindings) '(*unspecified*)) '()))))))
234
235 (define (letrec-setters bindings setters)
236   (cond ((null? bindings) setters)
237         (#t (letrec-setters (cdr bindings)
238                             (append setters
239                                     (cons (cons 'set! (car bindings)) '()))))))
240
241 (define-macro (letrec bindings . body)
242   `(let ,(unspecified-bindings bindings '())
243      ,@(letrec-setters bindings '())
244      ,@body))
245
246 (define gensym
247   (let ((counter 0))
248     (lambda (. rest)
249       (let ((value (number->string counter)))
250         (set! counter (+ counter 1))
251         (string->symbol (string-append "g" value))))))
252
253 (define else #t)
254
255 (define (error who . rest)
256   (display "error:")
257   (display who)
258   (display ":")
259   (display rest)
260   (display newline))
261
262 (define (syntax-error message . rest)
263   (display "syntax-error:")
264   (display message)
265   (display ":")
266   (display rest)
267   (newline))
268
269 (define (list-ref lst k)
270   (let loop ((lst lst) (k k))
271     (if (= 0 k) (car lst)
272         (loop (cdr lst) (- k 1)))))
273
274 ;; srfi-1
275 (define (last-pair lst)
276   (let loop ((lst lst))
277     (if (or (null? lst) (null? (cdr lst))) lst
278         (loop (cdr lst)))))
279
280 (define (reverse lst)
281   (if (null? lst) '()
282       (append (reverse (cdr lst)) (cons (car lst) '()))))
283
284 (define (eof-object? x)
285   (or (and (number? x) (= x -1))
286       (and (char? x) (eof-object? (char->integer x)))))
287
288 (define (char=? x y)
289   (and (char? x) (char? y)
290        (eq? x y)))
291
292 (define (char-alphabetic? x)
293   (and (char? x)
294        (let ((i (char->integer x)))
295         (or (and (>= i (char->integer #\A)) (<= i (char->integer #\Z)))
296             (and (>= i (char->integer #\a)) (<= i (char->integer #\z)))))))
297
298 (define (char-numeric? x)
299   (and (char? x)
300        (let ((i (char->integer x)))
301          (and (>= i (char->integer #\0)) (<= i (char->integer #\9))))))
302
303 (define (current-input-port) #f)
304 (define (port-filename port) "<stdin>")
305 (define (port-line port) 0)
306 (define (port-column port) 0)
307 (define (ftell port) 0)
308 (define (false-if-exception x) x)