build: Cater for ARM.
[mes.git] / module / mescc / mescc.scm
1 ;;; GNU Mes --- Maxwell Equations of Software
2 ;;; Copyright © 2016,2017,2018,2019 Jan (janneke) Nieuwenhuizen <janneke@gnu.org>
3 ;;;
4 ;;; This file is part of GNU Mes.
5 ;;;
6 ;;; GNU Mes is free software; you can redistribute it and/or modify it
7 ;;; under the terms of the GNU General Public License as published by
8 ;;; the Free Software Foundation; either version 3 of the License, or (at
9 ;;; your option) any later version.
10 ;;;
11 ;;; GNU Mes is distributed in the hope that it will be useful, but
12 ;;; WITHOUT ANY WARRANTY; without even the implied warranty of
13 ;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
14 ;;; GNU General Public License for more details.
15 ;;;
16 ;;; You should have received a copy of the GNU General Public License
17 ;;; along with GNU Mes.  If not, see <http://www.gnu.org/licenses/>.
18
19 (define-module (mescc mescc)
20   #:use-module (srfi srfi-1)
21   #:use-module (srfi srfi-26)
22   #:use-module (ice-9 pretty-print)
23   #:use-module (ice-9 getopt-long)
24   #:use-module (mes misc)
25
26   #:use-module (mescc i386 info)
27   #:use-module (mescc x86_64 info)
28   #:use-module (mescc preprocess)
29   #:use-module (mescc compile)
30   #:use-module (mescc M1)
31   #:export (mescc:preprocess
32             mescc:get-host
33             mescc:compile
34             mescc:assemble
35             mescc:link))
36
37 (define GUILE-with-output-to-file with-output-to-file)
38 (define (with-output-to-file file-name thunk)
39   (if (equal? file-name "-") (thunk)
40       (GUILE-with-output-to-file file-name thunk)))
41
42 (define (mescc:preprocess options)
43   (let* ((pretty-print/write (string->symbol (option-ref options 'write (if guile? "pretty-print" "write"))))
44          (pretty-print/write (if (eq? pretty-print/write 'pretty-print) pretty-print write))
45          (files (option-ref options '() '("a.c")))
46          (input-file-name (car files))
47          (ast-file-name (cond ((and (option-ref options 'preprocess #f)
48                                     (option-ref options 'output #f)))
49                               (else (replace-suffix input-file-name ".E"))))
50          (dir (dirname input-file-name))
51          (defines (reverse (filter-map (multi-opt 'define) options)))
52          (includes (reverse (filter-map (multi-opt 'include) options)))
53          (includes (cons dir includes))
54          (prefix (option-ref options 'prefix ""))
55          (machine (option-ref options 'machine "32"))
56          (arch (if (equal? machine "32") "__i386__=1" "__x86_64__=1"))
57          (defines (cons (arch-get-define options) defines)))
58     (with-output-to-file ast-file-name
59       (lambda _ (for-each (cut c->ast prefix defines includes write <>) files)))))
60
61 (define (c->ast prefix defines includes write file-name)
62   (with-input-from-file file-name
63     (cut write (c99-input->ast #:prefix prefix #:defines defines #:includes includes))))
64
65 (define (mescc:compile options)
66   (let* ((files (option-ref options '() '("a.c")))
67          (input-file-name (car files))
68          (M1-file-name (cond ((and (option-ref options 'compile #f)
69                                    (option-ref options 'output #f)))
70                              (else (replace-suffix input-file-name ".S"))))
71          (infos (map (cut file->info options <>) files))
72          (verbose? (option-ref options 'verbose #f))
73          (align? (option-ref options 'align #f)))
74     (when verbose?
75       (stderr "dumping: ~a\n" M1-file-name))
76     (with-output-to-file M1-file-name
77       (cut infos->M1 M1-file-name infos #:align? align?))
78     M1-file-name))
79
80 (define (file->info options file-name)
81   (cond ((.c? file-name) (c->info options file-name))
82         ((.E? file-name) (E->info options file-name))))
83
84 (define (c->info options file-name)
85   (let* ((defines (reverse (filter-map (multi-opt 'define) options)))
86          (includes (reverse (filter-map (multi-opt 'include) options)))
87          (dir (dirname file-name))
88          (includes (cons dir includes))
89          (prefix (option-ref options 'prefix ""))
90          (defines (cons (arch-get-define options) defines)))
91     (with-input-from-file file-name
92       (cut c99-input->info (arch-get-info options) #:prefix prefix #:defines defines #:includes includes))))
93
94 (define (E->info options file-name)
95   (let ((ast (with-input-from-file file-name read)))
96     (c99-ast->info (arch-get-info options) ast)))
97
98 (define (mescc:assemble options)
99   (let* ((files (option-ref options '() '("a.c")))
100          (input-file-name (car files))
101          (hex2-file-name (cond ((and (option-ref options 'assemble #f)
102                                      (option-ref options 'output #f)))
103                                (else (replace-suffix input-file-name ".o"))))
104          (S-files (filter .S? files))
105          (hex2-files  M1->hex2 ) ;; FIXME
106          (source-files (filter (disjoin .c? .E?) files))
107          (infos (map (cut file->info options <>) source-files)))
108     (if (and (pair? S-files) (pair? infos))
109         (error "mixing source and object not supported:" source-files S-files))
110     (when (pair? S-files)
111       (M1->hex2 options S-files))
112     (when (pair? infos)
113       (infos->hex2 options hex2-file-name infos))
114     hex2-file-name))
115
116 (define (mescc:link options)
117   (let* ((files (option-ref options '() '("a.c")))
118          (source-files (filter (disjoin .c? .E?) files))
119          (S-files (filter .S? files))
120          (o-files (filter .o? files))
121          (input-file-name (car files))
122          (hex2-file-name (if (or (string-suffix? ".hex2" input-file-name)
123                                  (string-suffix? ".o" input-file-name)) input-file-name
124                                  (replace-suffix input-file-name ".o")))
125          (infos (map (cut file->info options <>) source-files))
126          (S-files (filter .S? files))
127          (hex2-files (filter .o? files))
128          (hex2-files (if (null? S-files) hex2-files
129                          (append hex2-files (list (M1->hex2 options S-files)))))
130          (hex2-files (if (null? infos) hex2-files
131                          (append hex2-files
132                                  (list (infos->hex2 options hex2-file-name infos)))))
133          (default-libraries (if (or (option-ref options 'nodefaultlibs #f)
134                                     (option-ref options 'nostdlib #f)) '()
135                                     '("c")))
136          (libraries (filter-map (multi-opt 'library) options))
137          (libraries (delete-duplicates (append libraries default-libraries)))
138          (hex2-libraries (map (cut find-library options ".a" <>) libraries))
139          (hex2-files (append hex2-files hex2-libraries))
140          (S-files (append S-files (map (cut find-library options ".S" <>)  libraries)))
141          (debug-info? (option-ref options 'debug-info #f))
142          (S-files (cons (replace-suffix input-file-name ".S") S-files))
143          (elf-footer (and debug-info?
144                           (or (M1->blood-elf options S-files)
145                               (exit 1)))))
146     (or (hex2->elf options hex2-files #:elf-footer elf-footer)
147         (exit 1))))
148
149 (define (infos->hex2 options hex2-file-name infos)
150   (let* ((input-file-name (car (option-ref options '() '("a.c"))))
151          (M1-file-name (replace-suffix hex2-file-name ".S"))
152          (options (acons 'compile #t options)) ; ugh
153          (options (acons 'output hex2-file-name options))
154          (verbose? (option-ref options 'verbose #f))
155          (align? (option-ref options 'align #f)))
156     (when verbose?
157       (stderr "dumping: ~a\n" M1-file-name))
158     (with-output-to-file M1-file-name
159       (cut infos->M1 M1-file-name infos #:align? align?))
160     (or (M1->hex2 options (list M1-file-name))
161         (exit 1))))
162
163 (define (M1->hex2 options M1-files)
164   (let* ((input-file-name (car (option-ref options '() '("a.c"))))
165          (M1-file-name (car M1-files))
166          (hex2-file-name (cond ((and (option-ref options 'assemble #f)
167                                      (option-ref options 'output #f)))
168                                ((option-ref options 'assemble #f)
169                                 (replace-suffix input-file-name ".o"))
170                                (else (replace-suffix M1-file-name ".o"))))
171          (verbose? (option-ref options 'verbose #f))
172          (M1 (or (getenv "M1") "M1"))
173          (command `(,M1
174                     "--LittleEndian"
175                     "--architecture" ,(arch-get-architecture options)
176                     "-f" ,(arch-find options (arch-get-m1-macros options))
177                     ,@(append-map (cut list "-f" <>) M1-files)
178                     "-o" ,hex2-file-name)))
179     (when verbose?
180       (stderr "~a\n" (string-join command)))
181     (and (zero? (apply assert-system* command))
182          hex2-file-name)))
183
184 (define* (hex2->elf options hex2-files #:key elf-footer)
185   (let* ((input-file-name (car (option-ref options '() '("a.c"))))
186          (elf-file-name (cond ((option-ref options 'output #f))
187                               (else "a.out")))
188          (verbose? (option-ref options 'verbose #f))
189          (hex2 (or (getenv "HEX2") "hex2"))
190          (base-address (option-ref options 'base-address "0x1000000"))
191          (machine (arch-get-machine options))
192          (elf-footer (or elf-footer
193                          (arch-find options (string-append
194                                              "elf" machine "-footer-single-main.hex2"))))
195          (start-files (if (or (option-ref options 'nostartfiles #f)
196                               (option-ref options 'nostdlib #f)) '()
197                               `("-f" ,(arch-find options "crt1.o"))))
198          (command `(,hex2
199                     "--LittleEndian"
200                     "--architecture" ,(arch-get-architecture options)
201                     "--BaseAddress" ,base-address
202                     "-f" ,(arch-find options (string-append "elf" machine "-header.hex2"))
203                     ,@start-files
204                     ,@(append-map (cut list "-f" <>) hex2-files)
205                     "-f" ,elf-footer
206                     "--exec_enable"
207                     "-o" ,elf-file-name)))
208     (when verbose?
209       (stderr "~a\n" (string-join command)))
210     (and (zero? (apply assert-system* command))
211          elf-file-name)))
212
213 (define (M1->blood-elf options M1-files)
214   (let* ((M1-file-name (car M1-files))
215          (M1-blood-elf-footer (string-append M1-file-name ".blood-elf"))
216          (hex2-file-name (replace-suffix M1-file-name ".o"))
217          (blood-elf-footer (string-append hex2-file-name ".blood-elf"))
218          (verbose? (option-ref options 'verbose #f))
219          (blood-elf (or (getenv "BLOOD_ELF") "blood-elf"))
220          (command `(,blood-elf
221                       "-f" ,(arch-find options (arch-get-m1-macros options))
222                       ,@(append-map (cut list "-f" <>) M1-files)
223                       "-o" ,M1-blood-elf-footer)))
224     (when verbose?
225         (format (current-error-port) "~a\n" (string-join command)))
226     (and (zero? (apply assert-system* command))
227          (let* ((options (acons 'compile #t options)) ; ugh
228                 (options (acons 'output blood-elf-footer options)))
229            (M1->hex2 options (list M1-blood-elf-footer))))))
230
231 (define (replace-suffix file-name suffix)
232   (let* ((parts (string-split file-name #\.))
233          (base (if (pair? (cdr parts)) (drop-right parts 1)))
234          (old-suffix (last parts))
235          (program-prefix (cond ((string-prefix? "arm-mes-" old-suffix) ".arm-mes-")
236                                ((string-prefix? "x86-mes-" old-suffix) ".x86-mes-")
237                                ((string-prefix? "x86_64-mes-" old-suffix) ".x86_64-mes-")
238                                (else "."))))
239     (if (string-null? suffix)
240         (if (string-null? program-prefix) (string-join base ".")
241             (string-append (string-drop program-prefix 1) (string-join base ".")))
242         (string-append (string-join base ".") program-prefix (string-drop suffix 1)))))
243
244 (define (find-library options ext o)
245   (arch-find options (string-append "lib" o ext)))
246
247 (define* (arch-find options file-name)
248   (let* ((srcdest (or (getenv "srcdest") ""))
249          (srcdir-lib (string-append srcdest "lib"))
250          (arch (string-append (arch-get options) "-mes"))
251          (path (cons* "."
252                       srcdir-lib
253                       (prefix-file options "lib")
254                       (filter-map (multi-opt 'library-dir) options)))
255          (arch-file-name (string-append arch "/" file-name))
256          (verbose? (option-ref options 'verbose #f)))
257     (let ((file (search-path path arch-file-name)))
258       (when verbose?
259         (stderr "arch-find=~s\n" arch-file-name)
260         (stderr "     path=~s\n" path)
261         (stderr "  => ~s\n" file))
262       (or file
263           (error (format #f "mescc: file not found: ~s" arch-file-name))))))
264
265 (define (prefix-file options file-name)
266   (let ((prefix (option-ref options 'prefix "")))
267     (define (prefix-file o)
268       (if (string-null? prefix) o (string-append prefix "/" o)))
269     (prefix-file file-name)))
270
271 (define (assert-system* . args)
272   (let ((status (apply system* args)))
273     (when (not (zero? status))
274       (stderr "mescc: failed: ~a\n" (string-join args))
275       (exit (status:exit-val status)))
276     status))
277
278 (define (arch-get options)
279   (let* ((machine (option-ref options 'machine #f))
280          (arch (option-ref options 'arch #f)))
281     (if machine (cond ((member arch '("x86" "x86_64")) (cond ((equal? machine "32") "x86")
282                                                              ((equal? machine "64") "x86_64")))
283                       ((equal? arch "arm") (cond ((equal? machine "32") "arm"))))
284         arch)))
285
286 (define (mescc:get-host options)
287   (let ((cpu (arch-get options))
288         (kernel "linux"))
289     (string-join (list cpu kernel "mes") "-")))
290
291 (define (arch-get-info options)
292   (let ((arch (arch-get options)))
293     (cond ((equal? arch "arm") (armv4-info))
294           ((equal? arch "x86") (x86-info))
295           ((equal? arch "x86_64") (x86_64-info)))))
296
297 (define (arch-get-define options)
298   (let ((arch (arch-get options)))
299     (cond ((equal? arch "arm") "__arm__=1")
300           ((equal? arch "x86") "__i386__=1")
301           ((equal? arch "x86_64") "__x86_64__=1"))))
302
303 (define (arch-get-machine options)
304   (let* ((machine (option-ref options 'machine #f))
305          (arch (option-ref options 'arch #f)))
306     (or machine
307         (if (member arch '("x86_64")) "64"
308             "32"))))
309
310 (define (arch-get-m1-macros options)
311   (let ((arch (arch-get options)))
312     (cond ((equal? arch "arm") "arm.M1")
313           ((equal? arch "x86") "x86.M1")
314           ((equal? arch "x86_64") "x86_64.M1"))))
315
316 (define (arch-get-architecture options)
317   (let ((arch (arch-get options)))
318     (cond ((equal? arch "arm") "armv7l")
319           ((equal? arch "x86") "x86")
320           ((equal? arch "x86_64") "amd64"))))
321
322 (define (multi-opt option-name) (lambda (o) (and (eq? (car o) option-name) (cdr o))))
323
324 (define (.c? o) (or (string-suffix? ".c" o)
325                     (string-suffix? ".M2" o)))
326 (define (.E? o) (or (string-suffix? ".E" o)
327                     (string-suffix? ".mes-E" o)
328                     (string-suffix? ".arm-mes-E" o)
329                     (string-suffix? ".x86-mes-E" o)
330                     (string-suffix? ".x86_64-mes-E" o)))
331 (define (.S? o) (or (string-suffix? ".S" o)
332                     (string-suffix? ".mes-S" o)
333                     (string-suffix? ".arm-mes-S" o)
334                     (string-suffix? ".x86-mes-S" o)
335                     (string-suffix? ".x86_64-mes-S" o)
336                     (string-suffix? "S" o)
337                     (string-suffix? ".M1" o)))
338 (define (.o? o) (or (string-suffix? ".o" o)
339                     (string-suffix? ".mes-o" o)
340                     (string-suffix? ".arm-mes-o" o)
341                     (string-suffix? ".x86-mes-o" o)
342                     (string-suffix? ".x86_64-mes-o" o)
343                     (string-suffix? ".hex2" o)))