eba58c1674f2a9556e08bdd72517117f84b2338a
[mes.git] / module / mes / scm.mes
1 ;;; -*-scheme-*-
2
3 ;;; Mes --- Maxwell Equations of Software
4 ;;; Copyright © 2016,2017,2018 Jan (janneke) Nieuwenhuizen <janneke@gnu.org>
5 ;;;
6 ;;; This file is part of Mes.
7 ;;;
8 ;;; Mes is free software; you can redistribute it and/or modify it
9 ;;; under the terms of the GNU General Public License as published by
10 ;;; the Free Software Foundation; either version 3 of the License, or (at
11 ;;; your option) any later version.
12 ;;;
13 ;;; Mes is distributed in the hope that it will be useful, but
14 ;;; WITHOUT ANY WARRANTY; without even the implied warranty of
15 ;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
16 ;;; GNU General Public License for more details.
17 ;;;
18 ;;; You should have received a copy of the GNU General Public License
19 ;;; along with Mes.  If not, see <http://www.gnu.org/licenses/>.
20
21 ;;; Commentary:
22
23 ;;; scm.mes is loaded after base, quasiquote and let.  It provides
24 ;;; basic Scheme functions bringing Mes close to basic RRS Scheme (no
25 ;;; labels, processes, fluids or throw/catch).
26
27 ;;; Code:
28
29 (mes-use-module (mes let))
30
31 (define (cadddr x) (car (cdddr x)))
32
33 (define-macro (case val . args)
34   (if (null? args) #f
35       (let ((clause (car args)))
36         (let ((pred (car clause)))
37           (let ((body (cdr clause)))
38            (if (pair? pred) `(if ,(if (null? (cdr pred))
39                                       `(eq? ,val ',(car pred))
40                                       `(member ,val ',pred))
41                                  (begin ,@body)
42                                  (case ,val ,@(cdr args)))
43                `(begin ,@body)))))))
44
45 (define-macro (when expr . body)
46   `(if ,expr
47        ((lambda () ,@body))))
48
49 (define-macro (unless expr . body)
50   `(if (not ,expr)
51        ((lambda () ,@body))))
52
53 (define-macro (do init test . body)
54   `(let loop ((,(caar init) ,(cadar init)))
55      (when (not ,@test)
56        ,@body
57        (loop ,@(cddar init)))))
58
59 (define (for-each f l . r)
60   (if (pair? l) (if (null? r) (begin (f (car l)) (for-each f (cdr l)))
61                     (if (null? (cdr r)) (begin (f (car l) (caar r)) (for-each f (cdr l) (cdar r)))))))
62
63 (define core:error error)
64
65 (define (error who . rest)
66   (display "error:" (current-error-port))
67   (display who (current-error-port))
68   (display ":" (current-error-port))
69   (display rest (current-error-port))
70   (newline (current-error-port))
71   (display "exiting...\n" (current-error-port))
72   (core:error (if (symbol? who) who 'error) (cons who rest)))
73
74 (define (syntax-error message . rest)
75   (display "syntax-error:" (current-error-port))
76   (display message (current-error-port))
77   (display ":" (current-error-port))
78   (display rest (current-error-port))
79   (newline (current-error-port))
80   (core:error 'syntax-error (cons message rest)))
81
82 \f
83 (define integer? number?)
84
85 (if (not (defined? 'peek-char))
86     (define (peek-char)
87       (integer->char (peek-byte))))
88
89 (if (not (defined? 'read-char))
90     (define (read-char)
91       (integer->char (read-byte))))
92
93 (if (not (defined? 'unread-char))
94     (define (unread-char c)
95       (integer->char (unread-byte (char->integer c)))))
96
97 (define (assq-set! alist key val)
98   (let ((entry (assq key alist)))
99     (if (not entry) (acons key val alist)
100         (let ((entry (set-cdr! entry val)))
101           alist))))
102
103 (define (assq-ref alist key)
104   (let ((entry (assq key alist)))
105     (if entry (cdr entry)
106         #f)))
107
108 (define assv assq)
109 (define assv-ref assq-ref)
110
111 (define (assoc key alist)
112   (if (not (pair? alist)) #f
113       (if (equal? key (caar alist)) (car alist)
114           (assoc key (cdr alist)))))
115
116 (define (assoc-ref alist key)
117   (let ((entry (assoc key alist)))
118     (if entry (cdr entry)
119         #f)))
120
121 (define (assoc-set! alist key value)
122   (let ((entry (assoc key alist)))
123     (if (not entry) (acons key value alist)
124         (let ((entry (set-cdr! entry value)))
125           alist))))
126
127 (define memv memq)
128
129 (define (member x lst)
130   (if (null? lst) #f
131       (if (equal? x (car lst)) lst
132           (member x (cdr lst)))))
133
134 \f
135 ;;; Lists
136 (define (make-list n . x)
137   (let ((fill (if (pair? x) (car x) *unspecified*)))
138     (let loop ((n n))
139       (if (= 0 n) '()
140           (cons fill (loop (- n 1)))))))
141
142 (define (list-ref lst k)
143   (let loop ((lst lst) (k k))
144     (if (= 0 k) (car lst)
145         (loop (cdr lst) (- k 1)))))
146
147 (define (list-set! lst k v)
148   (let loop ((lst lst) (k k))
149     (if (= 0 k) (set-car! lst v)
150         (loop (cdr lst) (- k 1)))))
151
152 (define (list-head x n)
153   (if (= 0 n) '()
154       (cons (car x) (list-head (cdr x) (- n 1)))))
155
156 (define (list-tail x n)
157   (if (= 0 n) x
158       (list-tail (cdr x) (- n 1))))
159
160 (define (iota n)
161   (if (<= n 0) '()
162       (append2 (iota (- n 1)) (list (- n 1)))))
163
164 (define (reverse lst)
165   (let loop ((lst lst) (r '()))
166     (if (null? lst) r
167         (loop (cdr lst) (cons (car lst) r)))))
168
169 (define (filter pred lst)
170   (let loop ((lst lst))
171     (if (null? lst) '()
172         (if (pred (car lst))
173             (cons (car lst) (loop (cdr lst)))
174             (loop (cdr lst))))))
175
176 (define (delete x lst)
177   (filter (lambda (e) (not (equal? e x))) lst))
178
179 (define (delq x lst)
180   (filter (lambda (e) (not (eq? e x))) lst))
181
182 (define (compose proc . rest)
183   (if (null? rest) proc
184       (lambda args
185         (proc (apply (apply compose rest) args)))))
186
187 \f
188 ;; Vector
189 (define (vector . rest) (list->vector rest))
190 (define (make-vector n . x)
191   (if (null? x) (core:make-vector n)
192       (list->vector (apply make-list (cons n x)))))
193
194 (define (vector-copy x)
195   (list->vector (vector->list x)))
196
197 \f
198 ;;; Strings/srfi-13
199 (define (make-string n . fill)
200   (list->string (apply make-list n fill)))
201
202 (define (string-length s)
203   (length (string->list s)))
204
205 (define (string-ref s k)
206   (list-ref (string->list s) k))
207
208 (define (string-set! s k v)
209   (list->string (list-set! (string->list s) k v)))
210
211 (define (substring s start . rest)
212   (let* ((end (and (pair? rest) (car rest)))
213          (lst (list-tail (string->list s) start)))
214     (list->string (if (not end) lst
215                       (list-head lst (- end start))))))
216
217 (define (string-prefix? prefix string)
218   (let ((length (string-length string))
219         (prefix-length (string-length prefix)))
220   (and
221    (>= length prefix-length)
222    (equal? (substring string 0 prefix-length) prefix))))
223
224 (define (string-suffix? suffix string)
225   (let ((length (string-length string))
226         (suffix-length (string-length suffix)))
227     (and
228      (>= length suffix-length)
229      (equal? (substring string (- length suffix-length)) suffix))))
230
231 (define (string->number s . rest)
232   (let ((lst (string->list s)))
233     (and (pair? lst)
234          (let* ((radix (if (null? rest) 10 (car rest)))
235                 (sign (if (and (pair? lst) (char=? (car lst) #\-)) -1 1))
236                 (lst (if (= sign -1) (cdr lst) lst)))
237            (let loop ((lst lst) (n 0))
238              (if (null? lst) (* sign n)
239                  (let ((i (char->integer (car lst))))
240                    (cond ((and (>= i (char->integer #\0))
241                                (<= i (char->integer #\9)))
242                           (let ((d (char->integer #\0)))
243                             (loop (cdr lst) (+ (* n radix) (- i d)))))
244                          ((and (= radix 16)
245                                (>= i (char->integer #\a))
246                                (<= i (char->integer #\f)))
247                           (let ((d (char->integer #\a)))
248                             (loop (cdr lst) (+ (* n radix) (- i (- d 10))))))
249                          ((= i (char->integer #\.)) ; minimal FLOAT support
250                           (let ((fraction (cdr lst)))
251                             (if (null? fraction) n
252                                 (let ((fraction ((compose string->number list->string) fraction)))
253                                   (and fraction n))))) ; FLOAT as integer
254                          (else #f)))))))))
255
256 (define inexact->exact identity)
257
258 (define (number->string n . rest)
259   (let* ((radix (if (null? rest) 10 (car rest)))
260          (sign (if (< n 0) '(#\-) '())))
261     (let loop ((n (abs n)) (lst '()))
262       (let* ((i (remainder n radix))
263              (lst (cons (integer->char (+ i (if (< i 10) (char->integer #\0)
264                                                 (- (char->integer #\a) 10)))) lst))
265              (n (quotient n radix)))
266         (if (= 0 n) (list->string (append sign lst))
267             (loop n lst))))))
268
269 \f
270 ;;; Symbols
271 (define (symbol-prefix? prefix symbol)
272   (string-prefix? (symbol->string prefix) (symbol->string symbol)))
273
274 (define (symbol-append . rest)
275   (string->symbol (apply string-append (map symbol->string rest))))
276
277 (define gensym
278   (let ((counter 0))
279     (lambda (. rest)
280       (let ((value (number->string counter)))
281         (set! counter (+ counter 1))
282         (string->symbol (string-append "g" value))))))
283
284 \f
285 ;;; Keywords
286 (define (keyword->symbol s)
287   (list->symbol (keyword->list s)))
288
289 \f
290 ;;; Characters
291 (define (char=? x y)
292   (and (char? x) (char? y)
293        (eq? x y)))
294
295 (define (char<? a b) (< (char->integer a) (char->integer b)))
296 (define (char>? a b) (> (char->integer a) (char->integer b)))
297 (define (char<=? a b) (<= (char->integer a) (char->integer b)))
298 (define (char>=? a b) (>= (char->integer a) (char->integer b)))
299
300 (define (char-alphabetic? x)
301   (and (char? x)
302        (let ((i (char->integer x)))
303         (or (and (>= i (char->integer #\A)) (<= i (char->integer #\Z)))
304             (and (>= i (char->integer #\a)) (<= i (char->integer #\z)))))))
305
306 (define (char-numeric? x)
307   (and (char? x)
308        (let ((i (char->integer x)))
309          (and (>= i (char->integer #\0)) (<= i (char->integer #\9))))))
310
311 \f
312 ;;; Math
313 (define quotient /)
314
315 (define (<= . rest)
316   (or (apply < rest)
317       (apply = rest)))
318
319 (define (>= . rest)
320   (or (apply > rest)
321       (apply = rest)))
322
323 (define (remainder x y)
324   (- x (* (quotient x y) y)))
325
326 (define (even? x)
327   (= 0 (remainder x 2)))
328
329 (define (odd? x)
330   (= 1 (remainder x 2)))
331
332 (define (negative? x)
333   (< x 0))
334
335 (define (positive? x)
336   (> x 0))
337
338 (define (zero? x)
339   (= x 0))
340
341 (define (1+ x)
342   (+ x 1))
343
344 (define (1- x)
345   (- x 1))
346
347 (define (abs x)
348   (if (>= x 0) x (- x)))
349
350 (define (expt x y)
351   (let loop ((s 1) (count y))
352     (if (= 0 count) s
353         (loop (* s x) (- count 1)))))
354
355 (define (max x . rest)
356   (if (null? rest) x
357       (let ((y (car rest)))
358         (let ((z (if (> x y) x y)))
359           (apply max (cons z (cdr rest)))))))
360
361 (define (min x . rest)
362   (if (null? rest) x
363       (let ((y (car rest)))
364         (let ((z (if (< x y) x y)))
365           (apply min (cons z (cdr rest)))))))
366
367 (define (negate proc)
368   (lambda args
369     (not (apply proc args))))
370
371 (define (const . rest)
372   (lambda (. _)
373     (car rest)))