nyacc: CPP working better now
[mes.git] / module / nyacc / lang / c99 / body.scm
1 ;;; lang/c99/body.scm
2 ;;;
3 ;;; Copyright (C) 2015-2017 Matthew R. Wette
4 ;;;
5 ;;; This program is free software: you can redistribute it and/or modify
6 ;;; it under the terms of the GNU General Public License as published by 
7 ;;; the Free Software Foundation, either version 3 of the License, or 
8 ;;; (at your option) any later version.
9 ;;;
10 ;;; This program is distributed in the hope that it will be useful,
11 ;;; but WITHOUT ANY WARRANTY; without even the implied warranty of 
12 ;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
13 ;;; GNU General Public License for more details.
14 ;;;
15 ;;; You should have received a copy of the GNU General Public License
16 ;;; along with this program.  If not, see <http://www.gnu.org/licenses/>.
17
18 ;; @section The C99 Parser Body
19 ;; This code provides the front end to the C99 parser, including the lexical
20 ;; analyzer and optional CPP processing.  In @code{'file} mode the lex'er
21 ;; passes CPP statements to the parser; in @code{'code} mode the lex'er
22 ;; parses and evaluates the CPP statements.  In the case of included files
23 ;; (e.g., via @code{#include <file.h>}) the include files are parsed if
24 ;; not in the @code{td-dict}.  The @code{td-dict} is a dictionary that maps
25 ;; include file names to typedefs (e.g., @code{stdio.h} to @code{FILE}).
26
27 (use-modules ((srfi srfi-9) #:select (define-record-type)))
28 (use-modules ((sxml xpath) #:select (sxpath)))
29
30 (define c99-std-dict
31   '(("alloca.h")
32     ("complex.h" "complex" "imaginary")
33     ("ctype.h")
34     ("fenv.h" "fenv_t" "fexcept_t")
35     ("float.h" "float_t")
36     ("inttypes.h"
37      "int8_t" "uint8_t" "int16_t" "uint16_t" "int32_t" "uint32_t"
38      "int64_t" "uint64_t" "uintptr_t" "intptr_t" "intmax_t" "uintmax_t"
39      "int_least8_t" "uint_least8_t" "int_least16_t" "uint_least16_t"
40      "int_least32_t" "uint_least32_t" "int_least64_t" "uint_least64_t"
41      "imaxdiv_t")
42     ("limits.h")
43     ("math.h")
44     ("regex.h" "regex_t" "regmatch_t")
45     ("setjmp.h" "jmp_buf")
46     ("signal.h" "sig_atomic_t")
47     ("stdarg.h" "va_list")
48     ("stddef.h" "ptrdiff_t" "size_t" "wchar_t")
49     ("stdint.h"
50      "int8_t" "uint8_t" "int16_t" "uint16_t" "int32_t" "uint32_t"
51      "int64_t" "uint64_t" "uintptr_t" "intptr_t" "intmax_t" "uintmax_t"
52      "int_least8_t" "uint_least8_t" "int_least16_t" "uint_least16_t"
53      "int_least32_t" "uint_least32_t" "int_least64_t" "uint_least64_t")
54     ("stdio.h" "FILE" "size_t")
55     ("stdlib.h" "div_t" "ldiv_t" "lldiv_t" "wchar_t")
56     ("string.h" "size_t")
57     ("strings.h" "size_t")
58     ("time.h" "time_t" "clock_t" "size_t")
59     ("unistd.h" "size_t" "ssize_t" "div_t" "ldiv_t")
60     ("wchar.h" "wchar_t" "wint_t" "mbstate_t" "size_t")
61     ("wctype.h" "wctrans_t" "wctype_t" "wint_t")
62     ))
63
64 ;; @subsubsection CPP if-then-else Logic Block (ITLB) Processing
65 ;; The parser needs to have a "CPI" (CPP processing info) stack to deal with
66 ;; types (re)defined in multiple branches of a #if...#endif statement chain.
67 ;; If we are in "code" mode then we may be skipping code so need to track
68 ;; when to shift and when not to.
69 ;; 
70 ;; The state is contained in a stack @code{ppxs}
71 ;; States are
72 ;; @table code
73 ;; @item skip-done
74 ;; skip code
75 ;; @item skip-look
76 ;; skipping code, but still looking for true at this level
77 ;; @item keep
78 ;; keep code
79 ;; @item skip1-pop
80 ;; skip one token and pop skip-stack
81 ;; @end table
82 ;; Also, if we want to pass on all the sections of an ITLB to the parser
83 ;; we need to remove typedef names because a typedef may appear multiple
84 ;; times, as in
85 ;; @example
86 ;; #ifdef SIXTYFOURBIT
87 ;; typedef short int32_t;
88 ;; #else
89 ;; typedef long int32_t;
90 ;; #endif
91 ;; @end example
92 ;; @noindent
93 ;; To achieve this we keep a stack of valid typedefs.  On @code{#if} we push,
94 ;; on @code{#elif} we shift (i.e., pop, then push) and on @code{#endif} we pop.
95 ;;
96 ;; The grammar looks like
97 ;; @example
98 ;; (code
99 ;;  ("if" cond code "endif")
100 ;;  ("if" cond code "else" code "endif")
101 ;;  ("if" cond code elif-list "endif")
102 ;;  ("if" cond code elif-list "else" code "endif")
103 ;;  (other))
104 ;; (elif-list
105 ;;  ("elif" cond code)
106 ;;  (elif-list "elif" cond code))
107 ;; @end example
108 ;; @noindent
109
110 (define-record-type cpi
111   (make-cpi-1)
112   cpi?
113   (debug cpi-debug set-cpi-debug!)      ; debug #t #f
114   (defines cpi-defs set-cpi-defs!)      ; #defines
115   (incdirs cpi-incs set-cpi-incs!)      ; #includes
116   (tn-dict cpi-tynd set-cpi-tynd!)      ; typename dict (("<x>" foo_t ..
117   (ptl cpi-ptl set-cpi-ptl!)            ; parent typename list
118   (ctl cpi-ctl set-cpi-ctl!)            ; current typename list
119   )
120
121 (define (make-cpi debug defines incdirs tn-dict)
122   (let* ((cpi (make-cpi-1)))
123     (set-cpi-debug! cpi debug)    ; print states debug 
124     (set-cpi-defs! cpi defines)   ; list of define strings??
125     (set-cpi-incs! cpi incdirs)   ; list of include dir's
126     (set-cpi-tynd! cpi tn-dict)   ; typename dict by include-file name
127     (set-cpi-ptl! cpi '())        ; list of lists of typedef strings
128     (set-cpi-ctl! cpi '())        ; list of typedef strings
129     cpi))
130
131 (define *info* (make-fluid #f))
132
133 ;; given tyns
134 ;; cadr is next level
135 ;; caar is list of sibs
136 ;; search (caar car tyns), then (caar cadr tyns), then ...
137
138 ;; @deffn typename? name
139 ;; Called by lexer to determine if symbol is a typename.
140 ;; Check current sibling for each generation.
141 (define (typename? name)
142   (let ((cpi (fluid-ref *info*)))
143     (if (member name (cpi-ctl cpi)) #t
144         (let iter ((ptl (cpi-ptl cpi)))
145           (if (null? ptl) #f
146               (if (member name (car ptl)) #t
147                   (iter (cdr ptl))))))))
148
149 ;; @deffn add-typename name
150 ;; Helper for @code{save-typenames}.
151 (define (add-typename name)
152   (let ((cpi (fluid-ref *info*)))
153     (set-cpi-ctl! cpi (cons name (cpi-ctl cpi)))))
154
155 (define (cpi-push)      ;; on #if
156   (let ((cpi (fluid-ref *info*)))
157     (set-cpi-ptl! cpi (cons (cpi-ctl cpi) (cpi-ptl cpi)))
158     (set-cpi-ctl! cpi '())))
159
160 (define (cpi-shift)     ;; on #elif #else
161   (set-cpi-ctl! (fluid-ref *info*) '()))
162
163 (define (cpi-pop)       ;; on #endif
164   (let ((cpi (fluid-ref *info*)))
165     (set-cpi-ctl! cpi (append (cpi-ctl cpi) (car (cpi-ptl cpi))))
166     (set-cpi-ptl! cpi (cdr (cpi-ptl cpi)))))
167
168 ;; @deffn find-new-typenames decl
169 ;; Helper for @code{save-typenames}.
170 ;; Given declaration return a list of new typenames (via @code{typedef}).
171 (define (find-new-typenames decl)
172
173   ;; like declr->ident in util2.scm
174   (define (declr->id-name declr)
175     (case (car declr)
176       ((ident) (sx-ref declr 1))
177       ((init-declr) (declr->id-name (sx-ref declr 1)))
178       ((comp-declr) (declr->id-name (sx-ref declr 1)))
179       ((array-of) (declr->id-name (sx-ref declr 1)))
180       ((ptr-declr) (declr->id-name (sx-ref declr 2)))
181       ((ftn-declr) (declr->id-name (sx-ref declr 1)))
182       ((scope) (declr->id-name (sx-ref declr 1)))
183       (else (error "coding bug: " declr))))
184        
185   (let* ((spec (sx-ref decl 1))
186          (stor (sx-find 'stor-spec spec))
187          (id-l (sx-ref decl 2)))
188     (if (and stor (eqv? 'typedef (caadr stor)))
189         (let iter ((res '()) (idl (cdr id-l)))
190           (if (null? idl) res
191               (iter (cons (declr->id-name (sx-ref (car idl) 1)) res)
192                     (cdr idl))))
193         '())))
194
195 ;; @deffn save-typenames decl
196 ;; Save the typenames for the lexical analyzer and return the decl.
197 (define (save-typenames decl)
198   ;; This finds typenames using @code{find-new-typenames} and adds via
199   ;; @code{add-typename}.  Then return the decl.
200   (for-each add-typename (find-new-typenames decl))
201   decl)
202
203 ;; ------------------------------------------------------------------------
204
205 (define (p-err . args)
206   (apply throw 'c99-error args))
207
208 ;; @deffn read-cpp-line ch => #f | (cpp-xxxx)??
209 ;; Given if ch is #\# read a cpp-statement.
210 ;; The standard implies that comments are tossed here but we keep them
211 ;; so that they can end up in the pretty-print output.
212 (define (read-cpp-line ch)
213   (if (not (eq? ch #\#)) #f
214       (let iter ((cl '()) (ch (read-char)))
215         (cond
216          ((eq? ch #\newline) (unread-char ch) (list->string (reverse cl)))
217          ((eq? ch #\\)
218           (let ((c2 (read-char)))
219             (if (eq? c2 #\newline)
220                 (iter cl (read-char))
221                 (iter (cons* c2 ch cl) (read-char)))))
222          ((eq? ch #\/) ;; swallow comments, event w/ newlines
223           (let ((c2 (read-char)))
224             (cond
225              ((eqv? c2 #\*)
226               (let iter2 ((cl2 (cons* #\* #\/ cl)) (ch (read-char)))
227                 (cond
228                  ((eq? ch #\*)
229                   (let ((c2 (read-char)))
230                     (if (eqv? c2 #\/)
231                         (iter (cons* #\/ #\* cl2) (read-char)) ;; keep comment
232                         (iter2 (cons #\* cl2) c2))))
233                  (else
234                   (iter2 (cons ch cl2) (read-char))))))
235              (else
236               (iter (cons #\/ cl) c2)))))
237          (else (iter (cons ch cl) (read-char)))))))
238
239 ;; @deffn find-file-in-dirl file dirl => path
240 (define (find-file-in-dirl file dirl)
241   (let iter ((dirl dirl))
242     (if (null? dirl) #f
243         (let ((p (string-append (car dirl) "/" file)))
244           (if (access? p R_OK) p (iter (cdr dirl)))))))
245
246 (define (def-xdef? name mode)
247   (eqv? mode 'code))
248
249 ;; @deffn gen-c-lexer [#:mode mode] [#:xdef? proc] => procedure
250 ;; Generate a context-sensitive lexer for the C99 language.  The generated
251 ;; lexical analyzer reads and passes comments and optionally CPP statements
252 ;; to the parser.  The keyword argument @var{mode} will determine if CPP
253 ;; statements are passed (@code{'file} mode) or parsed and executed
254 ;; (@code{'file} mode) as described above.  Comments will be passed as
255 ;; ``line'' comments or ``lone'' comments: lone comments appear on a line
256 ;; without code.  The @code{xdef?} keyword argument allows user to pass
257 ;; a predicate which determines whether CPP symbols in code are expanded.
258 ;; The default predicate is
259 ;; @example
260 ;; (define (def-xdef? mode name) (eqv? mode 'code))
261 ;; @end example
262 (define gen-c-lexer
263   ;; This gets ugly in order to handle cpp.
264   ;;.need to add support for num's w/ letters like @code{14L} and @code{1.3f}.
265   ;; todo: I think there is a bug wrt the comment reader because // ... \n
266   ;; will end up in same mode...  so after
267   ;; int x; // comment
268   ;; the lexer will think we are not at BOL.
269   (let* ((match-table mtab)
270          (read-ident read-c-ident)
271          (read-comm read-c-comm)
272          ;;
273          (ident-like? (make-ident-like-p read-ident))
274          ;;
275          (strtab (filter-mt string? match-table)) ; strings in grammar
276          (kwstab (filter-mt ident-like? strtab))  ; keyword strings =>
277          (keytab (map-mt string->symbol kwstab))  ; keywords in grammar
278          (chrseq (remove-mt ident-like? strtab))  ; character sequences
279          (symtab (filter-mt symbol? match-table)) ; symbols in grammar
280          (chrtab (filter-mt char? match-table))   ; characters in grammar
281          ;;
282          (read-chseq (make-chseq-reader chrseq))
283          (assc-$ (lambda (pair) (cons (assq-ref symtab (car pair)) (cdr pair))))
284          ;;
285          (t-ident (assq-ref symtab '$ident))
286          (t-typename (assq-ref symtab 'typename))
287          (xp1 (sxpath '(cpp-stmt define)))
288          (xp2 (sxpath '(decl))))
289     ;; mode: 'code|'file
290     ;; xdef?: (proc name mode) => #t|#f  : do we expand #define?
291     (lambda* (#:key (mode 'code) (xdef? #f))
292       (let ((bol #t)                  ; begin-of-line condition
293             (ppxs (list 'keep))       ; CPP execution state stack
294             (info (fluid-ref *info*)) ; assume make and run in same thread
295             (x-def? (or xdef? def-xdef?)))
296         ;; Return the first (tval . lval) pair not excluded by the CPP.
297         (lambda ()
298
299           (define (exec-cpp-stmts?)     ; exec (vs pass to parser) CPP stmts?
300             (eqv? mode 'code))
301       
302           (define (add-define tree)
303             (let* ((tail (cdr tree))
304                    (name (car (assq-ref tail 'name)))
305                    (args (assq-ref tail 'args))
306                    (repl (car (assq-ref tail 'repl)))
307                    (cell (cons name (if args (cons args repl) repl))))
308               (set-cpi-defs! info (cons cell (cpi-defs info)))))
309           
310           (define (rem-define name)
311               (set-cpi-defs! info (delete name (cpi-defs info))))
312           
313           ;; Evaluate expression text in #if of #elif statement.
314           (define (eval-cpp-cond-text text)
315             (with-throw-handler
316              'cpp-error
317              (lambda ()
318                (let* ((defs (cpi-defs info))
319                       (rhs (cpp-expand-text text defs))
320                       (exp (parse-cpp-expr rhs)))
321                  (eval-cpp-expr exp defs)))
322              (lambda (key fmt . args)
323                (report-error fmt args)
324                (throw 'c99-error "CPP error"))))
325             
326           (define (eval-cpp-stmt stmt)
327             (case (car stmt)
328               ((include)
329                (let* ((parg (cadr stmt)) (leng (string-length parg))
330                       (file (substring parg 1 (1- leng)))
331                       (path (find-file-in-dirl file (cpi-incs info)))
332                       (tynd (assoc-ref (cpi-tynd info) file)))
333                  (cond
334                   (tynd (for-each add-typename tynd)) ; in dot-h dict
335                   ((not path) (p-err "not found: ~S" file))
336                   ((exec-cpp-stmts?) (push-input (open-input-file path)))
337                   (else         ; include as tree
338                    (let* ((tree (with-input-from-file path run-parse)))
339                      (if (not tree) (p-err "included from ~S" path))
340                      (for-each add-define (xp1 tree)) ; add def's 
341                      (set! stmt (append stmt (list tree)))))))
342                (if (exec-cpp-stmts?) (set! ppxs (cons 'skip1-pop ppxs))))
343               ((define)
344                (add-define stmt)
345                (if (exec-cpp-stmts?) (set! ppxs (cons 'skip1-pop ppxs))))
346               ((undef)
347                (rem-define (cadr stmt))
348                (if (exec-cpp-stmts?) (set! ppxs (cons 'skip1-pop ppxs))))
349               ((if) ;; covers (if ifdef ifndef)
350                (cond
351                 ((exec-cpp-stmts?)
352                  (let ((val (eval-cpp-cond-text (cadr stmt))))
353                    (cond
354                     ((not val) (p-err "unresolved: ~S" (cadr stmt)))
355                     ((zero? val) (set! ppxs (cons* 'skip1-pop 'skip-look ppxs)))
356                     (else (set! ppxs (cons* 'skip1-pop (car ppxs) ppxs))))))
357                 (else (cpi-push))))
358               ((elif)
359                (cond
360                 ((exec-cpp-stmts?)
361                  (let ((val (eval-cpp-cond-text (cadr stmt))))
362                    (cond
363                     ((not val)
364                      (p-err "unresolved: ~S" (cadr stmt)))
365                     ((eq? 'keep (car ppxs))
366                      (set! ppxs (cons* 'skip1-pop 'skip-done (cdr ppxs))))
367                     ((zero? val) (set! ppxs (cons* 'skip1-pop ppxs)))
368                     ((eq? 'skip-look (car ppxs))
369                      (set! ppxs (cons* 'skip1-pop 'keep (cdr ppxs))))
370                     (else
371                      (set! ppxs (cons* 'skip1-pop 'skip-done (cdr ppxs)))))))
372                 (else (cpi-shift))))
373               ((else)
374                (cond
375                 ((exec-cpp-stmts?)
376                  (cond
377                   ((eq? 'skip-look (car ppxs))
378                    (set! ppxs (cons* 'skip1-pop 'keep (cdr ppxs))))
379                   (else
380                    (set! ppxs (cons* 'skip1-pop 'skip-done (cdr ppxs))))))
381                 (else (cpi-shift))))
382               ((endif)
383                (cond
384                 ((exec-cpp-stmts?)
385                  (set! ppxs (cons 'skip1-pop (cdr ppxs))))
386                 (else (cpi-pop))))
387               ((error)
388                (if (exec-cpp-stmts?)
389                    (report-error "error: #error ~A" (cdr stmt))))
390               ((pragma)
391                ;; standard says implementation-defined if line is expanded
392                #t)
393               (else
394                (error "unhandled cpp stmt")))
395             (case (car stmt)
396               ((pragma) (cons 'cpp-pragma (cdr stmt)))
397               (else (cons 'cpp-stmt stmt))))
398           
399           (define (eval-cpp-line line)
400             (with-throw-handler
401              'cpp-error
402              (lambda () (eval-cpp-stmt (read-cpp-stmt line)))
403              (lambda (key fmt . rest)
404                (display "body.399\n")
405                (report-error fmt rest)
406                (throw 'c99-error "CPP error"))))
407
408           ;; Composition of @code{read-cpp-line} and @code{eval-cpp-line}.
409           (define (read-cpp ch)
410             (and=> (read-cpp-line ch) eval-cpp-line))
411
412           (define (read-token)
413             (let iter ((ch (read-char)))
414               (cond
415                ((eof-object? ch)
416                 (if (pop-input) (iter (read-char)) (assc-$ '($end . ""))))
417                ((eq? ch #\newline) (set! bol #t) (iter (read-char)))
418                ((char-set-contains? c:ws ch) (iter (read-char)))
419                (bol
420                 (cond
421                  ((read-comm ch bol) => assc-$)
422                  ((read-cpp ch) =>
423                   (lambda (res) ;; if '() stmt expanded so re-read
424                     (if (pair? res) (assc-$ res) (iter (read-char)))))
425                  (else (set! bol #f) (iter ch))))
426                ((read-ident ch) =>
427                 (lambda (name)
428                   (let ((symb (string->symbol name)))
429                     (cond
430                      ((and (x-def? name mode)
431                            (expand-cpp-mref name (cpi-defs info)))
432                       => (lambda (st)
433                            (push-input (open-input-string st))
434                            (iter (read-char))))
435                      ((assq-ref keytab symb)
436                       => (lambda (t) (cons t name)))
437                      ((typename? name)
438                       (cons (assq-ref symtab 'typename) name))
439                      (else
440                       (cons (assq-ref symtab '$ident) name))))))
441                ((read-c-num ch) => assc-$)
442                ((read-c-string ch) => assc-$)
443                ((read-c-chlit ch) => assc-$)
444                ((read-comm ch bol) => assc-$)
445                ((read-chseq ch) => identity)
446                ((assq-ref chrtab ch) => (lambda (t) (cons t (string ch))))
447                ((eqv? ch #\\) ;; C allows \ at end of line to continue
448                 (let ((ch (read-char)))
449                   (cond ((eqv? #\newline ch) (iter (read-char))) ;; extend line
450                         (else (unread-char ch) (cons #\\ "\\"))))) ;; parse err
451                (else (cons ch (string ch))))))
452
453           ;; Loop between reading tokens and skipping tokens via CPP logic.
454           (let iter ((pair (read-token)))
455             (case (car ppxs)
456               ((keep) pair)
457               ((skip-done skip-look)
458                (iter (read-token)))
459               ((skip1-pop)
460                (set! ppxs (cdr ppxs))
461                (iter (read-token)))))
462           )))))
463   
464 ;; --- last line ---