mescc: Support -nodefaultlibs, -nostartfiles, -nostdlib.
[mes.git] / module / mescc.scm
1 ;;; GNU Mes --- Maxwell Equations of Software
2 ;;; Copyright © 2016,2017,2018 Jan (janneke) Nieuwenhuizen <janneke@gnu.org>
3 ;;;
4 ;;; This file is part of GNU Mes.
5 ;;;
6 ;;; GNU Mes is free software; you can redistribute it and/or modify it
7 ;;; under the terms of the GNU General Public License as published by
8 ;;; the Free Software Foundation; either version 3 of the License, or (at
9 ;;; your option) any later version.
10 ;;;
11 ;;; GNU Mes is distributed in the hope that it will be useful, but
12 ;;; WITHOUT ANY WARRANTY; without even the implied warranty of
13 ;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
14 ;;; GNU General Public License for more details.
15 ;;;
16 ;;; You should have received a copy of the GNU General Public License
17 ;;; along with GNU Mes.  If not, see <http://www.gnu.org/licenses/>.
18
19 (define-module (mescc)
20   #:use-module (srfi srfi-1)
21   #:use-module (ice-9 getopt-long)
22   #:use-module (mes misc)
23   #:use-module (mescc mescc)
24   #:export (mescc:main))
25
26 (cond-expand
27  (mes
28   (define (set-port-encoding! port encoding) #t)
29   (mes-use-module (mes guile))
30   (mes-use-module (mes misc))
31   (mes-use-module (mes getopt-long))
32   (mes-use-module (mes display))
33   (mes-use-module (mescc mescc))
34   )
35  (guile
36   (define-macro (mes-use-module . rest) #t)))
37
38 (define %prefix (getenv "%prefix"))
39 (define %version (getenv "%version"))
40
41 (when (and=> (getenv "V") (lambda (v) (> (string->number v) 1)))
42   (format (current-error-port) "mescc[~a]...\n" %scheme))
43
44 (define (unclump-single o)
45   (cond ((string-prefix? "--" o) (list o))
46         ((and (string-prefix? "-" o)
47               (> (string-length o) 2)
48               (not (eq? (string-ref o 2) #\space)))
49          (list (substring o 0 2)
50                (substring o 2)))
51         (else (list o))))
52
53 (define (parse-opts args)
54   (let* ((option-spec
55           '((align)
56             (assemble (single-char #\c))
57             (base-address (value #t))
58             (compile (single-char #\S))
59             (define (single-char #\D) (value #t))
60             (debug-info (single-char #\g))
61             (dumpmachine)
62             (help (single-char #\h))
63             (include (single-char #\I) (value #t))
64             (library-dir (single-char #\L) (value #t))
65             (library (single-char #\l) (value #t))
66             (machine (single-char #\m) (value #t))
67             (nodefaultlibs)
68             (nostartfiles)
69             (nostdlib)
70             (preprocess (single-char #\E))
71             (std (value #t))
72             (output (single-char #\o) (value #t))
73             (optimize (single-char #\O) (value #t))
74             (version (single-char #\V))
75             (verbose (single-char #\v))
76             (write (single-char #\w) (value #t))
77             (language (single-char #\x) (value #t))))
78          (options (getopt-long args option-spec))
79          (help? (option-ref options 'help #f))
80          (files (option-ref options '() '()))
81          (usage? (and (not help?) (null? files)))
82          (version? (option-ref options 'version #f)))
83     (cond ((option-ref options 'dumpmachine #f)
84            (display "x86-mes")
85            (exit 0))
86           (version? (format #t "mescc (GNU Mes) ~a\n" %version) (exit 0))
87           (else
88            (and (or help? usage?)
89                 (format (or (and usage? (current-error-port)) (current-output-port)) "\
90 Usage: mescc [OPTION]... FILE...
91   --align             align globals
92   -dumpmachine        display the compiler's target processor
93   --base-address=ADRRESS
94                       use BaseAddress ADDRESS [0x1000000]
95   -D DEFINE[=VALUE]   define DEFINE [VALUE=1]
96   -E                  preprocess only; do not compile, assemble or link
97   -g                  add debug info [GDB, objdump] TODO: hex2 footer
98   -h, --help          display this help and exit
99   -I DIR              append DIR to include path
100   -L DIR              append DIR to library path
101   -l LIBNAME          link with LIBNAME
102   -m BITS             compile for BITS bits [32]
103   -nodefaultlibs      do not use libc.o when linking
104   -nostartfiles       do not use crt1.o when linking
105   -nostdlib           do not use crt1.o or libc.o when linking
106   -o FILE             write output to FILE
107   -O LEVEL            use optimizing LEVEL
108   -S                  preprocess and compile only; do not assemble or link
109   --std=STANDARD      assume that the input sources are for STANDARD
110   -v, --version       display version and exit
111   -w,--write=TYPE     dump Nyacc AST using TYPE {pretty-print,write}
112   -x LANGUAGE         specify LANGUAGE of the following input files
113
114 Environment variables:
115
116   MES=BINARY          run on mes-executable BINARY {mes,guile}
117   MES_DEBUG=LEVEL     show debug output with verbosity LEVEL {0..5}
118   NYACC_TRACE=1       show Nyacc progress
119
120 Report bugs to: bug-mes@gnu.org
121 GNU Mes home page: <http://gnu.org/software/mes/>
122 General help using GNU software: <http://gnu.org/gethelp/>
123 ")
124                 (exit (or (and usage? 2) 0)))
125            options))))
126
127 (define (mescc:main args)
128   (let* ((single-dash-options '("-dumpmachine"
129                                 "-nodefaultlibs"
130                                 "-nostartfiles"
131                                 "-nostdlib"
132                                 "-std"))
133          (args (map (lambda (o)
134                       (if (member o single-dash-options) (string-append "-" o)
135                           o))
136                     args))
137          (args (append-map unclump-single args))
138          (options (parse-opts args))
139          (options (acons 'prefix %prefix options))
140          (preprocess? (option-ref options 'preprocess #f))
141          (compile? (option-ref options 'compile #f))
142          (assemble? (option-ref options 'assemble #f))
143          (verbose? (option-ref options 'verbose (getenv "MES_DEBUG"))))
144     (when verbose?
145       (setenv "NYACC_TRACE" "yes")
146       (format (current-error-port) "options=~s\n" options))
147     (cond (preprocess? (mescc:preprocess options))
148           (compile? (mescc:compile options))
149           (assemble? (mescc:assemble options))
150           (else (mescc:link options)))))