2e488be620a9ef5bd82aa4310c12019cda467615
[mes.git] / module / mes / scm.mes
1 ;;; -*-scheme-*-
2
3 ;;; Mes --- Maxwell Equations of Software
4 ;;; Copyright © 2016 Jan Nieuwenhuizen <janneke@gnu.org>
5 ;;;
6 ;;; scm.mes: This file is part of Mes.
7 ;;;
8 ;;; Mes is free software; you can redistribute it and/or modify it
9 ;;; under the terms of the GNU General Public License as published by
10 ;;; the Free Software Foundation; either version 3 of the License, or (at
11 ;;; your option) any later version.
12 ;;;
13 ;;; Mes is distributed in the hope that it will be useful, but
14 ;;; WITHOUT ANY WARRANTY; without even the implied warranty of
15 ;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
16 ;;; GNU General Public License for more details.
17 ;;;
18 ;;; You should have received a copy of the GNU General Public License
19 ;;; along with Mes.  If not, see <http://www.gnu.org/licenses/>.
20
21 ;;; Commentary:
22
23 ;;; scm.mes is loaded after base, quasiquote and let.  It provides
24 ;;; basic Scheme functions bringing Mes close to basic RRS Scheme (no
25 ;;; labels, processes, fluids or throw/catch).
26
27 ;;; Code:
28
29 (define (cadddr x) (car (cdddr x)))
30
31 (define (list . rest) rest)
32
33 (define-macro (case val . args)
34   (if (null? args) #f
35       (let ((clause (car args)))
36         (let ((pred (car clause)))
37           (let ((body (cdr clause)))
38            (if (pair? pred) `(if ,(if (null? (cdr pred))
39                                       `(eq? ,val ',(car pred))
40                                       `(member ,val ',pred))
41                                  (begin ,@body)
42                                  (case ,val ,@(cdr args)))
43                `(begin ,@body)))))))
44
45 (define-macro (when expr . body)
46   `(if ,expr
47        ((lambda () ,@body))))
48
49 (define-macro (do init test . body)
50   `(let loop ((,(caar init) ,(cadar init)))
51      (when (not ,@test)
52        ,@body
53        (loop ,@(cddar init)))))
54
55 (define integer? number?)
56
57 (define (make-list n . x)
58   (let ((fill (if (pair? x) (car x) *unspecified*)))
59     (let loop ((n n))
60       (if (= 0 n) '()
61           (cons fill (loop (- n 1)))))))
62
63 (define (string->list s)
64   (let ((n (string-length s)))
65     (let loop ((i 0))
66       (if (= i n) '()
67           (cons (string-ref s i) (loop (+ i 1)))))))
68
69 (define (vector . rest) (list->vector rest))
70 (define c:make-vector make-vector)
71 (define (make-vector n . x)
72   (if (null? x) (c:make-vector n)
73       (list->vector (apply make-list (cons n x)))))
74
75 (define (acons key value alist)
76   (cons (cons key value) alist))
77
78 (define (assq-set! alist key val)
79   (let ((entry (assq key alist)))
80     (cond (entry (set-cdr! entry val)
81                  alist)
82           (#t (cons (cons key val) alist)))))
83
84 (define (assq-ref alist key)
85   (let ((entry (assq key alist)))
86     (if entry (cdr entry)
87         #f)))
88
89 (define assv assq)
90 (define assv-ref assq-ref)
91
92 (define (assoc key alist)
93   (if (null? alist) #f ;; IF
94       (if (equal? key (caar alist)) (car alist)
95           (assoc key (cdr alist)))))
96
97 (define (assoc-ref alist key)
98   (let ((entry (assoc key alist)))
99     (if entry (cdr entry)
100         #f)))
101
102 (define (memq x lst)
103   (if (null? lst) #f ;; IF
104       (if (eq? x (car lst)) lst
105           (memq x (cdr lst)))))
106 (define memv memq)
107
108 (define (member x lst)
109   (if (null? lst) #f ;; IF
110       (if (equal? x (car lst)) lst
111           (member x (cdr lst)))))
112
113 (define (for-each f l . r)
114   (if (null? l) '() ;; IF
115       (if (null? r) (begin (f (car l)) (for-each f (cdr l)))
116           (if (null? (cdr r))
117               (for-each f (cdr l) (cdar r))))))
118
119 (define (<= . rest)
120   (or (apply < rest)
121       (apply = rest)))
122
123 (define (>= . rest)
124   (or (apply > rest)
125       (apply = rest)))
126
127 ;; (define (>= . rest)
128 ;;   (if (apply > rest) #t
129 ;;       (if (apply = rest) #t
130 ;;           #f)))
131
132 (define (remainder x y)
133   (- x (* (quotient x y) y)))
134
135 (define (expt x y)
136   (let loop ((s 1) (count y))
137     (if (= 0 count) s
138         (loop (* s x) (- count 1)))))
139
140 (define (max x . rest)
141   (if (null? rest) x
142       (let ((y (car rest)))
143         (let ((z (if (> x y) x y)))
144           (apply max (cons z (cdr rest)))))))
145
146 (define (min x . rest)
147   (if (null? rest) x
148       (let ((y (car rest)))
149         (let ((z (if (< x y) x y)))
150           (apply min (cons z (cdr rest)))))))
151
152 (define gensym
153   (let ((counter 0))
154     (lambda (. rest)
155       (let ((value (number->string counter)))
156         (set! counter (+ counter 1))
157         (string->symbol (string-append "g" value))))))
158
159 (define else #t)
160
161 (define (error who . rest)
162   (display "error:" (current-error-port))
163   (display who (current-error-port))
164   (display ":" (current-error-port))
165   (display rest (current-error-port))
166   (newline (current-error-port))
167   (display "exiting...\n" (current-error-port))
168   (exit 1))
169
170 (define (syntax-error message . rest)
171   (display "syntax-error:" (current-error-port))
172   (display message (current-error-port))
173   (display ":" (current-error-port))
174   (display rest (current-error-port))
175   (newline (current-error-port)))
176
177 (define (list-ref lst k)
178   (let loop ((lst lst) (k k))
179     (if (= 0 k) (car lst)
180         (loop (cdr lst) (- k 1)))))
181
182 ;; srfi-1
183 (define (last-pair lst)
184   (let loop ((lst lst))
185     (if (or (null? lst) (null? (cdr lst))) lst
186         (loop (cdr lst)))))
187
188 (define (reverse lst)
189   (if (null? lst) '()
190       (append (reverse (cdr lst)) (cons (car lst) '()))))
191
192 (define (eof-object? x)
193   (or (and (number? x) (= x -1))
194       (and (char? x) (eof-object? (char->integer x)))))
195
196 (define (char=? x y)
197   (and (char? x) (char? y)
198        (eq? x y)))
199
200 (define (char-alphabetic? x)
201   (and (char? x)
202        (let ((i (char->integer x)))
203         (or (and (>= i (char->integer #\A)) (<= i (char->integer #\Z)))
204             (and (>= i (char->integer #\a)) (<= i (char->integer #\z)))))))
205
206 (define (char-numeric? x)
207   (and (char? x)
208        (let ((i (char->integer x)))
209          (and (>= i (char->integer #\0)) (<= i (char->integer #\9))))))