020c39492a4f6c60ec714d1227120eb4e795c6a3
[mes.git] / module / mes / scm.mes
1 ;;; -*-scheme-*-
2
3 ;;; Mes --- Maxwell Equations of Software
4 ;;; Copyright © 2016,2017 Jan Nieuwenhuizen <janneke@gnu.org>
5 ;;;
6 ;;; This file is part of Mes.
7 ;;;
8 ;;; Mes is free software; you can redistribute it and/or modify it
9 ;;; under the terms of the GNU General Public License as published by
10 ;;; the Free Software Foundation; either version 3 of the License, or (at
11 ;;; your option) any later version.
12 ;;;
13 ;;; Mes is distributed in the hope that it will be useful, but
14 ;;; WITHOUT ANY WARRANTY; without even the implied warranty of
15 ;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
16 ;;; GNU General Public License for more details.
17 ;;;
18 ;;; You should have received a copy of the GNU General Public License
19 ;;; along with Mes.  If not, see <http://www.gnu.org/licenses/>.
20
21 ;;; Commentary:
22
23 ;;; scm.mes is loaded after base, quasiquote and let.  It provides
24 ;;; basic Scheme functions bringing Mes close to basic RRS Scheme (no
25 ;;; labels, processes, fluids or throw/catch).
26
27 ;;; Code:
28
29 (mes-use-module (mes let))
30
31 (define (cadddr x) (car (cdddr x)))
32
33 (define-macro (case val . args)
34   (if (null? args) #f
35       (let ((clause (car args)))
36         (let ((pred (car clause)))
37           (let ((body (cdr clause)))
38            (if (pair? pred) `(if ,(if (null? (cdr pred))
39                                       `(eq? ,val ',(car pred))
40                                       `(member ,val ',pred))
41                                  (begin ,@body)
42                                  (case ,val ,@(cdr args)))
43                `(begin ,@body)))))))
44
45 (define-macro (when expr . body)
46   `(if ,expr
47        ((lambda () ,@body))))
48
49 (define-macro (unless expr . body)
50   `(if (not ,expr)
51        ((lambda () ,@body))))
52
53 (define-macro (do init test . body)
54   `(let loop ((,(caar init) ,(cadar init)))
55      (when (not ,@test)
56        ,@body
57        (loop ,@(cddar init)))))
58
59 (define (for-each f l . r)
60   (if (pair? l) (if (null? r) (begin (f (car l)) (for-each f (cdr l)))
61                     (if (null? (cdr r)) (begin (f (car l) (caar r)) (for-each f (cdr l) (cdar r)))))))
62
63 (define core:error error)
64
65 (define (error who . rest)
66   (display "error:" (current-error-port))
67   (display who (current-error-port))
68   (display ":" (current-error-port))
69   (display rest (current-error-port))
70   (newline (current-error-port))
71   (display "exiting...\n" (current-error-port))
72   (core:error (if (symbol? who) who 'error) (cons who rest)))
73
74 (define (syntax-error message . rest)
75   (display "syntax-error:" (current-error-port))
76   (display message (current-error-port))
77   (display ":" (current-error-port))
78   (display rest (current-error-port))
79   (newline (current-error-port))
80   (core:error 'syntax-error (cons message rest)))
81
82 \f
83 (define integer? number?)
84
85 (define (eof-object? x)
86   (or (and (number? x) (= x -1))
87       (and (char? x) (eof-object? (char->integer x)))))
88
89 (if (not (defined? 'peek-char))
90     (define (peek-char)
91       (integer->char (peek-byte))))
92
93 (if (not (defined? 'read-char))
94     (define (read-char)
95       (integer->char (read-byte))))
96
97 (if (not (defined? 'unread-char))
98     (define (unread-char c)
99       (unread-byte (char->integer c))))
100
101 (define (assq-set! alist key val)
102   (let ((entry (assq key alist)))
103     (if (not entry) (acons key val alist)
104         (let ((entry (set-cdr! entry val)))
105           alist))))
106
107 (define (assq-ref alist key)
108   (let ((entry (assq key alist)))
109     (if entry (cdr entry)
110         #f)))
111
112 (define assv assq)
113 (define assv-ref assq-ref)
114
115 (define (assoc key alist)
116   (if (null? alist) #f ;; IF
117       (if (equal? key (caar alist)) (car alist)
118           (assoc key (cdr alist)))))
119
120 (define (assoc-ref alist key)
121   (let ((entry (assoc key alist)))
122     (if entry (cdr entry)
123         #f)))
124
125 (define (assoc-set! alist key value)
126   (let ((entry (assoc key alist)))
127     (if (not entry) (acons key value alist)
128         (let ((entry (set-cdr! entry value)))
129           alist))))
130
131 (define (memq x lst)
132   (if (null? lst) #f ;; IF
133       (if (eq? x (car lst)) lst
134           (memq x (cdr lst)))))
135 (define memv memq)
136
137 (define (member x lst)
138   (if (null? lst) #f ;; IF
139       (if (equal? x (car lst)) lst
140           (member x (cdr lst)))))
141
142 \f
143 ;;; Lists
144 (define (make-list n . x)
145   (let ((fill (if (pair? x) (car x) *unspecified*)))
146     (let loop ((n n))
147       (if (= 0 n) '()
148           (cons fill (loop (- n 1)))))))
149
150 (define (list-ref lst k)
151   (let loop ((lst lst) (k k))
152     (if (= 0 k) (car lst)
153         (loop (cdr lst) (- k 1)))))
154
155 (define (list-set! lst k v)
156   (let loop ((lst lst) (k k))
157     (if (= 0 k) (set-car! lst v)
158         (loop (cdr lst) (- k 1)))))
159
160 (define (list-head x n)
161   (if (= 0 n) '()
162       (cons (car x) (list-head (cdr x) (- n 1)))))
163
164 (define (list-tail x n)
165   (if (= 0 n) x
166       (list-tail (cdr x) (- n 1))))
167
168 (define (last-pair lst)
169   (let loop ((lst lst))
170     (if (or (null? lst) (null? (cdr lst))) lst
171         (loop (cdr lst)))))
172
173 (define (iota n)
174   (if (<= n 0) '()
175       (append2 (iota (- n 1)) (list (- n 1)))))
176
177 (define (reverse lst)
178   (if (null? lst) '()
179       (append (reverse (cdr lst)) (cons (car lst) '()))))
180
181 (define (filter pred lst)
182   (let loop ((lst lst))
183     (if (null? lst) '()
184         (if (pred (car lst))
185             (cons (car lst) (loop (cdr lst)))
186             (loop (cdr lst))))))
187
188 (define (delete x lst)
189   (filter (lambda (e) (not (equal? e x))) lst))
190
191 (define (delq x lst)
192   (filter (lambda (e) (not (eq? e x))) lst))
193
194 (define (compose proc . rest)
195   (if (null? rest) proc
196       (lambda args
197         (proc (apply (apply compose rest) args)))))
198
199 \f
200 ;; Vector
201 (define (vector . rest) (list->vector rest))
202 (define c:make-vector make-vector)
203 (define (make-vector n . x)
204   (if (null? x) (c:make-vector n)
205       (list->vector (apply make-list (cons n x)))))
206
207 (define (vector-copy x)
208   (list->vector (vector->list x)))
209
210 \f
211 ;;; Strings/srfi-13
212 (define (string-length s)
213   (length (string->list s)))
214
215 (define (string-ref s k)
216   (list-ref (string->list s) k))
217
218 (define (string-set! s k v)
219   (list->string (list-set! (string->list s) k v)))
220
221 (define (substring s start . rest)
222   (let* ((end (and (pair? rest) (car rest)))
223          (lst (list-tail (string->list s) start)))
224     (list->string (if (not end) lst
225                       (list-head lst (- end start))))))
226
227 (define (string-prefix? prefix string)
228   (let ((length (string-length string))
229         (prefix-length (string-length prefix)))
230   (and
231    (>= length prefix-length)
232    (equal? (substring string 0 prefix-length) prefix))))
233
234 (define (string-suffix? suffix string)
235   (let ((length (string-length string))
236         (suffix-length (string-length suffix)))
237     (and
238      (>= length suffix-length)
239      (equal? (substring string (- length suffix-length)) suffix))))
240
241 (define (string->number s . rest)
242   (let* ((radix (if (null? rest) 10 (car rest)))
243          (lst (string->list s))
244          (sign (if (char=? (car lst) #\-) -1 1))
245          (lst (if (= sign -1) (cdr lst) lst)))
246     (let loop ((lst lst) (n 0))
247       (if (null? lst) (* sign n)
248           (let ((i (char->integer (car lst))))
249             (loop (cdr lst) (+ (* n radix) (- i (if (<= i (char->integer #\9)) (char->integer #\0)
250                                                     (- (char->integer #\a) 10))))))))))
251
252 (define (number->string n . rest)
253   (let* ((radix (if (null? rest) 10 (car rest)))
254          (sign (if (< n 0) '(#\-) '())))
255     (let loop ((n (abs n)) (lst '()))
256       (let* ((i (remainder n radix))
257              (lst (cons (integer->char (+ i (if (< i 10) (char->integer #\0)
258                                                 (- (char->integer #\a) 10)))) lst))
259              (n (quotient n radix)))
260         (if (= 0 n) (list->string (append sign lst))
261             (loop n lst))))))
262
263 \f
264 ;;; Symbols
265 (define (symbol-prefix? prefix symbol)
266   (string-prefix? (symbol->string prefix) (symbol->string symbol)))
267
268 (define (symbol-append . rest)
269   (string->symbol (apply string-append (map symbol->string rest))))
270
271 (define gensym
272   (let ((counter 0))
273     (lambda (. rest)
274       (let ((value (number->string counter)))
275         (set! counter (+ counter 1))
276         (string->symbol (string-append "g" value))))))
277
278 \f
279 ;;; Keywords
280 (define (keyword->symbol s)
281   (list->symbol (keyword->list s)))
282
283 \f
284 ;;; Characters
285 (define (char=? x y)
286   (and (char? x) (char? y)
287        (eq? x y)))
288
289 (define (char<? a b) (< (char->integer a) (char->integer b)))
290 (define (char>? a b) (> (char->integer a) (char->integer b)))
291 (define (char<=? a b) (<= (char->integer a) (char->integer b)))
292 (define (char>=? a b) (>= (char->integer a) (char->integer b)))
293
294 (define (char-alphabetic? x)
295   (and (char? x)
296        (let ((i (char->integer x)))
297         (or (and (>= i (char->integer #\A)) (<= i (char->integer #\Z)))
298             (and (>= i (char->integer #\a)) (<= i (char->integer #\z)))))))
299
300 (define (char-numeric? x)
301   (and (char? x)
302        (let ((i (char->integer x)))
303          (and (>= i (char->integer #\0)) (<= i (char->integer #\9))))))
304
305 \f
306 ;;; Math
307 (define quotient /)
308
309 (define (<= . rest)
310   (or (apply < rest)
311       (apply = rest)))
312
313 (define (>= . rest)
314   (or (apply > rest)
315       (apply = rest)))
316
317 (define (remainder x y)
318   (- x (* (quotient x y) y)))
319
320 (define (even? x)
321   (= 0 (remainder x 2)))
322
323 (define (odd? x)
324   (= 1 (remainder x 2)))
325
326 (define (negative? x)
327   (< x 0))
328
329 (define (positive? x)
330   (> x 0))
331
332 (define (zero? x)
333   (= x 0))
334
335 (define (1+ x)
336   (+ x 1))
337
338 (define (1- x)
339   (- x 1))
340
341 (define (abs x)
342   (if (>= x 0) x (- x)))
343
344 (define (expt x y)
345   (let loop ((s 1) (count y))
346     (if (= 0 count) s
347         (loop (* s x) (- count 1)))))
348
349 (define (max x . rest)
350   (if (null? rest) x
351       (let ((y (car rest)))
352         (let ((z (if (> x y) x y)))
353           (apply max (cons z (cdr rest)))))))
354
355 (define (min x . rest)
356   (if (null? rest) x
357       (let ((y (car rest)))
358         (let ((z (if (< x y) x y)))
359           (apply min (cons z (cdr rest)))))))
360
361 (define (negate proc)
362   (lambda args
363     (not (apply proc args))))