nyacc: lots of C99/CPP fixes. now more robust for code mode
[mes.git] / module / nyacc / lang / c99 / cppbody.scm
1 ;;; nyacc/lang/c99/cppbody.scm
2 ;;;
3 ;;; Copyright (C) 2016-2017 Matthew R. Wette
4 ;;;
5 ;;; This program is free software: you can redistribute it and/or modify
6 ;;; it under the terms of the GNU General Public License as published by
7 ;;; the Free Software Foundation, either version 3 of the License, or
8 ;;; (at your option) any later version.
9 ;;;
10 ;;; This program is distributed in the hope that it will be useful,
11 ;;; but WITHOUT ANY WARRANTY; without even the implied warranty of
12 ;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
13 ;;; GNU General Public License for more details.
14 ;;;
15 ;;; You should have received a copy of the GNU General Public License
16 ;;; along with this program.  If not, see <http://www.gnu.org/licenses/>.
17
18 (define (cpp-err fmt . args)
19   (apply throw 'cpp-error fmt args))
20
21 ;; Since we want to be able to get CPP statements with comment in tact
22 ;; (e.g., for passing to @code{pretty-print-c99}) we need to remove
23 ;; comments when parsing CPP expressions.  We convert a comm-reader
24 ;; into a comm-skipper here.  And from that generate a lexer generator.
25 (define cpp-comm-skipper
26   (let ((reader (make-comm-reader '(("/*" . "*/")))))
27     (lambda (ch)
28       (reader ch #f))))
29
30 ;; generate a lexical analyzer per string
31 (define gen-cpp-lexer
32   (make-lexer-generator mtab #:comm-skipper cpp-comm-skipper))
33
34 ;; @deffn parse-cpp-expr text => tree
35 ;; Given a string returns a cpp parse tree.  This is called by
36 ;; @code{eval-cpp-expr}.  The text will have had all CPP defined symbols
37 ;; expanded already so no identifiers should appear in the text.
38 ;; A @code{cpp-error} will be thrown if a parse error occurs.
39 (define (parse-cpp-expr text)
40   (with-throw-handler
41    'nyacc-error
42    (lambda ()
43      (with-input-from-string text
44        (lambda () (raw-parser (gen-cpp-lexer)))))
45    (lambda (key fmt . args)
46      (apply throw 'cpp-error fmt args))))
47
48 ;; @deffn eval-cpp-expr tree dict => datum
49 ;; Evaluate a tree produced from @code{parse-cpp-expr}.
50 ;; The tree passed to this routine is 
51 (define (eval-cpp-expr tree dict)
52   (letrec
53       ((tx (lambda (tr ix) (list-ref tr ix)))
54        (tx1 (lambda (tr) (tx tr 1)))
55        (ev (lambda (ex ix) (eval-expr (list-ref ex ix))))
56        (ev1 (lambda (ex) (ev ex 1)))    ; eval expr in arg 1
57        (ev2 (lambda (ex) (ev ex 2)))    ; eval expr in arg 2
58        (ev3 (lambda (ex) (ev ex 3)))    ; eval expr in arg 3
59        (eval-expr
60         (lambda (tree)
61           (case (car tree)
62             ((fixed) (string->number (tx1 tree)))
63             ((char) (char->integer (tx1 tree)))
64             ((defined) (if (assoc-ref dict (tx1 tree)) 1 0))
65             ((pre-inc post-inc) (1+ (ev1 tree)))
66             ((pre-dec post-dec) (1- (ev1 tree)))
67             ((pos) (ev1 tree))
68             ((neg) (- (ev1 tree)))
69             ((bw-not) (bitwise-not (ev1 tree)))
70             ((not) (if (zero? (ev1 tree)) 1 0))
71             ((mul) (* (ev1 tree) (ev2 tree)))
72             ((div) (/ (ev1 tree) (ev2 tree)))
73             ((mod) (modulo (ev1 tree) (ev2 tree)))
74             ((add) (+ (ev1 tree) (ev2 tree)))
75             ((sub) (- (ev1 tree) (ev2 tree)))
76             ((lshift) (bitwise-arithmetic-shift-left (ev1 tree) (ev2 tree)))
77             ((rshift) (bitwise-arithmetic-shift-right (ev1 tree) (ev2 tree)))
78             ((lt) (if (< (ev1 tree) (ev2 tree)) 1 0))
79             ((le) (if (<= (ev1 tree) (ev2 tree)) 1 0))
80             ((gt) (if (> (ev1 tree) (ev2 tree)) 1 0))
81             ((ge) (if (>= (ev1 tree) (ev2 tree)) 1 0))
82             ((equal) (if (= (ev1 tree) (ev2 tree)) 1 0))
83             ((noteq) (if (= (ev1 tree) (ev2 tree)) 0 1))
84             ((bw-or) (bitwise-ior (ev1 tree) (ev2 tree)))
85             ((bw-xor) (bitwise-xor (ev1 tree) (ev2 tree)))
86             ((bw-and) (bitwise-and (ev1 tree) (ev2 tree)))
87             ((or) (if (and (zero? (ev1 tree)) (zero? (ev2 tree))) 0 1))
88             ((and) (if (or (zero? (ev1 tree)) (zero? (ev2 tree))) 0 1))
89             ((cond-expr) (if (zero? (ev1 tree)) (ev3 tree) (ev2 tree)))
90             ((ident) (cpp-err "undefined identifier: ~S" (cadr tree)))
91             (else (error "incomplete implementation"))))))
92     (eval-expr tree)))
93
94 ;; @deffn scan-cpp-input argd used dict for-argl => string
95 ;; Process the replacement text and generate a (reversed) token-list.
96 ;; If for-argl, stop at, and push back, @code{,} or @code{)}.
97 (define (scan-cpp-input argd dict used for-argl)
98   ;; Works like this: scan tokens (comments, parens, strings, char's, etc).
99   ;; Tokens (i.e., strings) are collected in a (reverse ordered) list (stl)
100   ;; and merged together on return.  Lone characters are collected in the
101   ;; list @code{chl}.  Once a non-char token is found the character list is
102   ;; converted to a string and added to the string list first, followed by
103   ;; the new token.
104
105   ;; Turn reverse chl into a string and insert it into the string list stl.
106   (define (add-chl chl stl)
107     (if (null? chl) stl (cons (list->string (reverse chl)) stl)))
108
109   ;; We just scanned "defined", not need to scan the arg to inhibit expansion.
110   ;; E.g., scanned "defined", now scan "(FOO)", and return "defined(FOO)".
111   (define (scan-defined)
112     (let iter ((chl '()) (ch (read-char)))
113       (cond ((eof-object? ch) (cpp-err "bad CPP defined"))
114             ((char=? #\) ch)
115              (string-append "defined" (list->string (reverse (cons ch chl)))))
116             (else (iter (cons ch chl) (read-char))))))
117   
118   ;; 
119   (let iter ((stl '())          ; string list (i.e., tokens)
120              (chl '())          ; char-list (current list of input chars)
121              (nxt #f)           ; next string 
122              (lvl 0)            ; level
123              (ch (read-char)))  ; next character
124     (cond
125      ;; have item to add, but first add in char's
126      (nxt (iter (cons nxt (add-chl chl stl)) '() #f lvl ch))
127      ;; If end of string or see end-ch at level 0, then return.
128      ((eof-object? ch)  ;; CHECK (ab++)
129       (apply string-append (reverse (add-chl chl stl))))
130      ((and for-argl (memq ch '(#\) #\,)) (zero? lvl))
131       (unread-char ch) (apply string-append (reverse (add-chl chl stl))))
132      ((read-c-comm ch #f) =>
133       (lambda (cp) (iter stl chl (string-append "/*" (cdr cp) "*/")
134                          lvl (read-char))))
135      ((char=? #\( ch) (iter stl (cons ch chl) nxt (1+ lvl) (read-char)))
136      ((char=? #\) ch) (iter stl (cons ch chl) nxt (1- lvl) (read-char)))
137      ((char=? #\# ch)
138       (let ((ch (read-char)))
139         (if (eqv? ch #\#)
140             (iter (cons "##" stl) chl #f lvl (read-char))
141             (iter (cons "#" stl) chl #f lvl ch))))
142      ((read-c-string ch) =>
143       (lambda (st) (iter stl chl st lvl (read-char))))
144      ((read-c-ident ch) =>
145       (lambda (iden)
146         (if (equal? iden "defined")
147             ;; "defined" is a special case
148             (iter stl chl (scan-defined) lvl (read-char))
149             ;; otherwise ...
150             (let* ((aval (assoc-ref argd iden))  ; lookup argument
151                    (rval (assoc-ref dict iden))) ; lookup macro def
152               (cond
153                ((member iden used)      ; name used
154                 (iter stl chl iden lvl (read-char)))
155                (aval                    ; arg ref
156                 (iter stl chl aval lvl (read-char)))
157                ((string? rval)          ; cpp repl
158                 (iter stl chl rval lvl (read-char)))
159                ((pair? rval)            ; cpp macro
160                 (let* ((argl (car rval)) (text (cdr rval))
161                        (argv (collect-args argd dict used))
162                        (argd (map cons argl argv))
163                        (newl (expand-cpp-repl text argd dict (cons iden used))))
164                   (iter stl chl newl lvl (read-char))))
165                (else                    ; normal identifier
166                 (iter stl chl iden lvl (read-char))))))))
167      (else
168       (iter stl (cons ch chl) #f lvl (read-char))))))
169   
170 (define (collect-args argd dict used)
171   (if (not (eqv? (skip-ws (read-char)) #\()) (cpp-err "CPP expecting `('"))
172   (let iter ((argl (list (scan-cpp-input argd dict used #t))))
173     (let ((ch (read-char)))
174       (if (eqv? ch #\)) (reverse argl)
175           (iter (cons (scan-cpp-input argd dict used #t) argl))))))
176     
177 (define (expand-cpp-repl repl argd dict used)
178   (with-input-from-string repl
179     (lambda () (scan-cpp-input argd dict used #f))))
180
181 ;; @deffn cpp-expand-text text dict => string
182 (define (cpp-expand-text text dict)
183   (with-input-from-string text
184     (lambda () (scan-cpp-input '() dict '() #f))))
185
186 ;; @deffn expand-cpp-mref ident dict => repl|#f
187 ;; Given an identifier seen in C99 input, this checks for associated
188 ;; definition in @var{dict} (generated from CPP defines).  If found,
189 ;; the expansion is returned as a string.  If @var{ident} refers
190 ;; to a macro with arguments, then the arguments will be read from the
191 ;; current input.
192 (define (expand-cpp-mref ident dict . rest)
193   (let ((used (if (pair? rest) (car rest) '()))
194         (rval (assoc-ref dict ident)))
195     (cond
196      ((not rval) #f)
197      ((member ident used) ident)
198      ((string? rval)
199       (let ((expd (expand-cpp-repl rval '() dict (cons ident used))))
200         expd))
201      ((pair? rval)
202       (let* ((args (car rval)) (repl (cdr rval))
203              (argv (collect-args '() dict '()))
204              (argd (map cons args argv))
205              (expd (expand-cpp-repl repl argd dict (cons ident used))))
206         expd)))))
207
208 ;;; --- last line ---