6e58bfff4a2b5a16857109eeda68f265465348cd
[mes.git] / module / mes / scm.mes
1 ;;; -*-scheme-*-
2
3 ;;; Mes --- Maxwell Equations of Software
4 ;;; Copyright © 2016,2017 Jan Nieuwenhuizen <janneke@gnu.org>
5 ;;;
6 ;;; This file is part of Mes.
7 ;;;
8 ;;; Mes is free software; you can redistribute it and/or modify it
9 ;;; under the terms of the GNU General Public License as published by
10 ;;; the Free Software Foundation; either version 3 of the License, or (at
11 ;;; your option) any later version.
12 ;;;
13 ;;; Mes is distributed in the hope that it will be useful, but
14 ;;; WITHOUT ANY WARRANTY; without even the implied warranty of
15 ;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
16 ;;; GNU General Public License for more details.
17 ;;;
18 ;;; You should have received a copy of the GNU General Public License
19 ;;; along with Mes.  If not, see <http://www.gnu.org/licenses/>.
20
21 ;;; Commentary:
22
23 ;;; scm.mes is loaded after base, quasiquote and let.  It provides
24 ;;; basic Scheme functions bringing Mes close to basic RRS Scheme (no
25 ;;; labels, processes, fluids or throw/catch).
26
27 ;;; Code:
28
29 (mes-use-module (mes let))
30
31 (define (cadddr x) (car (cdddr x)))
32
33 (define-macro (case val . args)
34   (if (null? args) #f
35       (let ((clause (car args)))
36         (let ((pred (car clause)))
37           (let ((body (cdr clause)))
38            (if (pair? pred) `(if ,(if (null? (cdr pred))
39                                       `(eq? ,val ',(car pred))
40                                       `(member ,val ',pred))
41                                  (begin ,@body)
42                                  (case ,val ,@(cdr args)))
43                `(begin ,@body)))))))
44
45 (define-macro (when expr . body)
46   `(if ,expr
47        ((lambda () ,@body))))
48
49 (define-macro (unless expr . body)
50   `(if (not ,expr)
51        ((lambda () ,@body))))
52
53 (define-macro (do init test . body)
54   `(let loop ((,(caar init) ,(cadar init)))
55      (when (not ,@test)
56        ,@body
57        (loop ,@(cddar init)))))
58
59 (define (for-each f l . r)
60   (if (pair? l) (if (null? r) (begin (f (car l)) (for-each f (cdr l)))
61                     (if (null? (cdr r)) (begin (f (car l) (caar r)) (for-each f (cdr l) (cdar r)))))))
62
63 (define core:error error)
64
65 (define (error who . rest)
66   (display "error:" (current-error-port))
67   (display who (current-error-port))
68   (display ":" (current-error-port))
69   (display rest (current-error-port))
70   (newline (current-error-port))
71   (display "exiting...\n" (current-error-port))
72   (core:error (if (symbol? who) who 'error) (cons who rest)))
73
74 (define (syntax-error message . rest)
75   (display "syntax-error:" (current-error-port))
76   (display message (current-error-port))
77   (display ":" (current-error-port))
78   (display rest (current-error-port))
79   (newline (current-error-port))
80   (core:error 'syntax-error (cons message rest)))
81
82 \f
83 (define integer? number?)
84
85 (define (eof-object? x)
86   (or (and (number? x) (= x -1))
87       (and (char? x) (eof-object? (char->integer x)))))
88
89 (define (peek-char)
90   (integer->char (peek-byte)))
91
92 (define (read-char)
93   (integer->char (read-byte)))
94
95 (define (unread-char c)
96   (unread-byte (char->integer c))
97   c)
98
99 (define (assq-set! alist key val)
100   (let ((entry (assq key alist)))
101     (if (not entry) (acons key val alist)
102         (let ((entry (set-cdr! entry val)))
103           alist))))
104
105 (define (assq-ref alist key)
106   (let ((entry (assq key alist)))
107     (if entry (cdr entry)
108         #f)))
109
110 (define assv assq)
111 (define assv-ref assq-ref)
112
113 (define (assoc key alist)
114   (if (null? alist) #f ;; IF
115       (if (equal? key (caar alist)) (car alist)
116           (assoc key (cdr alist)))))
117
118 (define (assoc-ref alist key)
119   (let ((entry (assoc key alist)))
120     (if entry (cdr entry)
121         #f)))
122
123 (define (assoc-set! alist key value)
124   (let ((entry (assoc key alist)))
125     (if (not entry) (acons key value alist)
126         (let ((entry (set-cdr! entry value)))
127           alist))))
128
129 (define (memq x lst)
130   (if (null? lst) #f ;; IF
131       (if (eq? x (car lst)) lst
132           (memq x (cdr lst)))))
133 (define memv memq)
134
135 (define (member x lst)
136   (if (null? lst) #f ;; IF
137       (if (equal? x (car lst)) lst
138           (member x (cdr lst)))))
139
140 \f
141 ;;; Lists
142 (define (make-list n . x)
143   (let ((fill (if (pair? x) (car x) *unspecified*)))
144     (let loop ((n n))
145       (if (= 0 n) '()
146           (cons fill (loop (- n 1)))))))
147
148 (define (list-ref lst k)
149   (let loop ((lst lst) (k k))
150     (if (= 0 k) (car lst)
151         (loop (cdr lst) (- k 1)))))
152
153 (define (list-set! lst k v)
154   (let loop ((lst lst) (k k))
155     (if (= 0 k) (set-car! lst v)
156         (loop (cdr lst) (- k 1)))))
157
158 (define (list-head x n)
159   (if (= 0 n) '()
160       (cons (car x) (list-head (cdr x) (- n 1)))))
161
162 (define (list-tail x n)
163   (if (= 0 n) x
164       (list-tail (cdr x) (- n 1))))
165
166 (define (last-pair lst)
167   (let loop ((lst lst))
168     (if (or (null? lst) (null? (cdr lst))) lst
169         (loop (cdr lst)))))
170
171 (define (iota n)
172   (if (<= n 0) '()
173       (append2 (iota (- n 1)) (list (- n 1)))))
174
175 (define (reverse lst)
176   (if (null? lst) '()
177       (append (reverse (cdr lst)) (cons (car lst) '()))))
178
179 (define (filter pred lst)
180   (let loop ((lst lst))
181     (if (null? lst) '()
182         (if (pred (car lst))
183             (cons (car lst) (loop (cdr lst)))
184             (loop (cdr lst))))))
185
186 (define (delete x lst)
187   (filter (lambda (e) (not (equal? e x))) lst))
188
189 (define (delq x lst)
190   (filter (lambda (e) (not (eq? e x))) lst))
191
192 (define (compose proc . rest)
193   (if (null? rest) proc
194       (lambda args
195         (proc (apply (apply compose rest) args)))))
196
197 \f
198 ;; Vector
199 (define (vector . rest) (list->vector rest))
200 (define c:make-vector make-vector)
201 (define (make-vector n . x)
202   (if (null? x) (c:make-vector n)
203       (list->vector (apply make-list (cons n x)))))
204
205 (define (vector-copy x)
206   (list->vector (vector->list x)))
207
208 \f
209 ;;; Strings/srfi-13
210 (define (string-length s)
211   (length (string->list s)))
212
213 (define (string-ref s k)
214   (list-ref (string->list s) k))
215
216 (define (string-set! s k v)
217   (list->string (list-set! (string->list s) k v)))
218
219 (define (substring s start . rest)
220   (let* ((end (and (pair? rest) (car rest)))
221          (lst (list-tail (string->list s) start)))
222     (list->string (if (not end) lst
223                       (list-head lst (- end start))))))
224
225 (define (string-prefix? prefix string)
226   (let ((length (string-length string))
227         (prefix-length (string-length prefix)))
228   (and
229    (>= length prefix-length)
230    (equal? (substring string 0 prefix-length) prefix))))
231
232 (define (string-suffix? suffix string)
233   (let ((length (string-length string))
234         (suffix-length (string-length suffix)))
235     (and
236      (>= length suffix-length)
237      (equal? (substring string (- length suffix-length)) suffix))))
238
239 (define (string->number s . rest)
240   (let* ((radix (if (null? rest) 10 (car rest)))
241          (lst (string->list s))
242          (sign (if (char=? (car lst) #\-) -1 1))
243          (lst (if (= sign -1) (cdr lst) lst)))
244     (let loop ((lst lst) (n 0))
245       (if (null? lst) (* sign n)
246           (let ((i (char->integer (car lst))))
247             (loop (cdr lst) (+ (* n radix) (- i (if (<= i (char->integer #\9)) (char->integer #\0)
248                                                     (- (char->integer #\a) 10))))))))))
249
250 (define (number->string n . rest)
251   (let* ((radix (if (null? rest) 10 (car rest)))
252          (sign (if (< n 0) '(#\-) '())))
253     (let loop ((n (abs n)) (lst '()))
254       (let* ((i (remainder n radix))
255              (lst (cons (integer->char (+ i (if (<= i 10) (char->integer #\0)
256                                                 (- (char->integer #\a) 10)))) lst))
257              (n (quotient n radix)))
258         (if (= 0 n) (list->string (append sign lst))
259             (loop n lst))))))
260
261 \f
262 ;;; Symbols
263 (define (symbol-prefix? prefix symbol)
264   (string-prefix? (symbol->string prefix) (symbol->string symbol)))
265
266 (define (symbol-append . rest)
267   (string->symbol (apply string-append (map symbol->string rest))))
268
269 (define gensym
270   (let ((counter 0))
271     (lambda (. rest)
272       (let ((value (number->string counter)))
273         (set! counter (+ counter 1))
274         (string->symbol (string-append "g" value))))))
275
276 \f
277 ;;; Keywords
278 (define (keyword->symbol s)
279   (list->symbol (keyword->list s)))
280
281 \f
282 ;;; Characters
283 (define (char=? x y)
284   (and (char? x) (char? y)
285        (eq? x y)))
286
287 (define (char<? a b) (< (char->integer a) (char->integer b)))
288 (define (char>? a b) (> (char->integer a) (char->integer b)))
289 (define (char<=? a b) (<= (char->integer a) (char->integer b)))
290 (define (char>=? a b) (>= (char->integer a) (char->integer b)))
291
292 (define (char-alphabetic? x)
293   (and (char? x)
294        (let ((i (char->integer x)))
295         (or (and (>= i (char->integer #\A)) (<= i (char->integer #\Z)))
296             (and (>= i (char->integer #\a)) (<= i (char->integer #\z)))))))
297
298 (define (char-numeric? x)
299   (and (char? x)
300        (let ((i (char->integer x)))
301          (and (>= i (char->integer #\0)) (<= i (char->integer #\9))))))
302
303 \f
304 ;;; Math
305 (define quotient /)
306
307 (define (<= . rest)
308   (or (apply < rest)
309       (apply = rest)))
310
311 (define (>= . rest)
312   (or (apply > rest)
313       (apply = rest)))
314
315 (define (remainder x y)
316   (- x (* (quotient x y) y)))
317
318 (define (even? x)
319   (= 0 (remainder x 2)))
320
321 (define (odd? x)
322   (= 1 (remainder x 2)))
323
324 (define (negative? x)
325   (< x 0))
326
327 (define (positive? x)
328   (> x 0))
329
330 (define (zero? x)
331   (= x 0))
332
333 (define (1+ x)
334   (+ x 1))
335
336 (define (1- x)
337   (- x 1))
338
339 (define (abs x)
340   (if (>= x 0) x (- x)))
341
342 (define (expt x y)
343   (let loop ((s 1) (count y))
344     (if (= 0 count) s
345         (loop (* s x) (- count 1)))))
346
347 (define (max x . rest)
348   (if (null? rest) x
349       (let ((y (car rest)))
350         (let ((z (if (> x y) x y)))
351           (apply max (cons z (cdr rest)))))))
352
353 (define (min x . rest)
354   (if (null? rest) x
355       (let ((y (car rest)))
356         (let ((z (if (< x y) x y)))
357           (apply min (cons z (cdr rest)))))))