438568ade9ddaa0229daa898eecd36358d12b95b
[mes.git] / module / mes / scm.mes
1 ;;; -*-scheme-*-
2
3 ;;; Mes --- Maxwell Equations of Software
4 ;;; Copyright © 2016,2017,2018 Jan Nieuwenhuizen <janneke@gnu.org>
5 ;;;
6 ;;; This file is part of Mes.
7 ;;;
8 ;;; Mes is free software; you can redistribute it and/or modify it
9 ;;; under the terms of the GNU General Public License as published by
10 ;;; the Free Software Foundation; either version 3 of the License, or (at
11 ;;; your option) any later version.
12 ;;;
13 ;;; Mes is distributed in the hope that it will be useful, but
14 ;;; WITHOUT ANY WARRANTY; without even the implied warranty of
15 ;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
16 ;;; GNU General Public License for more details.
17 ;;;
18 ;;; You should have received a copy of the GNU General Public License
19 ;;; along with Mes.  If not, see <http://www.gnu.org/licenses/>.
20
21 ;;; Commentary:
22
23 ;;; scm.mes is loaded after base, quasiquote and let.  It provides
24 ;;; basic Scheme functions bringing Mes close to basic RRS Scheme (no
25 ;;; labels, processes, fluids or throw/catch).
26
27 ;;; Code:
28
29 (mes-use-module (mes let))
30
31 (define (cadddr x) (car (cdddr x)))
32
33 (define-macro (case val . args)
34   (if (null? args) #f
35       (let ((clause (car args)))
36         (let ((pred (car clause)))
37           (let ((body (cdr clause)))
38            (if (pair? pred) `(if ,(if (null? (cdr pred))
39                                       `(eq? ,val ',(car pred))
40                                       `(member ,val ',pred))
41                                  (begin ,@body)
42                                  (case ,val ,@(cdr args)))
43                `(begin ,@body)))))))
44
45 (define-macro (when expr . body)
46   `(if ,expr
47        ((lambda () ,@body))))
48
49 (define-macro (unless expr . body)
50   `(if (not ,expr)
51        ((lambda () ,@body))))
52
53 (define-macro (do init test . body)
54   `(let loop ((,(caar init) ,(cadar init)))
55      (when (not ,@test)
56        ,@body
57        (loop ,@(cddar init)))))
58
59 (define (for-each f l . r)
60   (if (pair? l) (if (null? r) (begin (f (car l)) (for-each f (cdr l)))
61                     (if (null? (cdr r)) (begin (f (car l) (caar r)) (for-each f (cdr l) (cdar r)))))))
62
63 (define core:error error)
64
65 (define (error who . rest)
66   (display "error:" (current-error-port))
67   (display who (current-error-port))
68   (display ":" (current-error-port))
69   (display rest (current-error-port))
70   (newline (current-error-port))
71   (display "exiting...\n" (current-error-port))
72   (core:error (if (symbol? who) who 'error) (cons who rest)))
73
74 (define (syntax-error message . rest)
75   (display "syntax-error:" (current-error-port))
76   (display message (current-error-port))
77   (display ":" (current-error-port))
78   (display rest (current-error-port))
79   (newline (current-error-port))
80   (core:error 'syntax-error (cons message rest)))
81
82 \f
83 (define integer? number?)
84
85 (if (not (defined? 'peek-char))
86     (define (peek-char)
87       (integer->char (peek-byte))))
88
89 (if (not (defined? 'read-char))
90     (define (read-char)
91       (integer->char (read-byte))))
92
93 (if (not (defined? 'unread-char))
94     (define (unread-char c)
95       (integer->char (unread-byte (char->integer c)))))
96
97 (define (assq-set! alist key val)
98   (let ((entry (assq key alist)))
99     (if (not entry) (acons key val alist)
100         (let ((entry (set-cdr! entry val)))
101           alist))))
102
103 (define (assq-ref alist key)
104   (let ((entry (assq key alist)))
105     (if entry (cdr entry)
106         #f)))
107
108 (define assv assq)
109 (define assv-ref assq-ref)
110
111 (define (assoc key alist)
112   (if (null? alist) #f ;; IF
113       (if (equal? key (caar alist)) (car alist)
114           (assoc key (cdr alist)))))
115
116 (define (assoc-ref alist key)
117   (let ((entry (assoc key alist)))
118     (if entry (cdr entry)
119         #f)))
120
121 (define (assoc-set! alist key value)
122   (let ((entry (assoc key alist)))
123     (if (not entry) (acons key value alist)
124         (let ((entry (set-cdr! entry value)))
125           alist))))
126
127 (define (memq x lst)
128   (if (null? lst) #f ;; IF
129       (if (eq? x (car lst)) lst
130           (memq x (cdr lst)))))
131 (define memv memq)
132
133 (define (member x lst)
134   (if (null? lst) #f ;; IF
135       (if (equal? x (car lst)) lst
136           (member x (cdr lst)))))
137
138 \f
139 ;;; Lists
140 (define (make-list n . x)
141   (let ((fill (if (pair? x) (car x) *unspecified*)))
142     (let loop ((n n))
143       (if (= 0 n) '()
144           (cons fill (loop (- n 1)))))))
145
146 (define (list-ref lst k)
147   (let loop ((lst lst) (k k))
148     (if (= 0 k) (car lst)
149         (loop (cdr lst) (- k 1)))))
150
151 (define (list-set! lst k v)
152   (let loop ((lst lst) (k k))
153     (if (= 0 k) (set-car! lst v)
154         (loop (cdr lst) (- k 1)))))
155
156 (define (list-head x n)
157   (if (= 0 n) '()
158       (cons (car x) (list-head (cdr x) (- n 1)))))
159
160 (define (list-tail x n)
161   (if (= 0 n) x
162       (list-tail (cdr x) (- n 1))))
163
164 (define (last-pair lst)
165   (let loop ((lst lst))
166     (if (or (null? lst) (null? (cdr lst))) lst
167         (loop (cdr lst)))))
168
169 (define (iota n)
170   (if (<= n 0) '()
171       (append2 (iota (- n 1)) (list (- n 1)))))
172
173 (define (reverse lst)
174   (if (null? lst) '()
175       (append (reverse (cdr lst)) (cons (car lst) '()))))
176
177 (define (filter pred lst)
178   (let loop ((lst lst))
179     (if (null? lst) '()
180         (if (pred (car lst))
181             (cons (car lst) (loop (cdr lst)))
182             (loop (cdr lst))))))
183
184 (define (delete x lst)
185   (filter (lambda (e) (not (equal? e x))) lst))
186
187 (define (delq x lst)
188   (filter (lambda (e) (not (eq? e x))) lst))
189
190 (define (compose proc . rest)
191   (if (null? rest) proc
192       (lambda args
193         (proc (apply (apply compose rest) args)))))
194
195 \f
196 ;; Vector
197 (define (vector . rest) (list->vector rest))
198 (define (make-vector n . x)
199   (if (null? x) (core:make-vector n)
200       (list->vector (apply make-list (cons n x)))))
201
202 (define (vector-copy x)
203   (list->vector (vector->list x)))
204
205 \f
206 ;;; Strings/srfi-13
207 (define (make-string n . fill)
208   (list->string (apply make-list n fill)))
209
210 (define (string-length s)
211   (length (string->list s)))
212
213 (define (string-ref s k)
214   (list-ref (string->list s) k))
215
216 (define (string-set! s k v)
217   (list->string (list-set! (string->list s) k v)))
218
219 (define (substring s start . rest)
220   (let* ((end (and (pair? rest) (car rest)))
221          (lst (list-tail (string->list s) start)))
222     (list->string (if (not end) lst
223                       (list-head lst (- end start))))))
224
225 (define (string-prefix? prefix string)
226   (let ((length (string-length string))
227         (prefix-length (string-length prefix)))
228   (and
229    (>= length prefix-length)
230    (equal? (substring string 0 prefix-length) prefix))))
231
232 (define (string-suffix? suffix string)
233   (let ((length (string-length string))
234         (suffix-length (string-length suffix)))
235     (and
236      (>= length suffix-length)
237      (equal? (substring string (- length suffix-length)) suffix))))
238
239 (define (string->number s . rest)
240   (let* ((radix (if (null? rest) 10 (car rest)))
241          (lst (string->list s))
242          (sign (if (char=? (car lst) #\-) -1 1))
243          (lst (if (= sign -1) (cdr lst) lst)))
244     (let loop ((lst lst) (n 0))
245       (if (null? lst) (* sign n)
246           (let ((i (char->integer (car lst))))
247             (loop (cdr lst) (+ (* n radix) (- i (if (<= i (char->integer #\9)) (char->integer #\0)
248                                                     (- (char->integer #\a) 10))))))))))
249
250 (define (number->string n . rest)
251   (let* ((radix (if (null? rest) 10 (car rest)))
252          (sign (if (< n 0) '(#\-) '())))
253     (let loop ((n (abs n)) (lst '()))
254       (let* ((i (remainder n radix))
255              (lst (cons (integer->char (+ i (if (< i 10) (char->integer #\0)
256                                                 (- (char->integer #\a) 10)))) lst))
257              (n (quotient n radix)))
258         (if (= 0 n) (list->string (append sign lst))
259             (loop n lst))))))
260
261 \f
262 ;;; Symbols
263 (define (symbol-prefix? prefix symbol)
264   (string-prefix? (symbol->string prefix) (symbol->string symbol)))
265
266 (define (symbol-append . rest)
267   (string->symbol (apply string-append (map symbol->string rest))))
268
269 (define gensym
270   (let ((counter 0))
271     (lambda (. rest)
272       (let ((value (number->string counter)))
273         (set! counter (+ counter 1))
274         (string->symbol (string-append "g" value))))))
275
276 \f
277 ;;; Keywords
278 (define (keyword->symbol s)
279   (list->symbol (keyword->list s)))
280
281 \f
282 ;;; Characters
283 (define (char=? x y)
284   (and (char? x) (char? y)
285        (eq? x y)))
286
287 (define (char<? a b) (< (char->integer a) (char->integer b)))
288 (define (char>? a b) (> (char->integer a) (char->integer b)))
289 (define (char<=? a b) (<= (char->integer a) (char->integer b)))
290 (define (char>=? a b) (>= (char->integer a) (char->integer b)))
291
292 (define (char-alphabetic? x)
293   (and (char? x)
294        (let ((i (char->integer x)))
295         (or (and (>= i (char->integer #\A)) (<= i (char->integer #\Z)))
296             (and (>= i (char->integer #\a)) (<= i (char->integer #\z)))))))
297
298 (define (char-numeric? x)
299   (and (char? x)
300        (let ((i (char->integer x)))
301          (and (>= i (char->integer #\0)) (<= i (char->integer #\9))))))
302
303 \f
304 ;;; Math
305 (define quotient /)
306
307 (define (<= . rest)
308   (or (apply < rest)
309       (apply = rest)))
310
311 (define (>= . rest)
312   (or (apply > rest)
313       (apply = rest)))
314
315 (define (remainder x y)
316   (- x (* (quotient x y) y)))
317
318 (define (even? x)
319   (= 0 (remainder x 2)))
320
321 (define (odd? x)
322   (= 1 (remainder x 2)))
323
324 (define (negative? x)
325   (< x 0))
326
327 (define (positive? x)
328   (> x 0))
329
330 (define (zero? x)
331   (= x 0))
332
333 (define (1+ x)
334   (+ x 1))
335
336 (define (1- x)
337   (- x 1))
338
339 (define (abs x)
340   (if (>= x 0) x (- x)))
341
342 (define (expt x y)
343   (let loop ((s 1) (count y))
344     (if (= 0 count) s
345         (loop (* s x) (- count 1)))))
346
347 (define (max x . rest)
348   (if (null? rest) x
349       (let ((y (car rest)))
350         (let ((z (if (> x y) x y)))
351           (apply max (cons z (cdr rest)))))))
352
353 (define (min x . rest)
354   (if (null? rest) x
355       (let ((y (car rest)))
356         (let ((z (if (< x y) x y)))
357           (apply min (cons z (cdr rest)))))))
358
359 (define (negate proc)
360   (lambda args
361     (not (apply proc args))))