d39fee3507526cb4b2def92fa20621b2f9542800
[mes.git] / module / mes / scm.mes
1 ;;; -*-scheme-*-
2
3 ;;; Mes --- Maxwell Equations of Software
4 ;;; Copyright © 2016 Jan Nieuwenhuizen <janneke@gnu.org>
5 ;;;
6 ;;; This file is part of Mes.
7 ;;;
8 ;;; Mes is free software; you can redistribute it and/or modify it
9 ;;; under the terms of the GNU General Public License as published by
10 ;;; the Free Software Foundation; either version 3 of the License, or (at
11 ;;; your option) any later version.
12 ;;;
13 ;;; Mes is distributed in the hope that it will be useful, but
14 ;;; WITHOUT ANY WARRANTY; without even the implied warranty of
15 ;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
16 ;;; GNU General Public License for more details.
17 ;;;
18 ;;; You should have received a copy of the GNU General Public License
19 ;;; along with Mes.  If not, see <http://www.gnu.org/licenses/>.
20
21 ;;; Commentary:
22
23 ;;; scm.mes is loaded after base, quasiquote and let.  It provides
24 ;;; basic Scheme functions bringing Mes close to basic RRS Scheme (no
25 ;;; labels, processes, fluids or throw/catch).
26
27 ;;; Code:
28
29 (mes-use-module (mes let))
30
31 (define (cadddr x) (car (cdddr x)))
32
33 (define (list . rest) rest)
34
35 (define (list-head x n)
36   (if (= 0 n) '()
37       (cons (car x) (list-head (cdr x) (- n 1)))))
38
39 (define (list-tail x n)
40   (if (= 0 n) x
41       (list-tail (cdr x) (- n 1))))
42
43 (define (string-prefix? prefix string)
44   (and
45    (>= (string-length string) (string-length prefix))
46    (equal? (substring string 0 (string-length prefix)) prefix)))
47
48 (define (symbol-prefix? prefix symbol)
49   (string-prefix? (symbol->string prefix) (symbol->string symbol)))
50
51 (define (symbol-append . rest)
52   (string->symbol (apply string-append (map symbol->string rest))))
53
54 (define-macro (case val . args)
55   (if (null? args) #f
56       (let ((clause (car args)))
57         (let ((pred (car clause)))
58           (let ((body (cdr clause)))
59            (if (pair? pred) `(if ,(if (null? (cdr pred))
60                                       `(eq? ,val ',(car pred))
61                                       `(member ,val ',pred))
62                                  (begin ,@body)
63                                  (case ,val ,@(cdr args)))
64                `(begin ,@body)))))))
65
66 (define-macro (when expr . body)
67   `(if ,expr
68        ((lambda () ,@body))))
69
70 (define-macro (unless expr . body)
71   `(if (not ,expr)
72        ((lambda () ,@body))))
73
74 (define-macro (do init test . body)
75   `(let loop ((,(caar init) ,(cadar init)))
76      (when (not ,@test)
77        ,@body
78        (loop ,@(cddar init)))))
79
80 (define integer? number?)
81
82 (define (make-list n . x)
83   (let ((fill (if (pair? x) (car x) *unspecified*)))
84     (let loop ((n n))
85       (if (= 0 n) '()
86           (cons fill (loop (- n 1)))))))
87
88 (define (string->list s)
89   (let ((n (string-length s)))
90     (let loop ((i 0))
91       (if (= i n) '()
92           (cons (string-ref s i) (loop (+ i 1)))))))
93
94 (define (vector . rest) (list->vector rest))
95 (define c:make-vector make-vector)
96 (define (make-vector n . x)
97   (if (null? x) (c:make-vector n)
98       (list->vector (apply make-list (cons n x)))))
99
100 (define (acons key value alist)
101   (cons (cons key value) alist))
102
103 (define (assq-set! alist key val)
104   (let ((entry (assq key alist)))
105     (cond (entry (set-cdr! entry val)
106                  alist)
107           (#t (cons (cons key val) alist)))))
108
109 (define (assq-ref alist key)
110   (let ((entry (assq key alist)))
111     (if entry (cdr entry)
112         #f)))
113
114 (define assv assq)
115 (define assv-ref assq-ref)
116
117 (define (assoc key alist)
118   (if (null? alist) #f ;; IF
119       (if (equal? key (caar alist)) (car alist)
120           (assoc key (cdr alist)))))
121
122 (define (assoc-ref alist key)
123   (let ((entry (assoc key alist)))
124     (if entry (cdr entry)
125         #f)))
126
127 (define (memq x lst)
128   (if (null? lst) #f ;; IF
129       (if (eq? x (car lst)) lst
130           (memq x (cdr lst)))))
131 (define memv memq)
132
133 (define (member x lst)
134   (if (null? lst) #f ;; IF
135       (if (equal? x (car lst)) lst
136           (member x (cdr lst)))))
137
138 (define (for-each f l . r)
139   (if (pair? l) (if (null? r) (begin (f (car l)) (for-each f (cdr l)))
140                     (if (null? (cdr r)) (begin (f (car l) (caar r)) (for-each f (cdr l) (cdar r)))))))
141
142 (define (<= . rest)
143   (or (apply < rest)
144       (apply = rest)))
145
146 (define (>= . rest)
147   (or (apply > rest)
148       (apply = rest)))
149
150 ;; (define (>= . rest)
151 ;;   (if (apply > rest) #t
152 ;;       (if (apply = rest) #t
153 ;;           #f)))
154
155 (define (remainder x y)
156   (- x (* (quotient x y) y)))
157
158 (define (even? x)
159   (= 0 (remainder x 2)))
160
161 (define (odd? x)
162   (= 1 (remainder x 2)))
163
164 (define (negative? x)
165   (< x 0))
166
167 (define (positive? x)
168   (> x 0))
169
170 (define (zero? x)
171   (= x 0))
172
173 (define (1+ x)
174   (+ x 1))
175
176 (define (1- x)
177   (- x 1))
178
179 (define (expt x y)
180   (let loop ((s 1) (count y))
181     (if (= 0 count) s
182         (loop (* s x) (- count 1)))))
183
184 (define (max x . rest)
185   (if (null? rest) x
186       (let ((y (car rest)))
187         (let ((z (if (> x y) x y)))
188           (apply max (cons z (cdr rest)))))))
189
190 (define (min x . rest)
191   (if (null? rest) x
192       (let ((y (car rest)))
193         (let ((z (if (< x y) x y)))
194           (apply min (cons z (cdr rest)))))))
195
196 (define gensym
197   (let ((counter 0))
198     (lambda (. rest)
199       (let ((value (number->string counter)))
200         (set! counter (+ counter 1))
201         (string->symbol (string-append "g" value))))))
202
203 (define else #t)
204
205 (define (error who . rest)
206   (display "error:" (current-error-port))
207   (display who (current-error-port))
208   (display ":" (current-error-port))
209   (display rest (current-error-port))
210   (newline (current-error-port))
211   (display "exiting...\n" (current-error-port))
212   (exit 1))
213
214 (define (syntax-error message . rest)
215   (display "syntax-error:" (current-error-port))
216   (display message (current-error-port))
217   (display ":" (current-error-port))
218   (display rest (current-error-port))
219   (newline (current-error-port)))
220
221 (define (list-ref lst k)
222   (let loop ((lst lst) (k k))
223     (if (= 0 k) (car lst)
224         (loop (cdr lst) (- k 1)))))
225
226 (define (iota n)
227   (if (<= n 0) '()
228       (append2 (iota (- n 1)) (list (- n 1)))))
229
230 ;; srfi-1
231 (define (last-pair lst)
232   (let loop ((lst lst))
233     (if (or (null? lst) (null? (cdr lst))) lst
234         (loop (cdr lst)))))
235
236 (define (reverse lst)
237   (if (null? lst) '()
238       (append (reverse (cdr lst)) (cons (car lst) '()))))
239
240 (define (filter pred lst)
241   (let loop ((lst lst))
242     (if (null? lst) '()
243         (if (pred (car lst))
244             (cons (car lst) (loop (cdr lst)))
245             (loop (cdr lst))))))
246
247 (define (delete x lst)
248   (filter (lambda (e) (not (equal? e x))) lst))
249
250 (define (delq x lst)
251   (filter (lambda (e) (not (eq? e x))) lst))
252
253 (define (vector-copy x)
254   (list->vector (vector->list x)))
255
256 (define (eof-object? x)
257   (or (and (number? x) (= x -1))
258       (and (char? x) (eof-object? (char->integer x)))))
259
260 (define (char=? x y)
261   (and (char? x) (char? y)
262        (eq? x y)))
263
264 (define (char-alphabetic? x)
265   (and (char? x)
266        (let ((i (char->integer x)))
267         (or (and (>= i (char->integer #\A)) (<= i (char->integer #\Z)))
268             (and (>= i (char->integer #\a)) (<= i (char->integer #\z)))))))
269
270 (define (char-numeric? x)
271   (and (char? x)
272        (let ((i (char->integer x)))
273          (and (>= i (char->integer #\0)) (<= i (char->integer #\9))))))