Add negative?, positive?, zero?, 1+ 1-.
[mes.git] / module / mes / scm.mes
1 ;;; -*-scheme-*-
2
3 ;;; Mes --- Maxwell Equations of Software
4 ;;; Copyright © 2016 Jan Nieuwenhuizen <janneke@gnu.org>
5 ;;;
6 ;;; This file is part of Mes.
7 ;;;
8 ;;; Mes is free software; you can redistribute it and/or modify it
9 ;;; under the terms of the GNU General Public License as published by
10 ;;; the Free Software Foundation; either version 3 of the License, or (at
11 ;;; your option) any later version.
12 ;;;
13 ;;; Mes is distributed in the hope that it will be useful, but
14 ;;; WITHOUT ANY WARRANTY; without even the implied warranty of
15 ;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
16 ;;; GNU General Public License for more details.
17 ;;;
18 ;;; You should have received a copy of the GNU General Public License
19 ;;; along with Mes.  If not, see <http://www.gnu.org/licenses/>.
20
21 ;;; Commentary:
22
23 ;;; scm.mes is loaded after base, quasiquote and let.  It provides
24 ;;; basic Scheme functions bringing Mes close to basic RRS Scheme (no
25 ;;; labels, processes, fluids or throw/catch).
26
27 ;;; Code:
28
29 (mes-use-module (mes let))
30
31 (define (cadddr x) (car (cdddr x)))
32
33 (define (list . rest) rest)
34
35 (define (list-head x n)
36   (if (= 0 n) '()
37       (cons (car x) (list-head (cdr x) (- n 1)))))
38
39 (define (list-tail x n)
40   (if (= 0 n) x
41       (list-tail (cdr x) (- n 1))))
42
43 (define (string-prefix? prefix string)
44   (and
45    (>= (string-length string) (string-length prefix))
46    (equal? (substring string 0 (string-length prefix)) prefix)))
47
48 (define (symbol-prefix? prefix symbol)
49   (string-prefix? (symbol->string prefix) (symbol->string symbol)))
50
51 (define (symbol-append . rest)
52   (string->symbol (apply string-append (map symbol->string rest))))
53
54 (define-macro (case val . args)
55   (if (null? args) #f
56       (let ((clause (car args)))
57         (let ((pred (car clause)))
58           (let ((body (cdr clause)))
59            (if (pair? pred) `(if ,(if (null? (cdr pred))
60                                       `(eq? ,val ',(car pred))
61                                       `(member ,val ',pred))
62                                  (begin ,@body)
63                                  (case ,val ,@(cdr args)))
64                `(begin ,@body)))))))
65
66 (define-macro (when expr . body)
67   `(if ,expr
68        ((lambda () ,@body))))
69
70 (define-macro (do init test . body)
71   `(let loop ((,(caar init) ,(cadar init)))
72      (when (not ,@test)
73        ,@body
74        (loop ,@(cddar init)))))
75
76 (define integer? number?)
77
78 (define (make-list n . x)
79   (let ((fill (if (pair? x) (car x) *unspecified*)))
80     (let loop ((n n))
81       (if (= 0 n) '()
82           (cons fill (loop (- n 1)))))))
83
84 (define (string->list s)
85   (let ((n (string-length s)))
86     (let loop ((i 0))
87       (if (= i n) '()
88           (cons (string-ref s i) (loop (+ i 1)))))))
89
90 (define (vector . rest) (list->vector rest))
91 (define c:make-vector make-vector)
92 (define (make-vector n . x)
93   (if (null? x) (c:make-vector n)
94       (list->vector (apply make-list (cons n x)))))
95
96 (define (acons key value alist)
97   (cons (cons key value) alist))
98
99 (define (assq-set! alist key val)
100   (let ((entry (assq key alist)))
101     (cond (entry (set-cdr! entry val)
102                  alist)
103           (#t (cons (cons key val) alist)))))
104
105 (define (assq-ref alist key)
106   (let ((entry (assq key alist)))
107     (if entry (cdr entry)
108         #f)))
109
110 (define assv assq)
111 (define assv-ref assq-ref)
112
113 (define (assoc key alist)
114   (if (null? alist) #f ;; IF
115       (if (equal? key (caar alist)) (car alist)
116           (assoc key (cdr alist)))))
117
118 (define (assoc-ref alist key)
119   (let ((entry (assoc key alist)))
120     (if entry (cdr entry)
121         #f)))
122
123 (define (memq x lst)
124   (if (null? lst) #f ;; IF
125       (if (eq? x (car lst)) lst
126           (memq x (cdr lst)))))
127 (define memv memq)
128
129 (define (member x lst)
130   (if (null? lst) #f ;; IF
131       (if (equal? x (car lst)) lst
132           (member x (cdr lst)))))
133
134 (define (for-each f l . r)
135   (if (pair? l) (if (null? r) (begin (f (car l)) (for-each f (cdr l)))
136                     (if (null? (cdr r)) (begin (f (car l) (caar r)) (for-each f (cdr l) (cdar r)))))))
137
138 (define (<= . rest)
139   (or (apply < rest)
140       (apply = rest)))
141
142 (define (>= . rest)
143   (or (apply > rest)
144       (apply = rest)))
145
146 ;; (define (>= . rest)
147 ;;   (if (apply > rest) #t
148 ;;       (if (apply = rest) #t
149 ;;           #f)))
150
151 (define (remainder x y)
152   (- x (* (quotient x y) y)))
153
154 (define (even? x)
155   (= 0 (remainder x 2)))
156
157 (define (odd? x)
158   (= 1 (remainder x 2)))
159
160 (define (negative? x)
161   (< x 0))
162
163 (define (positive? x)
164   (> x 0))
165
166 (define (zero? x)
167   (= x 0))
168
169 (define (1+ x)
170   (+ x 1))
171
172 (define (1- x)
173   (- x 1))
174
175 (define (expt x y)
176   (let loop ((s 1) (count y))
177     (if (= 0 count) s
178         (loop (* s x) (- count 1)))))
179
180 (define (max x . rest)
181   (if (null? rest) x
182       (let ((y (car rest)))
183         (let ((z (if (> x y) x y)))
184           (apply max (cons z (cdr rest)))))))
185
186 (define (min x . rest)
187   (if (null? rest) x
188       (let ((y (car rest)))
189         (let ((z (if (< x y) x y)))
190           (apply min (cons z (cdr rest)))))))
191
192 (define gensym
193   (let ((counter 0))
194     (lambda (. rest)
195       (let ((value (number->string counter)))
196         (set! counter (+ counter 1))
197         (string->symbol (string-append "g" value))))))
198
199 (define else #t)
200
201 (define (error who . rest)
202   (display "error:" (current-error-port))
203   (display who (current-error-port))
204   (display ":" (current-error-port))
205   (display rest (current-error-port))
206   (newline (current-error-port))
207   (display "exiting...\n" (current-error-port))
208   (exit 1))
209
210 (define (syntax-error message . rest)
211   (display "syntax-error:" (current-error-port))
212   (display message (current-error-port))
213   (display ":" (current-error-port))
214   (display rest (current-error-port))
215   (newline (current-error-port)))
216
217 (define (list-ref lst k)
218   (let loop ((lst lst) (k k))
219     (if (= 0 k) (car lst)
220         (loop (cdr lst) (- k 1)))))
221
222 ;; srfi-1
223 (define (last-pair lst)
224   (let loop ((lst lst))
225     (if (or (null? lst) (null? (cdr lst))) lst
226         (loop (cdr lst)))))
227
228 (define (reverse lst)
229   (if (null? lst) '()
230       (append (reverse (cdr lst)) (cons (car lst) '()))))
231
232 (define (eof-object? x)
233   (or (and (number? x) (= x -1))
234       (and (char? x) (eof-object? (char->integer x)))))
235
236 (define (char=? x y)
237   (and (char? x) (char? y)
238        (eq? x y)))
239
240 (define (char-alphabetic? x)
241   (and (char? x)
242        (let ((i (char->integer x)))
243         (or (and (>= i (char->integer #\A)) (<= i (char->integer #\Z)))
244             (and (>= i (char->integer #\a)) (<= i (char->integer #\z)))))))
245
246 (define (char-numeric? x)
247   (and (char? x)
248        (let ((i (char->integer x)))
249          (and (>= i (char->integer #\0)) (<= i (char->integer #\9))))))