nyacc: lots of fixes to make CPP more robust; now need to test
[mes.git] / module / nyacc / lang / c99 / cppbody.scm
1 ;;; nyacc/lang/c99/cppbody.scm
2 ;;;
3 ;;; Copyright (C) 2016-2017 Matthew R. Wette
4 ;;;
5 ;;; This program is free software: you can redistribute it and/or modify
6 ;;; it under the terms of the GNU General Public License as published by
7 ;;; the Free Software Foundation, either version 3 of the License, or
8 ;;; (at your option) any later version.
9 ;;;
10 ;;; This program is distributed in the hope that it will be useful,
11 ;;; but WITHOUT ANY WARRANTY; without even the implied warranty of
12 ;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
13 ;;; GNU General Public License for more details.
14 ;;;
15 ;;; You should have received a copy of the GNU General Public License
16 ;;; along with this program.  If not, see <http://www.gnu.org/licenses/>.
17
18 (define (cpp-err fmt . args)
19   (apply throw 'cpp-error fmt args))
20
21 ;; Since we want to be able to get CPP statements with comment in tact
22 ;; (e.g., for passing to @code{pretty-print-c99}) we need to remove
23 ;; comments when parsing CPP expressions.  We convert a comm-reader
24 ;; into a comm-skipper here.  And from that generate a lexer generator.
25 (define cpp-comm-skipper
26   (let ((reader (make-comm-reader '(("/*" . "*/")))))
27     (lambda (ch)
28       (reader ch #f))))
29
30 (define gen-cpp-lexer
31   (make-lexer-generator mtab #:comm-skipper cpp-comm-skipper))
32
33 ;; @deffn parse-cpp-expr text => tree
34 ;; Given a string returns a cpp parse tree.  This is called by
35 ;; @code{eval-cpp-expr}.  The text will have had all CPP defined symbols
36 ;; expanded already so no identifiers should appear in the text.
37 ;; A @code{cpp-error} will be thrown if a parse error occurs.
38 (define (parse-cpp-expr text)
39   (catch
40    'nyacc-error
41    (lambda ()
42      (with-input-from-string text
43        (lambda () (raw-parser (gen-cpp-lexer)))))
44    (lambda (key fmt . args)
45      (apply throw 'cpp-error fmt args))))
46
47 ;; @deffn eval-cpp-expr tree dict => datum
48 ;; Evaluate a tree produced from @code{parse-cpp-expr}.
49 ;; The tree passed to this routine is 
50 (define (eval-cpp-expr tree dict)
51   ;;(display "eval-cpp-expr:\n") (pretty-print tree)
52   (letrec
53       ((tx (lambda (tr ix) (list-ref tr ix)))
54        (tx1 (lambda (tr) (tx tr 1)))
55        (ev (lambda (ex ix) (eval-expr (list-ref ex ix))))
56        (ev1 (lambda (ex) (ev ex 1)))    ; eval expr in arg 1
57        (ev2 (lambda (ex) (ev ex 2)))    ; eval expr in arg 2
58        (ev3 (lambda (ex) (ev ex 3)))    ; eval expr in arg 3
59        (eval-expr
60         (lambda (tree)
61           (case (car tree)
62             ((fixed) (string->number (tx1 tree)))
63             ((char) (char->integer (tx1 tree)))
64             ((defined) (if (assoc-ref dict (tx1 tree)) 1 0))
65             ;;
66             ((pre-inc post-inc) (1+ (ev1 tree)))
67             ((pre-dec post-dec) (1- (ev1 tree)))
68             ((pos) (ev1 tree))
69             ((neg) (- (ev1 tree)))
70             ((bw-not) (bitwise-not (ev1 tree)))
71             ((not) (if (zero? (ev1 tree)) 1 0))
72             ((mul) (* (ev1 tree) (ev2 tree)))
73             ((div) (/ (ev1 tree) (ev2 tree)))
74             ((mod) (modulo (ev1 tree) (ev2 tree)))
75             ((add) (+ (ev1 tree) (ev2 tree)))
76             ((sub) (- (ev1 tree) (ev2 tree)))
77             ((lshift) (bitwise-arithmetic-shift-left (ev1 tree) (ev2 tree)))
78             ((rshift) (bitwise-arithmetic-shift-right (ev1 tree) (ev2 tree)))
79             ((lt) (if (< (ev1 tree) (ev2 tree)) 1 0))
80             ((le) (if (<= (ev1 tree) (ev2 tree)) 1 0))
81             ((gt) (if (> (ev1 tree) (ev2 tree)) 1 0))
82             ((ge) (if (>= (ev1 tree) (ev2 tree)) 1 0))
83             ((equal) (if (= (ev1 tree) (ev2 tree)) 1 0))
84             ((noteq) (if (= (ev1 tree) (ev2 tree)) 0 1))
85             ((bw-or) (bitwise-ior (ev1 tree) (ev2 tree)))
86             ((bw-xor) (bitwise-xor (ev1 tree) (ev2 tree)))
87             ((bw-and) (bitwise-and (ev1 tree) (ev2 tree)))
88             ((or) (if (and (zero? (ev1 tree)) (zero? (ev2 tree))) 0 1))
89             ((and) (if (or (zero? (ev1 tree)) (zero? (ev2 tree))) 0 1))
90             ((cond-expr) (if (zero? (ev1 tree)) (ev3 tree) (ev2 tree)))
91             ((ident) (error "text should not have identifiers"))
92             (else (error "incomplete implementation"))))))
93     (catch 'cpp-error
94            (lambda () (eval-expr tree))
95            (lambda () #f))))
96
97
98 ;; @deffn scan-cpp-input argd used dict for-argl => string
99 ;; Process the replacement text and generate a (reversed) token-list.
100 ;; If for-argl, stop at, and push back, @code{,} or @code{)}.
101 (define (scan-cpp-input argd dict used for-argl)
102   ;; Works like this: scan tokens (comments, parens, strings, char's, etc).
103   ;; Tokens (i.e., strings) are collected in a (reverse ordered) list (stl)
104   ;; and merged together on return.  Lone characters are collected in the
105   ;; list @code{chl}.  Once a non-char token is found the character list is
106   ;; converted to a string and added to the string list first, followed by
107   ;; the new token.
108
109   ;; Turn reverse chl into a string and insert it into the string list stl.
110   (define (add-chl chl stl)
111     (if (null? chl) stl (cons (list->string (reverse chl)) stl)))
112
113   ;; We just scanned "defined", not need to scan the arg to inhibit expansion.
114   ;; E.g., scanned "defined", now scan "(FOO)", and return "defined(FOO)".
115   (define (scan-defined)
116     (let iter ((chl '()) (ch (read-char)))
117       (cond ((eof-object? ch) (cpp-err "bad CPP defined"))
118             ((char=? #\) ch)
119              (string-append "defined" (list->string (reverse (cons ch chl)))))
120             (else (iter (cons ch chl) (read-char))))))
121   
122   ;; 
123   (let iter ((stl '())          ; string list (i.e., tokens)
124              (chl '())          ; char-list (current list of input chars)
125              (nxt #f)           ; next string 
126              (lvl 0)            ; level
127              (ch (read-char)))  ; next character
128     (cond
129      ;; have item to add, but first add in char's
130      (nxt (iter (cons nxt (add-chl chl stl)) '() #f lvl ch))
131      ;; If end of string or see end-ch at level 0, then return.
132      ((eof-object? ch)  ;; CHECK (ab++)
133       (apply string-append (reverse (add-chl chl stl))))
134      ((and for-argl (memq ch '(#\) #\,)) (zero? lvl))
135       (unread-char ch) (apply string-append (reverse (add-chl chl stl))))
136      ((read-c-comm ch #f) =>
137       (lambda (cp) (iter stl chl (string-append "/*" (cdr cp) "*/")
138                          lvl (read-char))))
139      ((char=? #\( ch) (iter stl (cons ch chl) nxt (1+ lvl) (read-char)))
140      ((char=? #\) ch) (iter stl (cons ch chl) nxt (1- lvl) (read-char)))
141      ((char=? #\# ch)
142       (let ((ch (read-char)))
143         (if (eqv? ch #\#)
144             (iter (cons "##" stl) chl #f lvl (read-char))
145             (iter (cons "#" stl) chl #f lvl ch))))
146      ((read-c-string ch) =>
147       (lambda (st) (iter stl chl st lvl (read-char))))
148      ((read-c-ident ch) =>
149       (lambda (iden)
150         (if (equal? iden "defined")
151             ;; "defined" is a special case
152             (iter stl chl (scan-defined) lvl (read-char))
153             ;; otherwise ...
154             (let* ((aval (assoc-ref argd iden))  ; lookup argument
155                    (rval (assoc-ref dict iden))) ; lookup macro def
156               (cond
157                ((member iden used)      ; name used
158                 (iter stl chl iden lvl (read-char)))
159                (aval                    ; arg ref
160                 (iter stl chl aval lvl (read-char)))
161                ((string? rval)          ; cpp repl
162                 (iter stl chl rval lvl (read-char)))
163                ((pair? rval)            ; cpp macro
164                 (let* ((argl (car rval)) (text (cdr rval))
165                        (argv (collect-args argd dict used))
166                        (argd (map cons argl argv))
167                        (newl (expand-cpp-repl text argd dict (cons iden used))))
168                   (iter stl chl newl lvl (read-char))))
169                (else                    ; normal identifier
170                 (iter stl chl iden lvl (read-char))))))))
171      (else
172       (iter stl (cons ch chl) #f lvl (read-char))))))
173   
174 (define (collect-args argd dict used)
175   (if (not (eqv? (skip-ws (read-char)) #\()) (cpp-err "CPP expecting `('"))
176   (let iter ((argl (list (scan-cpp-input argd dict used #t))))
177     (let ((ch (read-char)))
178       (if (eqv? ch #\)) (reverse argl)
179           (iter (cons (scan-cpp-input argd dict used #t) argl))))))
180     
181 (define (expand-cpp-repl repl argd dict used)
182   (with-input-from-string repl
183     (lambda () (scan-cpp-input argd dict used #f))))
184
185 ;; @deffn cpp-expand-text text dict => string
186 (define (cpp-expand-text text dict)
187   (with-input-from-string text
188     (lambda () (scan-cpp-input '() dict '() #f))))
189
190 ;; @deffn expand-cpp-mref ident dict => repl|#f
191 ;; Given an identifier seen in C99 input, this checks for associated
192 ;; definition in @var{dict} (generated from CPP defines).  If found,
193 ;; the expansion is returned as a string.  If @var{ident} refers
194 ;; to a macro with arguments, then the arguments will be read from the
195 ;; current input.
196 (define (expand-cpp-mref ident dict . rest)
197   (let ((used (if (pair? rest) (car rest) '()))
198         (rval (assoc-ref dict ident)))
199     (cond
200      ((not rval) #f)
201      ((member ident used) ident)
202      ((string? rval)
203       (let ((expd (expand-cpp-repl rval '() dict (cons ident used))))
204         expd))
205      ((pair? rval)
206       (let* ((args (car rval)) (repl (cdr rval))
207              (argv (collect-args '() dict '()))
208              (argd (map cons args argv))
209              (expd (expand-cpp-repl repl argd dict (cons ident used))))
210         expd)))))
211
212 ;;; --- last line ---