core: Remove substring.
[mes.git] / module / mes / scm.mes
1 ;;; -*-scheme-*-
2
3 ;;; Mes --- Maxwell Equations of Software
4 ;;; Copyright © 2016 Jan Nieuwenhuizen <janneke@gnu.org>
5 ;;;
6 ;;; This file is part of Mes.
7 ;;;
8 ;;; Mes is free software; you can redistribute it and/or modify it
9 ;;; under the terms of the GNU General Public License as published by
10 ;;; the Free Software Foundation; either version 3 of the License, or (at
11 ;;; your option) any later version.
12 ;;;
13 ;;; Mes is distributed in the hope that it will be useful, but
14 ;;; WITHOUT ANY WARRANTY; without even the implied warranty of
15 ;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
16 ;;; GNU General Public License for more details.
17 ;;;
18 ;;; You should have received a copy of the GNU General Public License
19 ;;; along with Mes.  If not, see <http://www.gnu.org/licenses/>.
20
21 ;;; Commentary:
22
23 ;;; scm.mes is loaded after base, quasiquote and let.  It provides
24 ;;; basic Scheme functions bringing Mes close to basic RRS Scheme (no
25 ;;; labels, processes, fluids or throw/catch).
26
27 ;;; Code:
28
29 (mes-use-module (mes let))
30
31 (define (cadddr x) (car (cdddr x)))
32
33 (define-macro (case val . args)
34   (if (null? args) #f
35       (let ((clause (car args)))
36         (let ((pred (car clause)))
37           (let ((body (cdr clause)))
38            (if (pair? pred) `(if ,(if (null? (cdr pred))
39                                       `(eq? ,val ',(car pred))
40                                       `(member ,val ',pred))
41                                  (begin ,@body)
42                                  (case ,val ,@(cdr args)))
43                `(begin ,@body)))))))
44
45 (define-macro (when expr . body)
46   `(if ,expr
47        ((lambda () ,@body))))
48
49 (define-macro (unless expr . body)
50   `(if (not ,expr)
51        ((lambda () ,@body))))
52
53 (define-macro (do init test . body)
54   `(let loop ((,(caar init) ,(cadar init)))
55      (when (not ,@test)
56        ,@body
57        (loop ,@(cddar init)))))
58
59 (define (for-each f l . r)
60   (if (pair? l) (if (null? r) (begin (f (car l)) (for-each f (cdr l)))
61                     (if (null? (cdr r)) (begin (f (car l) (caar r)) (for-each f (cdr l) (cdar r)))))))
62
63 (define (error who . rest)
64   (display "error:" (current-error-port))
65   (display who (current-error-port))
66   (display ":" (current-error-port))
67   (display rest (current-error-port))
68   (newline (current-error-port))
69   (display "exiting...\n" (current-error-port))
70   (exit 1))
71
72 (define (syntax-error message . rest)
73   (display "syntax-error:" (current-error-port))
74   (display message (current-error-port))
75   (display ":" (current-error-port))
76   (display rest (current-error-port))
77   (newline (current-error-port)))
78
79 \f
80 (define integer? number?)
81
82 (define (eof-object? x)
83   (or (and (number? x) (= x -1))
84       (and (char? x) (eof-object? (char->integer x)))))
85
86 (define (peek-char)
87   (integer->char (peek-byte)))
88
89 (define (read-char)
90   (integer->char (read-byte)))
91
92 (define (unread-char c)
93   (unread-byte (char->integer c))
94   c)
95
96 (define (assq-set! alist key val)
97   (let ((entry (assq key alist)))
98     (cond (entry (set-cdr! entry val)
99                  alist)
100           (#t (cons (cons key val) alist)))))
101
102 (define (assq-ref alist key)
103   (let ((entry (assq key alist)))
104     (if entry (cdr entry)
105         #f)))
106
107 (define assv assq)
108 (define assv-ref assq-ref)
109
110 (define (assoc key alist)
111   (if (null? alist) #f ;; IF
112       (if (equal? key (caar alist)) (car alist)
113           (assoc key (cdr alist)))))
114
115 (define (assoc-ref alist key)
116   (let ((entry (assoc key alist)))
117     (if entry (cdr entry)
118         #f)))
119
120 (define (memq x lst)
121   (if (null? lst) #f ;; IF
122       (if (eq? x (car lst)) lst
123           (memq x (cdr lst)))))
124 (define memv memq)
125
126 (define (member x lst)
127   (if (null? lst) #f ;; IF
128       (if (equal? x (car lst)) lst
129           (member x (cdr lst)))))
130
131 \f
132 ;;; Lists
133 (define (make-list n . x)
134   (let ((fill (if (pair? x) (car x) *unspecified*)))
135     (let loop ((n n))
136       (if (= 0 n) '()
137           (cons fill (loop (- n 1)))))))
138
139 (define (list-ref lst k)
140   (let loop ((lst lst) (k k))
141     (if (= 0 k) (car lst)
142         (loop (cdr lst) (- k 1)))))
143
144 (define (list-head x n)
145   (if (= 0 n) '()
146       (cons (car x) (list-head (cdr x) (- n 1)))))
147
148 (define (list-tail x n)
149   (if (= 0 n) x
150       (list-tail (cdr x) (- n 1))))
151
152 (define (last-pair lst)
153   (let loop ((lst lst))
154     (if (or (null? lst) (null? (cdr lst))) lst
155         (loop (cdr lst)))))
156
157 (define (iota n)
158   (if (<= n 0) '()
159       (append2 (iota (- n 1)) (list (- n 1)))))
160
161 (define (reverse lst)
162   (if (null? lst) '()
163       (append (reverse (cdr lst)) (cons (car lst) '()))))
164
165 (define (filter pred lst)
166   (let loop ((lst lst))
167     (if (null? lst) '()
168         (if (pred (car lst))
169             (cons (car lst) (loop (cdr lst)))
170             (loop (cdr lst))))))
171
172 (define (delete x lst)
173   (filter (lambda (e) (not (equal? e x))) lst))
174
175 (define (delq x lst)
176   (filter (lambda (e) (not (eq? e x))) lst))
177
178 \f
179 ;; Vector
180 (define (vector . rest) (list->vector rest))
181 (define c:make-vector make-vector)
182 (define (make-vector n . x)
183   (if (null? x) (c:make-vector n)
184       (list->vector (apply make-list (cons n x)))))
185
186 (define (vector-copy x)
187   (list->vector (vector->list x)))
188
189 \f
190 ;;; Strings/srfi-13
191 (define (string-length s)
192   (length (string->list s)))
193
194 (define (string-ref s k)
195   (list-ref (string->list s) k))
196
197 (define (substring s start . rest)
198   (let* ((end (and (pair? rest) (car rest)))
199          (lst (list-tail (string->list s) start)))
200     (list->string (if (not end) lst
201                       (list-head lst (- end start))))))
202
203 (define (string-prefix? prefix string)
204   (and
205    (>= (string-length string) (string-length prefix))
206    (equal? (substring string 0 (string-length prefix)) prefix)))
207
208 (define (string->number s . radix)
209   (if (and (pair? radix) (not (= (car radix) 10))) '*STRING->NUMBER:RADIX-NOT-SUPPORTED
210       (let* ((lst (string->list s))
211              (sign (if (char=? (car lst) #\-) -1 1))
212              (lst (if (= sign -1) (cdr lst) lst)))
213         (let loop ((lst lst) (n 0))
214           (if (null? lst) (* sign n)
215               (loop (cdr lst) (+ (* n 10) (- (char->integer (car lst)) (char->integer #\0)))))))))
216
217 \f
218 ;;; Symbols
219 (define (symbol-prefix? prefix symbol)
220   (string-prefix? (symbol->string prefix) (symbol->string symbol)))
221
222 (define (symbol-append . rest)
223   (string->symbol (apply string-append (map symbol->string rest))))
224
225 (define gensym
226   (let ((counter 0))
227     (lambda (. rest)
228       (let ((value (number->string counter)))
229         (set! counter (+ counter 1))
230         (string->symbol (string-append "g" value))))))
231
232 \f
233 ;;; Characters
234 (define (char=? x y)
235   (and (char? x) (char? y)
236        (eq? x y)))
237
238 (define (char<? a b) (< (char->integer a) (char->integer b)))
239 (define (char>? a b) (> (char->integer a) (char->integer b)))
240 (define (char<=? a b) (<= (char->integer a) (char->integer b)))
241 (define (char>=? a b) (>= (char->integer a) (char->integer b)))
242
243 (define (char-alphabetic? x)
244   (and (char? x)
245        (let ((i (char->integer x)))
246         (or (and (>= i (char->integer #\A)) (<= i (char->integer #\Z)))
247             (and (>= i (char->integer #\a)) (<= i (char->integer #\z)))))))
248
249 (define (char-numeric? x)
250   (and (char? x)
251        (let ((i (char->integer x)))
252          (and (>= i (char->integer #\0)) (<= i (char->integer #\9))))))
253
254 \f
255 ;;; Math
256 (define (<= . rest)
257   (or (apply < rest)
258       (apply = rest)))
259
260 (define (>= . rest)
261   (or (apply > rest)
262       (apply = rest)))
263
264 (define (remainder x y)
265   (- x (* (quotient x y) y)))
266
267 (define (even? x)
268   (= 0 (remainder x 2)))
269
270 (define (odd? x)
271   (= 1 (remainder x 2)))
272
273 (define (negative? x)
274   (< x 0))
275
276 (define (positive? x)
277   (> x 0))
278
279 (define (zero? x)
280   (= x 0))
281
282 (define (1+ x)
283   (+ x 1))
284
285 (define (1- x)
286   (- x 1))
287
288 (define (abs x)
289   (if (>= x 0) x (- x)))
290
291 (define (expt x y)
292   (let loop ((s 1) (count y))
293     (if (= 0 count) s
294         (loop (* s x) (- count 1)))))
295
296 (define (max x . rest)
297   (if (null? rest) x
298       (let ((y (car rest)))
299         (let ((z (if (> x y) x y)))
300           (apply max (cons z (cdr rest)))))))
301
302 (define (min x . rest)
303   (if (null? rest) x
304       (let ((y (car rest)))
305         (let ((z (if (< x y) x y)))
306           (apply min (cons z (cdr rest)))))))