scm.mes: add list-ref.
[mes.git] / scm.mes
1 ;;; -*-scheme-*-
2
3 ;;; Mes --- Maxwell Equations of Software
4 ;;; Copyright © 2016 Jan Nieuwenhuizen <janneke@gnu.org>
5 ;;;
6 ;;; scm.mes: This file is part of Mes.
7 ;;;
8 ;;; Mes is free software; you can redistribute it and/or modify it
9 ;;; under the terms of the GNU General Public License as published by
10 ;;; the Free Software Foundation; either version 3 of the License, or (at
11 ;;; your option) any later version.
12 ;;;
13 ;;; Mes is distributed in the hope that it will be useful, but
14 ;;; WITHOUT ANY WARRANTY; without even the implied warranty of
15 ;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
16 ;;; GNU General Public License for more details.
17 ;;;
18 ;;; You should have received a copy of the GNU General Public License
19 ;;; along with Mes.  If not, see <http://www.gnu.org/licenses/>.
20
21 ;; The Maxwell Equations of Software -- John McCarthy page 13
22 ;; http://www.softwarepreservation.org/projects/LISP/book/LISP%201.5%20Programmers%20Manual.pdf
23
24 (define-macro (if expr then . else)
25   `(cond
26     (,expr ,then)
27     (#t (cond (,(pair? else) ((lambda () ,@else)))))))
28
29 (define-macro (when expr . body)
30   `(if ,expr
31        ((lambda () ,@body))))
32
33 (define (list . rest) rest)
34
35 (define (split-params bindings params)
36   (cond ((null? bindings) params)
37         (#t (split-params (cdr bindings)
38                           (append params (cons (caar bindings) '()))))))
39
40 (define (split-values bindings values)
41   (cond ((null? bindings) values)
42         (#t (split-values (cdr bindings)
43                           (append values (cdar bindings) '())))))
44
45 (define-macro (simple-let bindings rest)
46   `((lambda ,(split-params bindings '()) ,@rest)
47     ,@(split-values bindings '())))
48
49 (define-macro (let-loop label bindings . rest)
50   `(let ((,label *unspecified*))
51      (let ((,label (lambda ,(split-params bindings '()) ,@rest)))
52        (,label ,@(split-values bindings '())))))
53
54 (define-macro (let-loop label bindings rest)
55   `((lambda (,label)
56       (set! ,label (lambda ,(split-params bindings '()) ,@rest))
57       (,label ,@(split-values bindings '())))
58     *unspecified*))
59
60 (define-macro (let bindings-or-label . rest)
61   `(cond (,(symbol? bindings-or-label)
62           (let-loop ,bindings-or-label ,(car rest) ,(cdr rest)))
63          (#t (simple-let ,bindings-or-label ,rest))))
64
65 (define-macro (do init test . body)
66   `(let loop ((,(caar init) ,(cadar init)))
67      (when (not ,@test)
68        ,@body
69        (loop ,@(cddar init)))))
70
71 (define-macro (or2 x y)
72   `(cond (,x ,x) (#t ,y)))
73
74 (define-macro (and2 x y)
75   `(cond (,x ,y) (#t #f)))
76
77 (define-macro (or . x)
78   (cond
79    ((null? x) #f)
80    ((null? (cdr x)) (car x))
81    (#t `(cond (,(car x))
82               (#t (or ,@(cdr x)))))))
83
84 (define-macro (and . x)
85   (cond ((null? x) #t)
86         ((null? (cdr x)) (car x))
87         (#t `(cond (,(car x) (and ,@(cdr x)))
88                    (#t #f)))))
89
90 (define (expand-let* bindings body)
91   (cond ((null? bindings)
92          `((lambda () ,@body)))
93         (#t `((lambda (,(caar bindings))
94                 ,(expand-let* (cdr bindings) body))
95               ,@(cdar bindings)))))
96
97 (define-macro (let* bindings . body)
98   (expand-let* bindings body))
99
100 (define (equal? a b) ;; FIXME: only 2 arg
101   (cond ((and (null? a) (null? b)) #t)
102         ((and (pair? a) (pair? b))
103          (and (equal? (car a) (car b))
104               (equal? (cdr a) (cdr b))))
105         ((and (string? a) (string? b))
106          (eq? (string->symbol a) (string->symbol b)))
107         ((and (vector? a) (vector? b))
108          (equal? (vector->list a) (vector->list b)))
109         (#t (eq? a b))))
110
111 (define (vector . rest) (list->vector rest))
112 (define (make-vector n . x)
113   (let ((fill (if (pair? x) (car x) *unspecified*)))
114     (list->vector (let loop ((n n))
115                     (if (= 0 n) '()
116                         (cons fill (loop (- n 1))))))))
117
118 (define-macro (defined? x)
119   `(assq ,x (cddr (current-module))))
120
121 (define (procedure? p)
122   (cond ((builtin? p) #t)
123         ((and (pair? p) (eq? (car p) 'lambda)))
124         ((and (pair? p) (eq? (car p) '*closure*)))
125         (#t #f)))
126
127 (define integer? number?)
128
129 (define (assq-set! alist key val)
130   (let ((entry (assq key alist)))
131     (cond (entry (set-cdr! entry val)
132                  alist)
133           (#t (cons (cons key val) alist)))))
134
135 (define (assq-ref alist key)
136   (let ((entry (assq key alist)))
137     (if entry (cdr entry)
138         #f)))
139
140 (define assv assq)
141
142 (define (assoc key alist)
143   (cond ((null? alist) #f)
144         ((equal? key (caar alist)) (car alist))
145         (#t (assoc key (cdr alist)))))
146
147 (define (memq x lst)
148   (cond ((null? lst) #f)
149         ((eq? x (car lst)) lst)
150         (#t (memq x (cdr lst)))))
151 (define memv memq)
152
153 (define (member x lst)
154   (cond ((null? lst) #f)
155         ((equal? x (car lst)) lst)
156         (#t (member x (cdr lst)))))
157
158 (define (map f l . r)
159   (cond ((null? l) '())
160         ((null? r) (cons (f (car l)) (map f (cdr l))))
161         ((null? (cdr r))
162          (cons (f (car l) (caar r)) (map f (cdr l) (cdar r))))))
163
164 (define (identity x) x)
165 (define (for-each f l . r)
166   (cond ((null? l) '())
167         ((null? r) (f (car l)) (for-each f (cdr l)))
168         ((null? (cdr r))
169          (for-each f (cdr l) (cdar r)))))
170
171 (define (not x)
172   (cond (x #f)
173         (#t #t)))
174
175 (define (<= . rest)
176   (or (apply < rest)
177       (apply = rest)))
178
179 (define (>= . rest)
180   (or (apply > rest)
181       (apply = rest)))
182
183 (define quotient /)
184
185 (define (remainder x y)
186   (- x (* (/ x y) y)))
187
188 (define (expt x y)
189   (let loop ((s 1) (count y))
190     (if (= 0 count) s
191         (loop (* s x) (- count 1)))))
192
193 (define (max x . rest)
194   (if (null? rest) x
195       (let* ((y (car rest))
196              (z (if (> x y) x y)))
197         (apply max (cons z (cdr rest))))))
198
199 (define (min x . rest)
200   (if (null? rest) x
201       (let* ((y (car rest))
202              (z (if (< x y) x y)))
203         (apply min (cons z (cdr rest))))))
204
205 (define (list? x)
206   (or (null? x)
207       (and (pair? x) (list? (cdr x)))))
208
209 (define (unspecified-bindings bindings params)
210   (cond ((null? bindings) params)
211         (#t (unspecified-bindings
212              (cdr bindings)
213              (append params (cons (cons (caar bindings) '(*unspecified*)) '()))))))
214
215 (define (letrec-setters bindings setters)
216   (cond ((null? bindings) setters)
217         (#t (letrec-setters (cdr bindings)
218                             (append setters
219                                     (cons (cons 'set! (car bindings)) '()))))))
220
221 (define-macro (letrec bindings . body)
222   `(let ,(unspecified-bindings bindings '())
223      ,@(letrec-setters bindings '())
224      ,@body))
225
226 (define gensym
227   (let ((counter 0))
228     (lambda (. rest)
229       (let ((value (number->string counter)))
230         (set! counter (+ counter 1))
231         (string->symbol (string-append "g" value))))))
232
233 (define else #t)
234
235 (define (error who . rest)
236   (display "error:")
237   (display who)
238   (display ":")
239   (display rest)
240   (display newline))
241
242 (define (syntax-error message . rest)
243   (display "syntax-error:")
244   (display message)
245   (display ":")
246   (display rest)
247   (newline))
248
249 (define (list-ref lst k)
250   (let loop ((lst lst) (k k))
251     (if (= 0 k) (car lst)
252         (loop (cdr lst) (- k 1)))))
253
254 ;; srfi-1
255 (define (last-pair lst)
256   (let loop ((lst lst))
257     (if (or (null? lst) (null? (cdr lst))) lst
258         (loop (cdr lst)))))
259
260 (define (reverse lst)
261   (if (null? lst) '()
262       (append (reverse (cdr lst)) (cons (car lst) '()))))