mescc: Be silent.
[mes.git] / module / mescc.scm
1 ;;; GNU Mes --- Maxwell Equations of Software
2 ;;; Copyright © 2016,2017,2018,2019 Jan (janneke) Nieuwenhuizen <janneke@gnu.org>
3 ;;;
4 ;;; This file is part of GNU Mes.
5 ;;;
6 ;;; GNU Mes is free software; you can redistribute it and/or modify it
7 ;;; under the terms of the GNU General Public License as published by
8 ;;; the Free Software Foundation; either version 3 of the License, or (at
9 ;;; your option) any later version.
10 ;;;
11 ;;; GNU Mes is distributed in the hope that it will be useful, but
12 ;;; WITHOUT ANY WARRANTY; without even the implied warranty of
13 ;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
14 ;;; GNU General Public License for more details.
15 ;;;
16 ;;; You should have received a copy of the GNU General Public License
17 ;;; along with GNU Mes.  If not, see <http://www.gnu.org/licenses/>.
18
19 (define-module (mescc)
20   #:use-module (srfi srfi-1)
21   #:use-module (ice-9 getopt-long)
22   #:use-module (mes guile)
23   #:use-module (mes misc)
24   #:use-module (mescc mescc)
25   #:export (mescc:main))
26
27 (cond-expand
28  (mes
29   (define (set-port-encoding! port encoding) #t)
30   (mes-use-module (mes guile))
31   (mes-use-module (mes misc))
32   (mes-use-module (mes getopt-long))
33   (mes-use-module (mes display))
34   (mes-use-module (mescc mescc))
35   )
36  (guile
37   (define-macro (mes-use-module . rest) #t)))
38
39 (define %host-arch (or (getenv "%arch") %arch))
40 (define %prefix (getenv "%prefix"))
41 (define %version (getenv "%version"))
42
43 (when (and=> (getenv "V") (lambda (v) (and (= (string-length v) 1) (> (string->number v) 1))))
44   (format (current-error-port) "mescc[~a]...\n" %scheme))
45
46 (define (unclump-single o)
47   (cond ((string-prefix? "--" o) (list o))
48         ((and (string-prefix? "-" o)
49               (> (string-length o) 2)
50               (not (eq? (string-ref o 2) #\space)))
51          (list (substring o 0 2)
52                (substring o 2)))
53         (else (list o))))
54
55 (define (parse-opts args)
56   (let* ((option-spec
57           '((align)
58             (arch (value #t))
59             (assemble (single-char #\c))
60             (base-address (value #t))
61             (compile (single-char #\S))
62             (define (single-char #\D) (value #t))
63             (debug-info (single-char #\g))
64             (dumpmachine)
65             (fno-builtin)
66             (help (single-char #\h))
67             (include (single-char #\I) (value #t))
68             (library-dir (single-char #\L) (value #t))
69             (library (single-char #\l) (value #t))
70             (machine (single-char #\m) (value #t))
71             (nodefaultlibs)
72             (nostartfiles)
73             (nostdinc)
74             (nostdlib)
75             (preprocess (single-char #\E))
76             (static)
77             (std (value #t))
78             (output (single-char #\o) (value #t))
79             (optimize (single-char #\O) (value #t))
80             (version (single-char #\V))
81             (verbose (single-char #\v))
82             (write (single-char #\w) (value #t))
83             (language (single-char #\x) (value #t))))
84          (options (getopt-long args option-spec))
85          (help? (option-ref options 'help #f))
86          (files (option-ref options '() '()))
87          (dumpmachine? (option-ref options 'dumpmachine #f))
88          (version? (option-ref options 'version #f))
89          (usage? (and (not dumpmachine?) (not help?) (not version?) (null? files))))
90     (cond (version? (format #t "mescc (GNU Mes) ~a\n" %version) (exit 0))
91           (else
92            (and (or help? usage?)
93                 (format (or (and usage? (current-error-port)) (current-output-port)) "\
94 Usage: mescc [OPTION]... FILE...
95   --align             align globals
96   --arch=ARCH         compile for ARCH [~a]
97   -dumpmachine        display the compiler's target machine
98   --base-address=ADRRESS
99                       use BaseAddress ADDRESS [0x1000000]
100   -D DEFINE[=VALUE]   define DEFINE [VALUE=1]
101   -E                  preprocess only; do not compile, assemble or link
102   -g                  add debug info [GDB, objdump] TODO: hex2 footer
103   -h, --help          display this help and exit
104   -I DIR              append DIR to include path
105   -L DIR              append DIR to library path
106   -l LIBNAME          link with LIBNAME
107   -m BITS             compile for BITS bits [32]
108   -nodefaultlibs      do not use libc.o when linking
109   -nostartfiles       do not use crt1.o when linking
110   -nostdlib           do not use crt1.o or libc.o when linking
111   -o FILE             write output to FILE
112   -O LEVEL            use optimizing LEVEL
113   -S                  preprocess and compile only; do not assemble or link
114   --std=STANDARD      assume that the input sources are for STANDARD
115   -v, --version       display version and exit
116   -w,--write=TYPE     dump Nyacc AST using TYPE {pretty-print,write}
117   -x LANGUAGE         specify LANGUAGE of the following input files
118
119 Ignored for GCC compatibility
120   -fno-builtin
121   -no-pie
122   -nostdinc
123   -static
124
125 Environment variables:
126
127   MES=BINARY          run on mes-executable BINARY {mes,guile}
128   MES_DEBUG=LEVEL     show debug output with verbosity LEVEL {0..5}
129   NYACC_TRACE=1       show Nyacc progress
130
131 Report bugs to: bug-mes@gnu.org
132 GNU Mes home page: <http://gnu.org/software/mes/>
133 General help using GNU software: <http://gnu.org/gethelp/>
134 " %host-arch)
135                 (exit (or (and usage? 2) 0)))
136            options))))
137
138 (define (mescc:main args)
139   (let* ((single-dash-options '("-dumpmachine"
140                                 "-fno-builtin"
141                                 "-no-pie"
142                                 "-nodefaultlibs"
143                                 "-nostartfiles"
144                                 "-nostdinc"
145                                 "-nostdlib"
146                                 "-static"
147                                 "-std"))
148          (args (map (lambda (o)
149                       (if (member o single-dash-options) (string-append "-" o)
150                           o))
151                     args))
152          (args (append-map unclump-single args))
153          (options (parse-opts args))
154          (options (acons 'prefix %prefix options))
155          (arch (option-ref options 'arch %host-arch))
156          (options (if arch (acons 'arch arch options) options))
157          (dumpmachine? (option-ref options 'dumpmachine #f))
158          (preprocess? (option-ref options 'preprocess #f))
159          (compile? (option-ref options 'compile #f))
160          (assemble? (option-ref options 'assemble #f))
161          (verbose? (count-opt options 'verbose)))
162     (when verbose?
163       (setenv "NYACC_TRACE" "yes")
164       (when (> verbose? 1)
165         (format (current-error-port) "options=~s\n" options)))
166     (cond (dumpmachine? (display (mescc:get-host options)))
167           (preprocess? (mescc:preprocess options))
168           (compile? (mescc:compile options))
169           (assemble? (mescc:assemble options))
170           (else (mescc:link options)))))