Add string->number.
[mes.git] / module / mes / scm.mes
1 ;;; -*-scheme-*-
2
3 ;;; Mes --- Maxwell Equations of Software
4 ;;; Copyright © 2016 Jan Nieuwenhuizen <janneke@gnu.org>
5 ;;;
6 ;;; This file is part of Mes.
7 ;;;
8 ;;; Mes is free software; you can redistribute it and/or modify it
9 ;;; under the terms of the GNU General Public License as published by
10 ;;; the Free Software Foundation; either version 3 of the License, or (at
11 ;;; your option) any later version.
12 ;;;
13 ;;; Mes is distributed in the hope that it will be useful, but
14 ;;; WITHOUT ANY WARRANTY; without even the implied warranty of
15 ;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
16 ;;; GNU General Public License for more details.
17 ;;;
18 ;;; You should have received a copy of the GNU General Public License
19 ;;; along with Mes.  If not, see <http://www.gnu.org/licenses/>.
20
21 ;;; Commentary:
22
23 ;;; scm.mes is loaded after base, quasiquote and let.  It provides
24 ;;; basic Scheme functions bringing Mes close to basic RRS Scheme (no
25 ;;; labels, processes, fluids or throw/catch).
26
27 ;;; Code:
28
29 (mes-use-module (mes let))
30
31 (define (cadddr x) (car (cdddr x)))
32
33 (define (list . rest) rest)
34
35 (define (list-head x n)
36   (if (= 0 n) '()
37       (cons (car x) (list-head (cdr x) (- n 1)))))
38
39 (define (list-tail x n)
40   (if (= 0 n) x
41       (list-tail (cdr x) (- n 1))))
42
43 (define (string-prefix? prefix string)
44   (and
45    (>= (string-length string) (string-length prefix))
46    (equal? (substring string 0 (string-length prefix)) prefix)))
47
48 (define (symbol-prefix? prefix symbol)
49   (string-prefix? (symbol->string prefix) (symbol->string symbol)))
50
51 (define (symbol-append . rest)
52   (string->symbol (apply string-append (map symbol->string rest))))
53
54 (define-macro (case val . args)
55   (if (null? args) #f
56       (let ((clause (car args)))
57         (let ((pred (car clause)))
58           (let ((body (cdr clause)))
59            (if (pair? pred) `(if ,(if (null? (cdr pred))
60                                       `(eq? ,val ',(car pred))
61                                       `(member ,val ',pred))
62                                  (begin ,@body)
63                                  (case ,val ,@(cdr args)))
64                `(begin ,@body)))))))
65
66 (define-macro (when expr . body)
67   `(if ,expr
68        ((lambda () ,@body))))
69
70 (define-macro (unless expr . body)
71   `(if (not ,expr)
72        ((lambda () ,@body))))
73
74 (define-macro (do init test . body)
75   `(let loop ((,(caar init) ,(cadar init)))
76      (when (not ,@test)
77        ,@body
78        (loop ,@(cddar init)))))
79
80 (define integer? number?)
81
82 (define (make-list n . x)
83   (let ((fill (if (pair? x) (car x) *unspecified*)))
84     (let loop ((n n))
85       (if (= 0 n) '()
86           (cons fill (loop (- n 1)))))))
87
88 (define (string->list s)
89   (let ((n (string-length s)))
90     (let loop ((i 0))
91       (if (= i n) '()
92           (cons (string-ref s i) (loop (+ i 1)))))))
93
94 (define (string->number s . radix)
95   (if (and (pair? radix) (not (= (car radix) 10))) '*STRING->NUMBER:RADIX-NOT-SUPPORTED
96       (let* ((lst (string->list s))
97              (sign (if (char=? (car lst) #\-) -1 1))
98              (lst (if (= sign -1) (cdr lst) lst)))
99         (let loop ((lst lst) (n 0))
100           (if (null? lst) (* sign n)
101               (loop (cdr lst) (+ (* n 10) (- (char->integer (car lst)) (char->integer #\0)))))))))
102
103 (define (vector . rest) (list->vector rest))
104 (define c:make-vector make-vector)
105 (define (make-vector n . x)
106   (if (null? x) (c:make-vector n)
107       (list->vector (apply make-list (cons n x)))))
108
109 (define (acons key value alist)
110   (cons (cons key value) alist))
111
112 (define (assq-set! alist key val)
113   (let ((entry (assq key alist)))
114     (cond (entry (set-cdr! entry val)
115                  alist)
116           (#t (cons (cons key val) alist)))))
117
118 (define (assq-ref alist key)
119   (let ((entry (assq key alist)))
120     (if entry (cdr entry)
121         #f)))
122
123 (define assv assq)
124 (define assv-ref assq-ref)
125
126 (define (assoc key alist)
127   (if (null? alist) #f ;; IF
128       (if (equal? key (caar alist)) (car alist)
129           (assoc key (cdr alist)))))
130
131 (define (assoc-ref alist key)
132   (let ((entry (assoc key alist)))
133     (if entry (cdr entry)
134         #f)))
135
136 (define (memq x lst)
137   (if (null? lst) #f ;; IF
138       (if (eq? x (car lst)) lst
139           (memq x (cdr lst)))))
140 (define memv memq)
141
142 (define (member x lst)
143   (if (null? lst) #f ;; IF
144       (if (equal? x (car lst)) lst
145           (member x (cdr lst)))))
146
147 (define (for-each f l . r)
148   (if (pair? l) (if (null? r) (begin (f (car l)) (for-each f (cdr l)))
149                     (if (null? (cdr r)) (begin (f (car l) (caar r)) (for-each f (cdr l) (cdar r)))))))
150
151 (define (<= . rest)
152   (or (apply < rest)
153       (apply = rest)))
154
155 (define (>= . rest)
156   (or (apply > rest)
157       (apply = rest)))
158
159 ;; (define (>= . rest)
160 ;;   (if (apply > rest) #t
161 ;;       (if (apply = rest) #t
162 ;;           #f)))
163
164 (define (remainder x y)
165   (- x (* (quotient x y) y)))
166
167 (define (even? x)
168   (= 0 (remainder x 2)))
169
170 (define (odd? x)
171   (= 1 (remainder x 2)))
172
173 (define (negative? x)
174   (< x 0))
175
176 (define (positive? x)
177   (> x 0))
178
179 (define (zero? x)
180   (= x 0))
181
182 (define (1+ x)
183   (+ x 1))
184
185 (define (1- x)
186   (- x 1))
187
188 (define (expt x y)
189   (let loop ((s 1) (count y))
190     (if (= 0 count) s
191         (loop (* s x) (- count 1)))))
192
193 (define (max x . rest)
194   (if (null? rest) x
195       (let ((y (car rest)))
196         (let ((z (if (> x y) x y)))
197           (apply max (cons z (cdr rest)))))))
198
199 (define (min x . rest)
200   (if (null? rest) x
201       (let ((y (car rest)))
202         (let ((z (if (< x y) x y)))
203           (apply min (cons z (cdr rest)))))))
204
205 (define gensym
206   (let ((counter 0))
207     (lambda (. rest)
208       (let ((value (number->string counter)))
209         (set! counter (+ counter 1))
210         (string->symbol (string-append "g" value))))))
211
212 (define else #t)
213
214 (define (error who . rest)
215   (display "error:" (current-error-port))
216   (display who (current-error-port))
217   (display ":" (current-error-port))
218   (display rest (current-error-port))
219   (newline (current-error-port))
220   (display "exiting...\n" (current-error-port))
221   (exit 1))
222
223 (define (syntax-error message . rest)
224   (display "syntax-error:" (current-error-port))
225   (display message (current-error-port))
226   (display ":" (current-error-port))
227   (display rest (current-error-port))
228   (newline (current-error-port)))
229
230 (define (list-ref lst k)
231   (let loop ((lst lst) (k k))
232     (if (= 0 k) (car lst)
233         (loop (cdr lst) (- k 1)))))
234
235 (define (iota n)
236   (if (<= n 0) '()
237       (append2 (iota (- n 1)) (list (- n 1)))))
238
239 ;; srfi-1
240 (define (last-pair lst)
241   (let loop ((lst lst))
242     (if (or (null? lst) (null? (cdr lst))) lst
243         (loop (cdr lst)))))
244
245 (define (reverse lst)
246   (if (null? lst) '()
247       (append (reverse (cdr lst)) (cons (car lst) '()))))
248
249 (define (filter pred lst)
250   (let loop ((lst lst))
251     (if (null? lst) '()
252         (if (pred (car lst))
253             (cons (car lst) (loop (cdr lst)))
254             (loop (cdr lst))))))
255
256 (define (delete x lst)
257   (filter (lambda (e) (not (equal? e x))) lst))
258
259 (define (delq x lst)
260   (filter (lambda (e) (not (eq? e x))) lst))
261
262 (define (vector-copy x)
263   (list->vector (vector->list x)))
264
265 (define (eof-object? x)
266   (or (and (number? x) (= x -1))
267       (and (char? x) (eof-object? (char->integer x)))))
268
269 (define (char=? x y)
270   (and (char? x) (char? y)
271        (eq? x y)))
272
273 (define (char-alphabetic? x)
274   (and (char? x)
275        (let ((i (char->integer x)))
276         (or (and (>= i (char->integer #\A)) (<= i (char->integer #\Z)))
277             (and (>= i (char->integer #\a)) (<= i (char->integer #\z)))))))
278
279 (define (char-numeric? x)
280   (and (char? x)
281        (let ((i (char->integer x)))
282          (and (>= i (char->integer #\0)) (<= i (char->integer #\9))))))