5e5bb5e3dbe4edb7d5e9e635150e5e4c43930670
[mes.git] / module / nyacc / lang / c99 / util1.scm
1 ;;; lang/c/util1.scm
2 ;;;
3 ;;; Copyright (C) 2015,2016 Matthew R. Wette
4 ;;;
5 ;;; This program is free software: you can redistribute it and/or modify
6 ;;; it under the terms of the GNU General Public License as published by 
7 ;;; the Free Software Foundation, either version 3 of the License, or 
8 ;;; (at your option) any later version.
9 ;;;
10 ;;; This program is distributed in the hope that it will be useful,
11 ;;; but WITHOUT ANY WARRANTY; without even the implied warranty of 
12 ;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
13 ;;; GNU General Public License for more details.
14 ;;;
15 ;;; You should have received a copy of the GNU General Public License
16 ;;; along with this program.  If not, see <http://www.gnu.org/licenses/>.
17
18 ;; C parser utilities
19
20 (define-module (nyacc lang c99 util1)
21   #:export (c99-std-help
22             gen-gcc-defs
23             remove-inc-trees
24             merge-inc-trees!
25             elifify)
26   #:use-module (nyacc lang util)
27   #:use-module ((srfi srfi-1) #:select (append-reverse))
28   #:use-module (srfi srfi-2) ;; and-let*
29   #:use-module (sxml fold)
30   #:use-module (sxml match)
31 )
32
33 ;; include-helper for C99 std
34 (define c99-std-help
35   '(("alloca.h")
36     ("complex.h" "complex" "imaginary" "_Imaginary_I=C99_ANY" "I=C99_ANY")
37     ("ctype.h")
38     ("fenv.h" "fenv_t" "fexcept_t")
39     ("float.h" "float_t" "FLT_MAX=C99_ANY" "DBL_MAX=C99_ANY")
40     ("inttypes.h"
41      "int8_t" "uint8_t" "int16_t" "uint16_t" "int32_t" "uint32_t"
42      "int64_t" "uint64_t" "uintptr_t" "intptr_t" "intmax_t" "uintmax_t"
43      "int_least8_t" "uint_least8_t" "int_least16_t" "uint_least16_t"
44      "int_least32_t" "uint_least32_t" "int_least64_t" "uint_least64_t"
45      "imaxdiv_t")
46     ("limits.h"
47      "INT_MIN=C99_ANY" "INT_MAX=C99_ANY" "LONG_MIN=C99_ANY" "LONG_MAX=C99_ANY")
48     ("math.h" "float_t" "double_t")
49     ("regex.h" "regex_t" "regmatch_t")
50     ("setjmp.h" "jmp_buf")
51     ("signal.h" "sig_atomic_t")
52     ("stdarg.h" "va_list")
53     ("stddef.h" "ptrdiff_t" "size_t" "wchar_t")
54     ("stdint.h"
55      "int8_t" "uint8_t" "int16_t" "uint16_t" "int32_t" "uint32_t"
56      "int64_t" "uint64_t" "uintptr_t" "intptr_t" "intmax_t" "uintmax_t"
57      "int_least8_t" "uint_least8_t" "int_least16_t" "uint_least16_t"
58      "int_least32_t" "uint_least32_t" "int_least64_t" "uint_least64_t")
59     ("stdio.h" "FILE" "size_t")
60     ("stdlib.h" "div_t" "ldiv_t" "lldiv_t" "wchar_t")
61     ("string.h" "size_t")
62     ("strings.h" "size_t")
63     ("time.h" "time_t" "clock_t" "size_t")
64     ("unistd.h" "size_t" "ssize_t" "div_t" "ldiv_t")
65     ("wchar.h" "wchar_t" "wint_t" "mbstate_t" "size_t")
66     ("wctype.h" "wctrans_t" "wctype_t" "wint_t")
67     ))
68
69 ;; @deffn gen-gcc-defs args  [#:CC "clang"] => '(("ABC" . "123") ...)
70 ;; Generate a list of default defines produced by gcc (or clang).
71 (define gen-gcc-defs
72   ;; @code{"gcc -dM -E"} will generate lines like @code{"#define ABC 123"}.
73   ;; We generate and return a list like @code{'(("ABC" . "123") ...)}.
74   (let ((rx (make-regexp "#define\\s+(\\S+)\\s+(.*)")))
75     (lambda* (args #:key (CC "gcc"))
76       (map
77        (lambda (l)
78          (let ((m (regexp-exec rx l)))
79            (cons (match:substring m 1) (match:substring m 2))))
80        (let ((ip (open-input-pipe (string-append CC " -dM -E - </dev/null"))))
81          (let iter ((lines '()) (line (read-line ip 'trim)))
82            (if (eof-object? line) lines
83                (iter (cons line lines) (read-line ip 'trim)))))))))
84
85 ;; @item remove-inc-trees tree
86 ;; Remove the trees included with cpp-include statements.
87 ;; @example
88 ;; '(... (cpp-stmt (include "<foo.h>" (trans-unit ...))) ...)
89 ;; => '(... (cpp-stmt (include "<foo.h>")) ...)
90 ;; @end example
91 (define (remove-inc-trees tree)
92   (if (not (eqv? 'trans-unit (car tree))) (error "expecting c-tree"))
93   (let iter ((rslt (make-tl 'trans-unit))
94              ;;(head '(trans-unit)) (tail (cdr tree))
95              (tree (cdr tree)))
96     (cond
97      ((null? tree) (tl->list rslt))
98      ((and (eqv? 'cpp-stmt (car (car tree)))
99            (eqv? 'include (caadr (car tree))))
100       (iter (tl-append rslt `(cpp-stmt (include ,(cadadr (car tree)))))
101             (cdr tree)))
102      (else (iter (tl-append rslt (car tree)) (cdr tree))))))
103
104 ;; @item merge-inc-trees tree
105 ;; Remove the trees included with cpp-include statements.
106 ;; @example
107 ;; '(... (cpp-stmt (include "<foo.h>" (trans-unit (stmt ...))) ...)
108 ;; => '(... (stmt...) ...)
109 ;; @end example
110 #;(define (Xmerge-inc-trees tree)
111   (if (not (eqv? 'trans-unit (car tree))) (error "expecting c-tree"))
112   (let iter ((rslt (make-tl 'trans-unit))
113              (tree (cdr tree)))
114     (cond
115      ((null? tree) (tl->list rslt))
116      ((and (eqv? 'cpp-stmt (caar tree)) (eqv? 'include (cadar tree)))
117       (iter (tl-extend rslt (cdr (merge-inc-trees (cdddar tree)))) (cdr tree)))
118      (else (iter (tl-append rslt (car tree)) (cdr tree))))))
119
120
121 ;; @item merge-inc-trees! tree => tree
122 ;; This will (recursively) merge code from cpp-includes into the tree.
123 ;; @example
124 ;; (trans-unit
125 ;;  (decl (a))
126 ;;  (cpp-stmt (include "<hello.h>" (trans-unit (decl (b)))))
127 ;;  (decl (c)))
128 ;; =>
129 ;; (trans-unit (decl (a)) (decl (b)) (decl (c)))
130 ;; @end example
131 (define (merge-inc-trees! tree)
132
133   ;; @item find-span (trans-unit a b c) => ((a . +->) . (c . '())
134   (define (find-span tree)
135     (cond
136      ((not (pair? tree)) '())           ; maybe parse failed
137      ((not (eqv? 'trans-unit (car tree))) (error "expecting c-tree"))
138      ((null? (cdr tree)) (error "null c99-tree"))
139      (else
140       (let ((fp tree))                  ; first pair
141         (let iter ((lp tree)            ; last pair
142                    (np (cdr tree)))     ; next pair
143           (cond
144            ((null? np) (cons (cdr fp) lp))
145            ;; The following is an ugly hack to find cpp-include
146            ;; with trans-unit attached.
147            ((and-let* ((expr (car np))
148                        ((eqv? 'cpp-stmt (car expr)))
149                        ((eqv? 'include (caadr expr)))
150                        (rest (cddadr expr))
151                        ((pair? rest))
152                        (span (find-span (car rest))))
153                       (set-cdr! lp (car span))
154                       (iter (cdr span) (cdr np))))
155            (else
156             (set-cdr! lp np)
157             (iter np (cdr np)))))))))
158
159   ;; Use cons to generate a new reference:
160   ;; (cons (car tree) (car (find-span tree)))
161   ;; or not:
162   (find-span tree)
163   tree)
164
165
166 ;; @deffn elifify tree => tree
167 ;; This procedure will find patterns of
168 ;; @example
169 ;; (if cond-1 then-part-1
170 ;;            (if cond-2 then-part-2
171 ;;                       else-part-2
172 ;; @end example
173 ;; @noindent
174 ;; and convert to
175 ;; @example
176 ;; (if cond-1 then-part-1
177 ;;            (elif cond-2 then-part-2)
178 ;;            else-part-2
179 ;; @end example
180 (define (elifify tree)
181   (define (fU tree)
182     (sxml-match tree
183       ((if ,x1 ,t1 (if ,x2 ,t2 (else-if ,x3 ,t3) . ,rest))
184        `(if ,x1 ,t1 (else-if ,x2 ,t2) (else-if ,x3 ,t3) . ,rest))
185       ((if ,x1 ,t1 (if ,x2 ,t2 . ,rest))
186        `(if ,x1 ,t1 (else-if ,x2 ,t2) . ,rest))
187       (,otherwise
188        tree)))
189   (foldt fU identity tree))
190        
191 ;; --- last line ---