build: Make build more autotools-like.
[mes.git] / module / mescc / mescc.scm
1 ;;; GNU Mes --- Maxwell Equations of Software
2 ;;; Copyright © 2016,2017,2018 Jan (janneke) Nieuwenhuizen <janneke@gnu.org>
3 ;;;
4 ;;; This file is part of GNU Mes.
5 ;;;
6 ;;; GNU Mes is free software; you can redistribute it and/or modify it
7 ;;; under the terms of the GNU General Public License as published by
8 ;;; the Free Software Foundation; either version 3 of the License, or (at
9 ;;; your option) any later version.
10 ;;;
11 ;;; GNU Mes is distributed in the hope that it will be useful, but
12 ;;; WITHOUT ANY WARRANTY; without even the implied warranty of
13 ;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
14 ;;; GNU General Public License for more details.
15 ;;;
16 ;;; You should have received a copy of the GNU General Public License
17 ;;; along with GNU Mes.  If not, see <http://www.gnu.org/licenses/>.
18
19 (define-module (mescc mescc)
20   #:use-module (srfi srfi-1)
21   #:use-module (srfi srfi-26)
22   #:use-module (ice-9 pretty-print)
23   #:use-module (ice-9 getopt-long)
24   #:use-module (mes guile)
25   #:use-module (mes misc)
26
27   #:use-module (mescc preprocess)
28   #:use-module (mescc compile)
29   #:use-module (mescc M1)
30   #:export (mescc:preprocess
31             mescc:compile
32             mescc:assemble
33             mescc:link))
34
35 (define (mescc:preprocess options)
36   (let* ((defines (reverse (filter-map (multi-opt 'define) options)))
37          (includes (reverse (filter-map (multi-opt 'include) options)))
38          (pretty-print/write (string->symbol (option-ref options 'write (if guile? "pretty-print" "write"))))
39          (pretty-print/write (if (eq? pretty-print/write 'pretty-print) pretty-print write))
40          (files (option-ref options '() '("a.c")))
41          (input-file-name (car files))
42          (ast-file-name (cond ((and (option-ref options 'preprocess #f)
43                                     (option-ref options 'output #f)))
44                               (else (replace-suffix input-file-name ".E"))))
45          (prefix (option-ref options 'prefix "")))
46     (with-output-to-file ast-file-name
47       (lambda _ (for-each (cut c->ast prefix defines includes write <>) files)))))
48
49 (define (c->ast prefix defines includes write file-name)
50   (with-input-from-file file-name
51     (cut write (c99-input->ast #:prefix prefix #:defines defines #:includes includes))))
52
53 (define (mescc:compile options)
54   (let* ((files (option-ref options '() '("a.c")))
55          (input-file-name (car files))
56          (M1-file-name (cond ((and (option-ref options 'compile #f)
57                                    (option-ref options 'output #f)))
58                              (else (replace-suffix input-file-name ".S"))))
59          (infos (map (cut file->info options <>) files))
60          (verbose? (option-ref options 'verbose #f)))
61     (when verbose?
62       (stderr "dumping: ~a\n" M1-file-name))
63     (with-output-to-file M1-file-name
64       (cut infos->M1 M1-file-name infos))
65     M1-file-name))
66
67 (define (file->info options file-name)
68   (cond ((.c? file-name) (c->info options file-name))
69         ((.E? file-name) (E->info options file-name))))
70
71 (define (c->info options file-name)
72   (let ((defines (reverse (filter-map (multi-opt 'define) options)))
73         (includes (reverse (filter-map (multi-opt 'include) options)))
74         (prefix (option-ref options 'prefix "")))
75     (with-input-from-file file-name
76       (cut c99-input->info #:prefix prefix #:defines defines #:includes includes))))
77
78 (define (E->info options file-name)
79   (let ((ast (with-input-from-file file-name read)))
80     (c99-ast->info ast)))
81
82 (define (mescc:assemble options)
83   (let* ((files (option-ref options '() '("a.c")))
84          (input-file-name (car files))
85          (hex2-file-name (cond ((and (option-ref options 'assemble #f)
86                                      (option-ref options 'output #f)))
87                                (else (replace-suffix input-file-name ".o"))))
88          (S-files (filter .S? files))
89          (hex2-files  M1->hex2 ) ;; FIXME
90          (source-files (filter (disjoin .c? .E?) files))
91          (infos (map (cut file->info options <>) source-files)))
92     (if (and (pair? S-files) (pair? infos))
93         (error "mixing source and object not supported:" source-files S-files))
94     (when (pair? S-files)
95       (M1->hex2 options S-files))
96     (when (pair? infos)
97       (infos->hex2 options hex2-file-name infos))
98     hex2-file-name))
99
100 (define (mescc:link options)
101   (let* ((files (option-ref options '() '("a.c")))
102          (source-files (filter (disjoin .c? .E?) files))
103          (S-files (filter .S? files))
104          (o-files (filter .o? files))
105          (input-file-name (car files))
106          (hex2-file-name (if (or (string-suffix? ".hex2" input-file-name)
107                                  (string-suffix? ".o" input-file-name)) input-file-name
108                                  (replace-suffix input-file-name ".o")))
109          (infos (map (cut file->info options <>) source-files))
110          (S-files (filter .S? files))
111          (hex2-files (filter .o? files))
112          (hex2-files (if (null? S-files) hex2-files
113                          (append hex2-files (list (M1->hex2 options S-files)))))
114          (hex2-files (if (null? infos) hex2-files
115                          (append hex2-files
116                                  (list (infos->hex2 options hex2-file-name infos)))))
117          (libraries (filter-map (multi-opt 'library) options))
118          (libraries (if (pair? libraries) libraries '("c")))
119          (hex2-libraries (map (cut find-library options ".o" <>) libraries))
120          (hex2-files (append hex2-files hex2-libraries))
121          (S-files (append S-files (map (cut find-library options ".S" <>)  libraries)))
122          (debug-info? (option-ref options 'debug-info #f))
123          (S-files (cons (replace-suffix input-file-name ".S") S-files))
124          (elf-footer (and debug-info?
125                           (or (M1->blood-elf options S-files)
126                               (exit 1)))))
127     (or (hex2->elf options hex2-files #:elf-footer elf-footer)
128         (exit 1))))
129
130 (define (infos->hex2 options hex2-file-name infos)
131   (let* ((input-file-name (car (option-ref options '() '("a.c"))))
132          (M1-file-name (replace-suffix hex2-file-name ".S"))
133          (options (acons 'compile #t options)) ; ugh
134          (options (acons 'output hex2-file-name options))
135          (verbose? (option-ref options 'verbose #f)))
136     (when verbose?
137       (stderr "dumping: ~a\n" M1-file-name))
138     (with-output-to-file M1-file-name
139       (cut infos->M1 M1-file-name infos))
140     (or (M1->hex2 options (list M1-file-name))
141         (exit 1))))
142
143 (define (M1->hex2 options M1-files)
144   (let* ((input-file-name (car (option-ref options '() '("a.c"))))
145          (M1-file-name (car M1-files))
146          (hex2-file-name (cond ((and (option-ref options 'assemble #f)
147                                      (option-ref options 'output #f)))
148                                ((option-ref options 'assemble #f)
149                                 (replace-suffix input-file-name ".o"))
150                                (else (replace-suffix M1-file-name ".o"))))
151          (verbose? (option-ref options 'verbose #f))
152          (M1 (or (getenv "M1") "M1"))
153          (command `(,M1
154                     "--LittleEndian"
155                     "--Architecture" "1"
156                     "-f" ,(arch-find options "x86.M1")
157                     ,@(append-map (cut list "-f" <>) M1-files)
158                     "-o" ,hex2-file-name)))
159     (when verbose?
160       (stderr "~a\n" (string-join command)))
161     (and (zero? (apply assert-system* command))
162          hex2-file-name)))
163
164 (define* (hex2->elf options hex2-files #:key elf-footer)
165   (let* ((input-file-name (car (option-ref options '() '("a.c"))))
166          (elf-file-name (cond ((option-ref options 'output #f))
167                               (else (replace-suffix input-file-name ""))))
168          (verbose? (option-ref options 'verbose #f))
169          (elf-footer (or elf-footer (arch-find options "elf32-footer-single-main.hex2")))
170          (hex2 (or (getenv "HEX2") "hex2"))
171          (command `(,hex2
172                     "--LittleEndian"
173                     "--Architecture" "1"
174                     "--BaseAddress" "0x1000000"
175                     "-f" ,(arch-find options "elf32-header.hex2")
176                     "-f" ,(arch-find options "crt1.o")
177                     ,@(append-map (cut list "-f" <>) hex2-files)
178                     "-f" ,elf-footer
179                     "--exec_enable"
180                     "-o" ,elf-file-name)))
181     (when verbose?
182       (stderr "~a\n" (string-join command)))
183     (and (zero? (apply assert-system* command))
184          elf-file-name)))
185
186 (define (M1->blood-elf options M1-files)
187   (let* ((M1-file-name (car M1-files))
188          (M1-blood-elf-footer (string-append M1-file-name ".blood-elf"))
189          (hex2-file-name (replace-suffix M1-file-name ".o"))
190          (blood-elf-footer (string-append hex2-file-name ".blood-elf"))
191          (verbose? (option-ref options 'verbose #f))
192          (blood-elf (or (getenv "BLOOD_ELF") "blood-elf"))
193          (command `(,blood-elf
194                       "-f" ,(arch-find options "x86.M1")
195                       ,@(append-map (cut list "-f" <>) M1-files)
196                       "-o" ,M1-blood-elf-footer)))
197     (when verbose?
198         (format (current-error-port) "~a\n" (string-join command)))
199     (and (zero? (apply assert-system* command))
200          (let* ((options (acons 'compile #t options)) ; ugh
201                 (options (acons 'output blood-elf-footer options)))
202            (M1->hex2 options (list M1-blood-elf-footer))))))
203
204 (define (replace-suffix file-name suffix)
205   (let* ((parts (string-split file-name #\.))
206          (base (if (pair? (cdr parts)) (drop-right parts 1))))
207     (string-append (string-join base ".") suffix)))
208
209 (define (find-library options ext o)
210   (arch-find options (string-append "lib" o ext)))
211
212 (define* (arch-find options file-name)
213   (let* ((srcdest (or (getenv "srcdest") ""))
214          (srcdir-lib (string-append srcdest "lib"))
215          (path (cons* srcdir-lib
216                       (prefix-file options "lib")
217                       (filter-map (multi-opt 'library-dir) options)))
218          (arch-file-name (string-append "x86-mes/" file-name))
219          (verbose? (option-ref options 'verbose #f)))
220     (when verbose?
221       (stderr "arch-find=~s\n" arch-file-name)
222       (stderr "     path=~s\n" path)
223       (stderr "  => ~s\n" (search-path path arch-file-name)))
224     (search-path path arch-file-name)))
225
226 (define (prefix-file options file-name)
227   (let ((prefix (option-ref options 'prefix "")))
228     (define (prefix-file o)
229       (if (string-null? prefix) o (string-append prefix "/" o)))
230     (prefix-file file-name)))
231
232 (define (assert-system* . args)
233   (let ((status (apply system* args)))
234     (when (not (zero? status))
235       (stderr "mescc: failed: ~a\n" (string-join args))
236       (exit status))
237     status))
238
239 (define (multi-opt option-name) (lambda (o) (and (eq? (car o) option-name) (cdr o))))
240
241 (define (.c? o) (or (string-suffix? ".c" o)
242                     (string-suffix? ".M2" o)))
243 (define (.E? o) (string-suffix? ".E" o))
244 (define (.S? o) (or (string-suffix? ".S" o)
245                     (string-suffix? ".mes-S" o)
246                     (string-suffix? "S" o)
247                     (string-suffix? ".M1" o)))
248 (define (.o? o) (or (string-suffix? ".o" o)
249                     (string-suffix? ".mes-o" o)
250                     (string-suffix? "o" o)
251                     (string-suffix? ".hex2" o)))