f7eb9dd2a96b5583548749d64f0c85458e457061
[mes.git] / module / nyacc / lang / c99 / body.scm
1 ;;; lang/c99/body.scm
2 ;;;
3 ;;; Copyright (C) 2015-2017 Matthew R. Wette
4 ;;;
5 ;;; This program is free software: you can redistribute it and/or modify
6 ;;; it under the terms of the GNU General Public License as published by 
7 ;;; the Free Software Foundation, either version 3 of the License, or 
8 ;;; (at your option) any later version.
9 ;;;
10 ;;; This program is distributed in the hope that it will be useful,
11 ;;; but WITHOUT ANY WARRANTY; without even the implied warranty of 
12 ;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
13 ;;; GNU General Public License for more details.
14 ;;;
15 ;;; You should have received a copy of the GNU General Public License
16 ;;; along with this program.  If not, see <http://www.gnu.org/licenses/>.
17
18 ;; @section The C99 Parser Body
19 ;; This code provides the front end to the C99 parser, including the lexical
20 ;; analyzer and optional CPP processing.  In @code{'file} mode the lex'er
21 ;; passes CPP statements to the parser; in @code{'code} mode the lex'er
22 ;; parses and evaluates the CPP statements.  In the case of included files
23 ;; (e.g., via @code{#include <file.h>}) the include files are parsed if
24 ;; not in the @code{td-dict}.  The @code{td-dict} is a dictionary that maps
25 ;; include file names to typedefs (e.g., @code{stdio.h} to @code{FILE}).
26
27 (use-modules ((srfi srfi-9) #:select (define-record-type)))
28 (use-modules ((sxml xpath) #:select (sxpath)))
29
30 (define c99-std-dict
31   '(("alloca.h")
32     ("complex.h" "complex" "imaginary")
33     ("ctype.h")
34     ("fenv.h" "fenv_t" "fexcept_t")
35     ("float.h" "float_t")
36     ("inttypes.h"
37      "int8_t" "uint8_t" "int16_t" "uint16_t" "int32_t" "uint32_t"
38      "int64_t" "uint64_t" "uintptr_t" "intptr_t" "intmax_t" "uintmax_t"
39      "int_least8_t" "uint_least8_t" "int_least16_t" "uint_least16_t"
40      "int_least32_t" "uint_least32_t" "int_least64_t" "uint_least64_t"
41      "imaxdiv_t")
42     ("limits.h")
43     ("math.h")
44     ("regex.h" "regex_t" "regmatch_t")
45     ("setjmp.h" "jmp_buf")
46     ("signal.h" "sig_atomic_t")
47     ("stdarg.h" "va_list")
48     ("stddef.h" "ptrdiff_t" "size_t" "wchar_t")
49     ("stdint.h"
50      "int8_t" "uint8_t" "int16_t" "uint16_t" "int32_t" "uint32_t"
51      "int64_t" "uint64_t" "uintptr_t" "intptr_t" "intmax_t" "uintmax_t"
52      "int_least8_t" "uint_least8_t" "int_least16_t" "uint_least16_t"
53      "int_least32_t" "uint_least32_t" "int_least64_t" "uint_least64_t")
54     ("stdio.h" "FILE" "size_t")
55     ("stdlib.h" "div_t" "ldiv_t" "lldiv_t" "wchar_t")
56     ("string.h" "size_t")
57     ("time.h" "time_t" "clock_t" "size_t")
58     ("unistd.h" "size_t" "ssize_t" "div_t" "ldiv_t")
59     ("wchar.h" "wchar_t" "wint_t" "mbstate_t" "size_t")
60     ("wctype.h" "wctrans_t" "wctype_t" "wint_t")
61     ))
62
63 ;; @subsubsection CPP if-then-else Logic Block (ITLB) Processing
64 ;; The parser needs to have a "CPI" (CPP processing info) stack to deal with
65 ;; types (re)defined in multiple branches of a #if...#endif statement chain.
66 ;; If we are in "code" mode then we may be skipping code so need to track
67 ;; when to shift and when not to.
68 ;; 
69 ;; The state is contained in a stack @code{ppxs}
70 ;; States are
71 ;; @table code
72 ;; @item skip-done
73 ;; skip code
74 ;; @item skip-look
75 ;; skipping code, but still looking for true at this level
76 ;; @item keep
77 ;; keep code
78 ;; @item skip1-pop
79 ;; skip one token and pop skip-stack
80 ;; @end table
81 ;; Also, if we want to pass on all the sections of an ITLB to the parser
82 ;; we need to remove typedef names because a typedef may appear multiple
83 ;; times, as in
84 ;; @example
85 ;; #ifdef SIXTYFOURBIT
86 ;; typedef short int32_t;
87 ;; #else
88 ;; typedef long int32_t;
89 ;; #endif
90 ;; @end example
91 ;; @noindent
92 ;; To achieve this we keep a stack of valid typedefs.  On @code{#if} we push,
93 ;; on @code{#elif} we shift (i.e., pop, then push) and on @code{#endif} we pop.
94 ;;
95 ;; The grammar looks like
96 ;; @example
97 ;; (code
98 ;;  ("if" cond code "endif")
99 ;;  ("if" cond code "else" code "endif")
100 ;;  ("if" cond code elif-list "endif")
101 ;;  ("if" cond code elif-list "else" code "endif")
102 ;;  (other))
103 ;; (elif-list
104 ;;  ("elif" cond code)
105 ;;  (elif-list "elif" cond code))
106 ;; @end example
107 ;; @noindent
108
109 (define-record-type cpi
110   (make-cpi-1)
111   cpi?
112   (debug cpi-debug set-cpi-debug!)      ; debug #t #f
113   (defines cpi-defs set-cpi-defs!)      ; #defines
114   (incdirs cpi-incs set-cpi-incs!)      ; #includes
115   (tn-dict cpi-tynd set-cpi-tynd!)      ; typename dict (("<x>" foo_t ..
116   (ptl cpi-ptl set-cpi-ptl!)            ; parent typename list
117   (ctl cpi-ctl set-cpi-ctl!)            ; current typename list
118   )
119
120 (define (make-cpi debug defines incdirs tn-dict)
121   (let* ((cpi (make-cpi-1)))
122     (set-cpi-debug! cpi debug)    ; print states debug 
123     (set-cpi-defs! cpi defines)   ; list of define strings??
124     (set-cpi-incs! cpi incdirs)   ; list of include dir's
125     (set-cpi-tynd! cpi tn-dict)   ; typename dict by include-file name
126     (set-cpi-ptl! cpi '())        ; list of lists of typedef strings
127     (set-cpi-ctl! cpi '())        ; list of typedef strings
128     cpi))
129
130 (define *info* (make-fluid #f))
131
132 ;; given tyns
133 ;; cadr is next level
134 ;; caar is list of sibs
135 ;; search (caar car tyns), then (caar cadr tyns), then ...
136
137 ;; @deffn typename? name
138 ;; Called by lexer to determine if symbol is a typename.
139 ;; Check current sibling for each generation.
140 (define (typename? name)
141   (let ((cpi (fluid-ref *info*)))
142     (if (member name (cpi-ctl cpi)) #t
143         (let iter ((ptl (cpi-ptl cpi)))
144           (if (null? ptl) #f
145               (if (member name (car ptl)) #t
146                   (iter (cdr ptl))))))))
147
148 ;; @deffn add-typename name
149 ;; Helper for @code{save-typenames}.
150 (define (add-typename name)
151   (let ((cpi (fluid-ref *info*)))
152     (set-cpi-ctl! cpi (cons name (cpi-ctl cpi)))))
153
154 (define (cpi-push)      ;; on #if
155   (let ((cpi (fluid-ref *info*)))
156     (set-cpi-ptl! cpi (cons (cpi-ctl cpi) (cpi-ptl cpi)))
157     (set-cpi-ctl! cpi '())))
158
159 (define (cpi-shift)     ;; on #elif #else
160   (set-cpi-ctl! (fluid-ref *info*) '()))
161
162 (define (cpi-pop)       ;; on #endif
163   (let ((cpi (fluid-ref *info*)))
164     (set-cpi-ctl! cpi (append (cpi-ctl cpi) (car (cpi-ptl cpi))))
165     (set-cpi-ptl! cpi (cdr (cpi-ptl cpi)))))
166
167 ;; @deffn find-new-typenames decl
168 ;; Helper for @code{save-typenames}.
169 ;; Given declaration return a list of new typenames (via @code{typedef}).
170 (define (find-new-typenames decl)
171
172   ;; like declr->ident in util2.scm
173   (define (declr->id-name declr)
174     (case (car declr)
175       ((ident) (sx-ref declr 1))
176       ((init-declr) (declr->id-name (sx-ref declr 1)))
177       ((comp-declr) (declr->id-name (sx-ref declr 1)))
178       ((array-of) (declr->id-name (sx-ref declr 1)))
179       ((ptr-declr) (declr->id-name (sx-ref declr 2)))
180       ((ftn-declr) (declr->id-name (sx-ref declr 1)))
181       ((scope) (declr->id-name (sx-ref declr 1)))
182       (else (error "coding bug: " declr))))
183        
184   (let* ((spec (sx-ref decl 1))
185          (stor (sx-find 'stor-spec spec))
186          (id-l (sx-ref decl 2)))
187     (if (and stor (eqv? 'typedef (caadr stor)))
188         (let iter ((res '()) (idl (cdr id-l)))
189           (if (null? idl) res
190               (iter (cons (declr->id-name (sx-ref (car idl) 1)) res)
191                     (cdr idl))))
192         '())))
193
194 ;; @deffn save-typenames decl
195 ;; Save the typenames for the lexical analyzer and return the decl.
196 (define (save-typenames decl)
197   ;; This finds typenames using @code{find-new-typenames} and adds via
198   ;; @code{add-typename}.  Then return the decl.
199   (for-each add-typename (find-new-typenames decl))
200   decl)
201
202 ;; ------------------------------------------------------------------------
203
204 (define (p-err . args)
205   (apply throw 'c99-error args))
206
207 ;; @deffn read-cpp-line ch => #f | (cpp-xxxx)??
208 ;; Given if ch is #\# read a cpp-statement
209 ;; includes BUG: #define ABC 123 /* \n
210 (define (read-cpp-line ch)
211   (if (not (eq? ch #\#)) #f
212       (let iter ((cl '()) (ch (read-char)))
213         (cond
214          ((eq? ch #\newline) (unread-char ch) (list->string (reverse cl)))
215          ((eq? ch #\\)
216           (let ((c2 (read-char)))
217             (if (eq? c2 #\newline)
218                 (iter cl (read-char))
219                 (iter (cons* c2 ch cl) (read-char)))))
220          ((eq? ch #\/) ;; swallow comments, event w/ newlines
221           (let ((c2 (read-char)))
222             (cond
223              ((eqv? c2 #\*)
224               (let iter2 ((cl2 (cons* #\* #\/ cl)) (ch (read-char)))
225                 (cond
226                  ((eq? ch #\*)
227                   (let ((c2 (read-char)))
228                     (if (eqv? c2 #\/)
229                         (iter (cons* #\/ #\* cl2) (read-char)) ;; keep comment
230                         ;;(iter cl (read-char)) ;; toss comment
231                         (iter2 (cons #\* cl2) c2))))
232                  (else
233                   (iter2 (cons ch cl2) (read-char))))))
234              (else
235               (iter (cons #\/ cl) c2)))))
236          (else (iter (cons ch cl) (read-char)))))))
237
238 ;; @deffn find-file-in-dirl file dirl => path
239 (define (find-file-in-dirl file dirl)
240   (let iter ((dirl dirl))
241     (if (null? dirl) #f
242         (let ((p (string-append (car dirl) "/" file)))
243           (if (access? p R_OK) p (iter (cdr dirl)))))))
244
245 (define (def-xdef? name mode)
246   (eqv? mode 'code))
247
248 ;; @deffn gen-c-lexer [#:mode mode] [#:xdef? proc] => procedure
249 ;; Generate a context-sensitive lexer for the C99 language.  The generated
250 ;; lexical analyzer reads and passes comments and optionally CPP statements
251 ;; to the parser.  The keyword argument @var{mode} will determine if CPP
252 ;; statements are passed (@code{'file} mode) or parsed and executed
253 ;; (@code{'file} mode) as described above.  Comments will be passed as
254 ;; ``line'' comments or ``lone'' comments: lone comments appear on a line
255 ;; without code.  The @code{xdef?} keyword argument allows user to pass
256 ;; a predicate which determines whether CPP symbols in code are expanded.
257 ;; The default predicate is
258 ;; @example
259 ;; (define (def-xdef? mode name) (eqv? mode 'code))
260 ;; @end example
261 (define gen-c-lexer
262   ;; This gets ugly in order to handle cpp.
263   ;;.need to add support for num's w/ letters like @code{14L} and @code{1.3f}.
264   ;; todo: I think there is a bug wrt the comment reader because // ... \n
265   ;; will end up in same mode...  so after
266   ;; int x; // comment
267   ;; the lexer will think we are not at BOL.
268   (let* ((match-table mtab)
269          (read-ident read-c-ident)
270          (read-comm read-c-comm)
271          ;;
272          (ident-like? (make-ident-like-p read-ident))
273          ;;
274          (strtab (filter-mt string? match-table)) ; strings in grammar
275          (kwstab (filter-mt ident-like? strtab))  ; keyword strings =>
276          (keytab (map-mt string->symbol kwstab))  ; keywords in grammar
277          (chrseq (remove-mt ident-like? strtab))  ; character sequences
278          (symtab (filter-mt symbol? match-table)) ; symbols in grammar
279          (chrtab (filter-mt char? match-table))   ; characters in grammar
280          ;;
281          (read-chseq (make-chseq-reader chrseq))
282          (assc-$ (lambda (pair) (cons (assq-ref symtab (car pair)) (cdr pair))))
283          ;;
284          (t-ident (assq-ref symtab '$ident))
285          (t-typename (assq-ref symtab 'typename))
286          (xp1 (sxpath '(cpp-stmt define)))
287          (xp2 (sxpath '(decl))))
288     ;; mode: 'code|'file
289     ;; xdef?: (proc name mode) => #t|#f  : do we expand #define?
290     (lambda* (#:key (mode 'code) (xdef? #f))
291       (let ((bol #t)                  ; begin-of-line condition
292             (ppxs (list 'keep))       ; CPP execution state stack
293             (info (fluid-ref *info*)) ; assume make and run in same thread
294             (x-def? (or xdef? def-xdef?)))
295         ;; Return the first (tval . lval) pair not excluded by the CPP.
296         (lambda ()
297
298           (define (exec-cpp-stmts?)     ; exec (vs pass to parser) CPP stmts?
299             (eqv? mode 'code))
300       
301           (define (add-define tree)
302             (let* ((tail (cdr tree))
303                    (name (car (assq-ref tail 'name)))
304                    (args (assq-ref tail 'args))
305                    (repl (car (assq-ref tail 'repl)))
306                    (cell (cons name (if args (cons args repl) repl))))
307               (set-cpi-defs! info (cons cell (cpi-defs info)))))
308           
309           (define (rem-define name)
310               (set-cpi-defs! info (delete name (cpi-defs info))))
311           
312           ;; Evaluate expression text in #if of #elif statement.
313           (define (eval-cpp-cond-text text)
314             (with-throw-handler
315              'cpp-error
316              (lambda ()
317                (let* ((defs (cpi-defs info))
318                       (rhs (cpp-expand-text text defs))
319                       (exp (parse-cpp-expr rhs)))
320                  (eval-cpp-expr exp defs)))
321              (lambda (key fmt . args)
322                (report-error fmt args)
323                (throw 'c99-error "CPP error"))))
324             
325           (define (eval-cpp-stmt stmt)
326             (case (car stmt)
327               ((include)
328                (let* ((parg (cadr stmt)) (leng (string-length parg))
329                       (file (substring parg 1 (1- leng)))
330                       (path (find-file-in-dirl file (cpi-incs info)))
331                       (tynd (assoc-ref (cpi-tynd info) file)))
332                  (cond
333                   (tynd (for-each add-typename tynd)) ; in dot-h dict
334                   ((not path) (p-err "not found: ~S" file))
335                   ((exec-cpp-stmts?) (push-input (open-input-file path)))
336                   (else         ; include as tree
337                    (let* ((tree (with-input-from-file path run-parse)))
338                      (if (not tree) (p-err "included from ~S" path))
339                      (for-each add-define (xp1 tree)) ; add def's 
340                      (set! stmt (append stmt (list tree)))))))
341                (if (exec-cpp-stmts?) (set! ppxs (cons 'skip1-pop ppxs))))
342               ((define)
343                (add-define stmt)
344                (if (exec-cpp-stmts?) (set! ppxs (cons 'skip1-pop ppxs))))
345               ((undef)
346                (rem-define (cadr stmt))
347                (if (exec-cpp-stmts?) (set! ppxs (cons 'skip1-pop ppxs))))
348               ((if) ;; covers (if ifdef ifndef)
349                (cond
350                 ((exec-cpp-stmts?)
351                  (let ((val (eval-cpp-cond-text (cadr stmt))))
352                    (cond
353                     ((not val) (p-err "unresolved: ~S" (cadr stmt)))
354                     ((zero? val) (set! ppxs (cons* 'skip1-pop 'skip-look ppxs)))
355                     (else (set! ppxs (cons* 'skip1-pop (car ppxs) ppxs))))))
356                 (else (cpi-push))))
357               ((elif)
358                (cond
359                 ((exec-cpp-stmts?)
360                  (let ((val (eval-cpp-cond-text (cadr stmt))))
361                    (cond
362                     ((not val)
363                      (p-err "unresolved: ~S" (cadr stmt)))
364                     ((eq? 'keep (car ppxs))
365                      (set! ppxs (cons* 'skip1-pop 'skip-done (cdr ppxs))))
366                     ((zero? val) (set! ppxs (cons* 'skip1-pop ppxs)))
367                     ((eq? 'skip-look (car ppxs))
368                      (set! ppxs (cons* 'skip1-pop 'keep (cdr ppxs))))
369                     (else
370                      (set! ppxs (cons* 'skip1-pop 'skip-done (cdr ppxs)))))))
371                 (else (cpi-shift))))
372               ((else)
373                (cond
374                 ((exec-cpp-stmts?)
375                  (cond
376                   ((eq? 'skip-look (car ppxs))
377                    (set! ppxs (cons* 'skip1-pop 'keep (cdr ppxs))))
378                   (else
379                    (set! ppxs (cons* 'skip1-pop 'skip-done (cdr ppxs))))))
380                 (else (cpi-shift))))
381               ((endif)
382                (cond
383                 ((exec-cpp-stmts?)
384                  (set! ppxs (cons 'skip1-pop (cdr ppxs))))
385                 (else (cpi-pop))))
386               ((error)
387                stmt)
388               (else
389                (error "unhandled cpp stmt")))
390             (cons 'cpp-stmt stmt))
391           
392           (define (eval-cpp-line line)
393             (with-throw-handler
394              'cpp-error
395              (lambda () (eval-cpp-stmt (read-cpp-stmt line)))
396              (lambda (key fmt . rest)
397                (report-error fmt rest)
398                (throw 'c99-error "CPP error"))))
399
400           ;; Composition of @code{read-cpp-line} and @code{eval-cpp-line}.
401           (define (read-cpp ch)
402             (and=> (read-cpp-line ch) eval-cpp-line))
403
404           (define (read-token)
405             (let iter ((ch (read-char)))
406               (cond
407                ((eof-object? ch)
408                 (if (pop-input) (iter (read-char)) (assc-$ '($end . ""))))
409                ((eq? ch #\newline) (set! bol #t) (iter (read-char)))
410                ((char-set-contains? c:ws ch) (iter (read-char)))
411                (bol
412                 (cond
413                  ((read-comm ch bol) => assc-$)
414                  ((read-cpp ch) =>
415                   (lambda (res) ;; if '() stmt expanded so re-read
416                     (if (pair? res) (assc-$ res) (iter (read-char)))))
417                  (else (set! bol #f) (iter ch))))
418                ((read-ident ch) =>
419                 (lambda (name)
420                   (let ((symb (string->symbol name)))
421                     (cond
422                      ((and (x-def? name mode)
423                            (expand-cpp-mref name (cpi-defs info)))
424                       => (lambda (st)
425                            (push-input (open-input-string st))
426                            (iter (read-char))))
427                      ((assq-ref keytab symb)
428                       => (lambda (t) (cons t name)))
429                      ((typename? name)
430                       (cons (assq-ref symtab 'typename) name))
431                      (else
432                       (cons (assq-ref symtab '$ident) name))))))
433                ((read-c-num ch) => assc-$)
434                ((read-c-string ch) => assc-$)
435                ((read-c-chlit ch) => assc-$)
436                ((read-comm ch bol) => assc-$)
437                ((read-chseq ch) => identity)
438                ((assq-ref chrtab ch) => (lambda (t) (cons t (string ch))))
439                ((eqv? ch #\\) ;; C allows \ at end of line to continue
440                 (let ((ch (read-char)))
441                   (cond ((eqv? #\newline ch) (iter (read-char))) ;; extend line
442                         (else (unread-char ch) (cons #\\ "\\"))))) ;; parse err
443                (else (cons ch (string ch))))))
444
445           ;; Loop between reading tokens and skipping tokens via CPP logic.
446           (let iter ((pair (read-token)))
447             (case (car ppxs)
448               ((keep)
449                pair)
450               ((skip-done skip-look)
451                (iter (read-token)))
452               ((skip1-pop)
453                (set! ppxs (cdr ppxs))
454                (iter (read-token)))))
455           )))))
456   
457 ;; --- last line ---