7e5ea6186122bb96f913dda48c14110613383d8d
[mes.git] / module / mes / scm.mes
1 ;;; -*-scheme-*-
2
3 ;;; Mes --- Maxwell Equations of Software
4 ;;; Copyright © 2016,2017,2018 Jan (janneke) Nieuwenhuizen <janneke@gnu.org>
5 ;;;
6 ;;; This file is part of Mes.
7 ;;;
8 ;;; Mes is free software; you can redistribute it and/or modify it
9 ;;; under the terms of the GNU General Public License as published by
10 ;;; the Free Software Foundation; either version 3 of the License, or (at
11 ;;; your option) any later version.
12 ;;;
13 ;;; Mes is distributed in the hope that it will be useful, but
14 ;;; WITHOUT ANY WARRANTY; without even the implied warranty of
15 ;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
16 ;;; GNU General Public License for more details.
17 ;;;
18 ;;; You should have received a copy of the GNU General Public License
19 ;;; along with Mes.  If not, see <http://www.gnu.org/licenses/>.
20
21 ;;; Commentary:
22
23 ;;; scm.mes is loaded after base, quasiquote and let.  It provides
24 ;;; basic Scheme functions bringing Mes close to basic RRS Scheme (no
25 ;;; labels, processes, fluids or throw/catch).
26
27 ;;; Code:
28
29 (mes-use-module (mes let))
30
31 (define (cadddr x) (car (cdddr x)))
32
33 (define-macro (case val . args)
34   (if (null? args) #f
35       (let ((clause (car args)))
36         (let ((pred (car clause)))
37           (let ((body (cdr clause)))
38            (if (pair? pred) `(if ,(if (null? (cdr pred))
39                                       `(eq? ,val ',(car pred))
40                                       `(member ,val ',pred))
41                                  (begin ,@body)
42                                  (case ,val ,@(cdr args)))
43                `(begin ,@body)))))))
44
45 (define-macro (when expr . body)
46   `(if ,expr
47        ((lambda () ,@body))))
48
49 (define-macro (unless expr . body)
50   `(if (not ,expr)
51        ((lambda () ,@body))))
52
53 (define-macro (do init test . body)
54   `(let loop ((,(caar init) ,(cadar init)))
55      (when (not ,@test)
56        ,@body
57        (loop ,@(cddar init)))))
58
59 (define (for-each f l . r)
60   (if (pair? l) (if (null? r) (begin (f (car l)) (for-each f (cdr l)))
61                     (if (null? (cdr r)) (begin (f (car l) (caar r)) (for-each f (cdr l) (cdar r)))))))
62
63 (define core:error error)
64
65 (define (error who . rest)
66   (display "error:" (current-error-port))
67   (display who (current-error-port))
68   (display ":" (current-error-port))
69   (display rest (current-error-port))
70   (newline (current-error-port))
71   (display "exiting...\n" (current-error-port))
72   (core:error (if (symbol? who) who 'error) (cons who rest)))
73
74 (define (syntax-error message . rest)
75   (display "syntax-error:" (current-error-port))
76   (display message (current-error-port))
77   (display ":" (current-error-port))
78   (display rest (current-error-port))
79   (newline (current-error-port))
80   (core:error 'syntax-error (cons message rest)))
81
82 \f
83 (define integer? number?)
84
85 (if (not (defined? 'peek-char))
86     (define (peek-char)
87       (integer->char (peek-byte))))
88
89 (if (not (defined? 'read-char))
90     (define (read-char)
91       (integer->char (read-byte))))
92
93 (if (not (defined? 'unread-char))
94     (define (unread-char c)
95       (integer->char (unread-byte (char->integer c)))))
96
97 (define (assq-set! alist key val)
98   (let ((entry (assq key alist)))
99     (if (not entry) (acons key val alist)
100         (let ((entry (set-cdr! entry val)))
101           alist))))
102
103 (define (assq-ref alist key)
104   (let ((entry (assq key alist)))
105     (if entry (cdr entry)
106         #f)))
107
108 (define assv assq)
109 (define assv-ref assq-ref)
110
111 (define (assoc key alist)
112   (if (null? alist) #f
113       (if (equal? key (caar alist)) (car alist)
114           (assoc key (cdr alist)))))
115
116 (define (assoc-ref alist key)
117   (let ((entry (assoc key alist)))
118     (if entry (cdr entry)
119         #f)))
120
121 (define (assoc-set! alist key value)
122   (let ((entry (assoc key alist)))
123     (if (not entry) (acons key value alist)
124         (let ((entry (set-cdr! entry value)))
125           alist))))
126
127 (define memv memq)
128
129 (define (member x lst)
130   (if (null? lst) #f
131       (if (equal? x (car lst)) lst
132           (member x (cdr lst)))))
133
134 \f
135 ;;; Lists
136 (define (make-list n . x)
137   (let ((fill (if (pair? x) (car x) *unspecified*)))
138     (let loop ((n n))
139       (if (= 0 n) '()
140           (cons fill (loop (- n 1)))))))
141
142 (define (list-ref lst k)
143   (let loop ((lst lst) (k k))
144     (if (= 0 k) (car lst)
145         (loop (cdr lst) (- k 1)))))
146
147 (define (list-set! lst k v)
148   (let loop ((lst lst) (k k))
149     (if (= 0 k) (set-car! lst v)
150         (loop (cdr lst) (- k 1)))))
151
152 (define (list-head x n)
153   (if (= 0 n) '()
154       (cons (car x) (list-head (cdr x) (- n 1)))))
155
156 (define (list-tail x n)
157   (if (= 0 n) x
158       (list-tail (cdr x) (- n 1))))
159
160 (define (last-pair lst)
161   (let loop ((lst lst))
162     (if (or (null? lst) (null? (cdr lst))) lst
163         (loop (cdr lst)))))
164
165 (define (iota n)
166   (if (<= n 0) '()
167       (append2 (iota (- n 1)) (list (- n 1)))))
168
169 (define (reverse lst)
170   (if (null? lst) '()
171       (append (reverse (cdr lst)) (cons (car lst) '()))))
172
173 (define (filter pred lst)
174   (let loop ((lst lst))
175     (if (null? lst) '()
176         (if (pred (car lst))
177             (cons (car lst) (loop (cdr lst)))
178             (loop (cdr lst))))))
179
180 (define (delete x lst)
181   (filter (lambda (e) (not (equal? e x))) lst))
182
183 (define (delq x lst)
184   (filter (lambda (e) (not (eq? e x))) lst))
185
186 (define (compose proc . rest)
187   (if (null? rest) proc
188       (lambda args
189         (proc (apply (apply compose rest) args)))))
190
191 \f
192 ;; Vector
193 (define (vector . rest) (list->vector rest))
194 (define (make-vector n . x)
195   (if (null? x) (core:make-vector n)
196       (list->vector (apply make-list (cons n x)))))
197
198 (define (vector-copy x)
199   (list->vector (vector->list x)))
200
201 \f
202 ;;; Strings/srfi-13
203 (define (make-string n . fill)
204   (list->string (apply make-list n fill)))
205
206 (define (string-length s)
207   (length (string->list s)))
208
209 (define (string-ref s k)
210   (list-ref (string->list s) k))
211
212 (define (string-set! s k v)
213   (list->string (list-set! (string->list s) k v)))
214
215 (define (substring s start . rest)
216   (let* ((end (and (pair? rest) (car rest)))
217          (lst (list-tail (string->list s) start)))
218     (list->string (if (not end) lst
219                       (list-head lst (- end start))))))
220
221 (define (string-prefix? prefix string)
222   (let ((length (string-length string))
223         (prefix-length (string-length prefix)))
224   (and
225    (>= length prefix-length)
226    (equal? (substring string 0 prefix-length) prefix))))
227
228 (define (string-suffix? suffix string)
229   (let ((length (string-length string))
230         (suffix-length (string-length suffix)))
231     (and
232      (>= length suffix-length)
233      (equal? (substring string (- length suffix-length)) suffix))))
234
235 (define (string->number s . rest)
236   (let* ((radix (if (null? rest) 10 (car rest)))
237          (lst (string->list s))
238          (sign (if (char=? (car lst) #\-) -1 1))
239          (lst (if (= sign -1) (cdr lst) lst)))
240     (let loop ((lst lst) (n 0))
241       (if (null? lst) (* sign n)
242           (let ((i (char->integer (car lst))))
243             (loop (cdr lst) (+ (* n radix) (- i (if (<= i (char->integer #\9)) (char->integer #\0)
244                                                     (- (char->integer #\a) 10))))))))))
245
246 (define (number->string n . rest)
247   (let* ((radix (if (null? rest) 10 (car rest)))
248          (sign (if (< n 0) '(#\-) '())))
249     (let loop ((n (abs n)) (lst '()))
250       (let* ((i (remainder n radix))
251              (lst (cons (integer->char (+ i (if (< i 10) (char->integer #\0)
252                                                 (- (char->integer #\a) 10)))) lst))
253              (n (quotient n radix)))
254         (if (= 0 n) (list->string (append sign lst))
255             (loop n lst))))))
256
257 \f
258 ;;; Symbols
259 (define (symbol-prefix? prefix symbol)
260   (string-prefix? (symbol->string prefix) (symbol->string symbol)))
261
262 (define (symbol-append . rest)
263   (string->symbol (apply string-append (map symbol->string rest))))
264
265 (define gensym
266   (let ((counter 0))
267     (lambda (. rest)
268       (let ((value (number->string counter)))
269         (set! counter (+ counter 1))
270         (string->symbol (string-append "g" value))))))
271
272 \f
273 ;;; Keywords
274 (define (keyword->symbol s)
275   (list->symbol (keyword->list s)))
276
277 \f
278 ;;; Characters
279 (define (char=? x y)
280   (and (char? x) (char? y)
281        (eq? x y)))
282
283 (define (char<? a b) (< (char->integer a) (char->integer b)))
284 (define (char>? a b) (> (char->integer a) (char->integer b)))
285 (define (char<=? a b) (<= (char->integer a) (char->integer b)))
286 (define (char>=? a b) (>= (char->integer a) (char->integer b)))
287
288 (define (char-alphabetic? x)
289   (and (char? x)
290        (let ((i (char->integer x)))
291         (or (and (>= i (char->integer #\A)) (<= i (char->integer #\Z)))
292             (and (>= i (char->integer #\a)) (<= i (char->integer #\z)))))))
293
294 (define (char-numeric? x)
295   (and (char? x)
296        (let ((i (char->integer x)))
297          (and (>= i (char->integer #\0)) (<= i (char->integer #\9))))))
298
299 \f
300 ;;; Math
301 (define quotient /)
302
303 (define (<= . rest)
304   (or (apply < rest)
305       (apply = rest)))
306
307 (define (>= . rest)
308   (or (apply > rest)
309       (apply = rest)))
310
311 (define (remainder x y)
312   (- x (* (quotient x y) y)))
313
314 (define (even? x)
315   (= 0 (remainder x 2)))
316
317 (define (odd? x)
318   (= 1 (remainder x 2)))
319
320 (define (negative? x)
321   (< x 0))
322
323 (define (positive? x)
324   (> x 0))
325
326 (define (zero? x)
327   (= x 0))
328
329 (define (1+ x)
330   (+ x 1))
331
332 (define (1- x)
333   (- x 1))
334
335 (define (abs x)
336   (if (>= x 0) x (- x)))
337
338 (define (expt x y)
339   (let loop ((s 1) (count y))
340     (if (= 0 count) s
341         (loop (* s x) (- count 1)))))
342
343 (define (max x . rest)
344   (if (null? rest) x
345       (let ((y (car rest)))
346         (let ((z (if (> x y) x y)))
347           (apply max (cons z (cdr rest)))))))
348
349 (define (min x . rest)
350   (if (null? rest) x
351       (let ((y (car rest)))
352         (let ((z (if (< x y) x y)))
353           (apply min (cons z (cdr rest)))))))
354
355 (define (negate proc)
356   (lambda args
357     (not (apply proc args))))