nyacc: fixed C99 use of 'defined XYZ' (no parens)
[mes.git] / module / nyacc / lang / c99 / cppbody.scm
1 ;;; nyacc/lang/c99/cppbody.scm
2 ;;;
3 ;;; Copyright (C) 2016-2017 Matthew R. Wette
4 ;;;
5 ;;; This program is free software: you can redistribute it and/or modify
6 ;;; it under the terms of the GNU General Public License as published by
7 ;;; the Free Software Foundation, either version 3 of the License, or
8 ;;; (at your option) any later version.
9 ;;;
10 ;;; This program is distributed in the hope that it will be useful,
11 ;;; but WITHOUT ANY WARRANTY; without even the implied warranty of
12 ;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
13 ;;; GNU General Public License for more details.
14 ;;;
15 ;;; You should have received a copy of the GNU General Public License
16 ;;; along with this program.  If not, see <http://www.gnu.org/licenses/>.
17
18 (define (cpp-err fmt . args)
19   (apply throw 'cpp-error fmt args))
20
21 ;;.@deffn skip-ws ch
22 (define (skip-ws ch)
23   (if (eof-object? ch) ch
24       (if (char-set-contains? c:ws ch)
25           (skip-ws (read-char))
26           ch)))
27
28 ;; Since we want to be able to get CPP statements with comment in tact
29 ;; (e.g., for passing to @code{pretty-print-c99}) we need to remove
30 ;; comments when parsing CPP expressions.  We convert a comm-reader
31 ;; into a comm-skipper here.  And from that generate a lexer generator.
32 (define cpp-comm-skipper
33   (let ((reader (make-comm-reader '(("/*" . "*/")))))
34     (lambda (ch)
35       (reader ch #f))))
36
37 ;; generate a lexical analyzer per string
38 (define gen-cpp-lexer
39   (make-lexer-generator mtab #:comm-skipper cpp-comm-skipper))
40
41 ;; @deffn parse-cpp-expr text => tree
42 ;; Given a string returns a cpp parse tree.  This is called by
43 ;; @code{eval-cpp-expr}.  The text will have had all CPP defined symbols
44 ;; expanded already so no identifiers should appear in the text.
45 ;; A @code{cpp-error} will be thrown if a parse error occurs.
46 (define (parse-cpp-expr text)
47   (with-throw-handler
48    'nyacc-error
49    (lambda ()
50      (with-input-from-string text
51        (lambda () (raw-parser (gen-cpp-lexer)))))
52    (lambda (key fmt . args)
53      (apply throw 'cpp-error fmt args))))
54
55 ;; @deffn eval-cpp-expr tree dict => datum
56 ;; Evaluate a tree produced from @code{parse-cpp-expr}.
57 ;; The tree passed to this routine is 
58 (define (eval-cpp-expr tree dict)
59   (letrec
60       ((tx (lambda (tr ix) (list-ref tr ix)))
61        (tx1 (lambda (tr) (tx tr 1)))
62        (ev (lambda (ex ix) (eval-expr (list-ref ex ix))))
63        (ev1 (lambda (ex) (ev ex 1)))    ; eval expr in arg 1
64        (ev2 (lambda (ex) (ev ex 2)))    ; eval expr in arg 2
65        (ev3 (lambda (ex) (ev ex 3)))    ; eval expr in arg 3
66        (eval-expr
67         (lambda (tree)
68           (case (car tree)
69             ((fixed) (string->number (tx1 tree)))
70             ((char) (char->integer (tx1 tree)))
71             ((defined) (if (assoc-ref dict (tx1 tree)) 1 0))
72             ((pre-inc post-inc) (1+ (ev1 tree)))
73             ((pre-dec post-dec) (1- (ev1 tree)))
74             ((pos) (ev1 tree))
75             ((neg) (- (ev1 tree)))
76             ((bw-not) (bitwise-not (ev1 tree)))
77             ((not) (if (zero? (ev1 tree)) 1 0))
78             ((mul) (* (ev1 tree) (ev2 tree)))
79             ((div) (/ (ev1 tree) (ev2 tree)))
80             ((mod) (modulo (ev1 tree) (ev2 tree)))
81             ((add) (+ (ev1 tree) (ev2 tree)))
82             ((sub) (- (ev1 tree) (ev2 tree)))
83             ((lshift) (bitwise-arithmetic-shift-left (ev1 tree) (ev2 tree)))
84             ((rshift) (bitwise-arithmetic-shift-right (ev1 tree) (ev2 tree)))
85             ((lt) (if (< (ev1 tree) (ev2 tree)) 1 0))
86             ((le) (if (<= (ev1 tree) (ev2 tree)) 1 0))
87             ((gt) (if (> (ev1 tree) (ev2 tree)) 1 0))
88             ((ge) (if (>= (ev1 tree) (ev2 tree)) 1 0))
89             ((equal) (if (= (ev1 tree) (ev2 tree)) 1 0))
90             ((noteq) (if (= (ev1 tree) (ev2 tree)) 0 1))
91             ((bw-or) (bitwise-ior (ev1 tree) (ev2 tree)))
92             ((bw-xor) (bitwise-xor (ev1 tree) (ev2 tree)))
93             ((bw-and) (bitwise-and (ev1 tree) (ev2 tree)))
94             ((or) (if (and (zero? (ev1 tree)) (zero? (ev2 tree))) 0 1))
95             ((and) (if (or (zero? (ev1 tree)) (zero? (ev2 tree))) 0 1))
96             ((cond-expr) (if (zero? (ev1 tree)) (ev3 tree) (ev2 tree)))
97             ((ident) (cpp-err "undefined identifier: ~S" (cadr tree)))
98             (else (error "incomplete implementation"))))))
99     (eval-expr tree)))
100
101 ;; @deffn scan-cpp-input argd used dict for-argl => string
102 ;; Process the replacement text and generate a (reversed) token-list.
103 ;; If for-argl, stop at, and push back, @code{,} or @code{)}.
104 (define (scan-cpp-input argd dict used for-argl)
105   ;; Works like this: scan tokens (comments, parens, strings, char's, etc).
106   ;; Tokens (i.e., strings) are collected in a (reverse ordered) list (stl)
107   ;; and merged together on return.  Lone characters are collected in the
108   ;; list @code{chl}.  Once a non-char token is found the character list is
109   ;; converted to a string and added to the string list first, followed by
110   ;; the new token.
111
112   ;; Turn reverse chl into a string and insert it into the string list stl.
113   (define (add-chl chl stl)
114     (if (null? chl) stl (cons (list->string (reverse chl)) stl)))
115
116   ;; We just scanned "defined", now need to scan the arg to inhibit expansion.
117   ;; For example, we have scanned "defined"; we now scan "(FOO)" or "FOO", and
118   ;; return "defined(FOO)".  We use ec (end-char) as state indicator: nul at
119   ;; start, #\) on seeing #\( or #\space if other.
120   (define (scan-defined)
121     (let* ((ch (skip-ws (read-char))) (ec (if (char=? ch #\() #\) #\space)))
122       (let iter ((chl '(#\()) (ec ec) (ch ch))
123         (cond
124          ((and (eof-object? ch) (char=? #\space ec))
125           (string-append "defined" (list->string (reverse (cons #\) chl)))))
126          ((eof-object? ch) (cpp-err "illegal argument to `defined'"))
127          ((and (char=? ch #\)) (char=? ec #\)))
128           (string-append "defined" (list->string (reverse (cons ch chl)))))
129          ((char-set-contains? c:ir ch)
130           (iter (cons ch chl) ec (read-char)))
131          (else (cpp-err "illegal identifier"))))))
132
133   (let iter ((stl '())          ; string list (i.e., tokens)
134              (chl '())          ; char-list (current list of input chars)
135              (nxt #f)           ; next string 
136              (lvl 0)            ; level
137              (ch (read-char)))  ; next character
138     (cond
139      ;; have item to add, but first add in char's
140      (nxt (iter (cons nxt (add-chl chl stl)) '() #f lvl ch))
141      ;; If end of string or see end-ch at level 0, then return.
142      ((eof-object? ch)  ;; CHECK (ab++)
143       (apply string-append (reverse (add-chl chl stl))))
144      ((and for-argl (memq ch '(#\) #\,)) (zero? lvl))
145       (unread-char ch) (apply string-append (reverse (add-chl chl stl))))
146      ((read-c-comm ch #f) =>
147       (lambda (cp) (iter stl chl (string-append "/*" (cdr cp) "*/")
148                          lvl (read-char))))
149      ((char=? #\( ch) (iter stl (cons ch chl) nxt (1+ lvl) (read-char)))
150      ((char=? #\) ch) (iter stl (cons ch chl) nxt (1- lvl) (read-char)))
151      ((char=? #\# ch)
152       (let ((ch (read-char)))
153         (if (eqv? ch #\#)
154             (iter (cons "##" stl) chl #f lvl (read-char))
155             (iter (cons "#" stl) chl #f lvl ch))))
156      ((read-c-string ch) =>
157       (lambda (st) (iter stl chl st lvl (read-char))))
158      ((read-c-ident ch) =>
159       (lambda (iden)
160         (if (equal? iden "defined")
161             ;; "defined" is a special case
162             (iter stl chl (scan-defined) lvl (read-char))
163             ;; otherwise ...
164             (let* ((aval (assoc-ref argd iden))  ; lookup argument
165                    (rval (assoc-ref dict iden))) ; lookup macro def
166               (cond
167                ((member iden used)      ; name used
168                 (iter stl chl iden lvl (read-char)))
169                (aval                    ; arg ref
170                 (iter stl chl aval lvl (read-char)))
171                ((string? rval)          ; cpp repl
172                 (iter stl chl rval lvl (read-char)))
173                ((pair? rval)            ; cpp macro
174                 (let* ((argl (car rval)) (text (cdr rval))
175                        (argv (collect-args argd dict used))
176                        (argd (map cons argl argv))
177                        (newl (expand-cpp-repl text argd dict (cons iden used))))
178                   (iter stl chl newl lvl (read-char))))
179                (else                    ; normal identifier
180                 (iter stl chl iden lvl (read-char))))))))
181      (else
182       (iter stl (cons ch chl) #f lvl (read-char))))))
183   
184 (define (collect-args argd dict used)
185   (if (not (eqv? (skip-ws (read-char)) #\()) (cpp-err "CPP expecting `('"))
186   (let iter ((argl (list (scan-cpp-input argd dict used #t))))
187     (let ((ch (read-char)))
188       (if (eqv? ch #\)) (reverse argl)
189           (iter (cons (scan-cpp-input argd dict used #t) argl))))))
190     
191 (define (expand-cpp-repl repl argd dict used)
192   (with-input-from-string repl
193     (lambda () (scan-cpp-input argd dict used #f))))
194
195 ;; @deffn cpp-expand-text text dict => string
196 (define (cpp-expand-text text dict)
197   (with-input-from-string text
198     (lambda () (scan-cpp-input '() dict '() #f))))
199
200 ;; @deffn expand-cpp-mref ident dict => repl|#f
201 ;; Given an identifier seen in C99 input, this checks for associated
202 ;; definition in @var{dict} (generated from CPP defines).  If found,
203 ;; the expansion is returned as a string.  If @var{ident} refers
204 ;; to a macro with arguments, then the arguments will be read from the
205 ;; current input.
206 (define (expand-cpp-mref ident dict . rest)
207   (let ((used (if (pair? rest) (car rest) '()))
208         (rval (assoc-ref dict ident)))
209     (cond
210      ((not rval) #f)
211      ((member ident used) ident)
212      ((string? rval)
213       (let ((expd (expand-cpp-repl rval '() dict (cons ident used))))
214         expd))
215      ((pair? rval)
216       (let* ((args (car rval)) (repl (cdr rval))
217              (argv (collect-args '() dict '()))
218              (argd (map cons args argv))
219              (expd (expand-cpp-repl repl argd dict (cons ident used))))
220         expd)))))
221
222 ;;; --- last line ---