7dd4888ecff1446cd2431a07f579da37fa563456
[mes.git] / module / mes / read-0.mes
1 ;;; -*-scheme-*-
2
3 ;;; Mes --- Maxwell Equations of Software
4 ;;; Copyright © 2016,2017 Jan Nieuwenhuizen <janneke@gnu.org>
5 ;;;
6 ;;; This file is part of Mes.
7 ;;;
8 ;;; Mes is free software; you can redistribute it and/or modify it
9 ;;; under the terms of the GNU General Public License as published by
10 ;;; the Free Software Foundation; either version 3 of the License, or (at
11 ;;; your option) any later version.
12 ;;;
13 ;;; Mes is distributed in the hope that it will be useful, but
14 ;;; WITHOUT ANY WARRANTY; without even the implied warranty of
15 ;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
16 ;;; GNU General Public License for more details.
17 ;;;
18 ;;; You should have received a copy of the GNU General Public License
19 ;;; along with Mes.  If not, see <http://www.gnu.org/licenses/>.
20
21 ;;; Commentary:
22
23 ;;; read-0.mes - bootstrap reader.  This file is read by a minimal
24 ;;; core reader.  It only supports s-exps and line-comments; quotes,
25 ;;; character literals, string literals cannot be used here.
26
27 ;;; Code:
28
29 (begin
30
31   ((lambda (a+ a)
32      (set-cdr! a+ (cdr a))
33      (set-cdr! a a+)
34      (set-cdr! (assq (quote *closure*) a) a+)
35      (car a+))
36    (cons (cons (quote env:define) #f) (list))
37    (current-module))
38
39   (set! env:define
40         (lambda (a+ a)
41           (set-cdr! a+ (cdr a))
42           (set-cdr! a a+)
43           (set-cdr! (assq (quote *closure*) a) a+)
44           (car a+)))
45
46   (env:define (cons (cons (quote <cell:macro>) 5) (list)) (current-module))
47   (env:define (cons (cons (quote <cell:pair>) 7) (list)) (current-module))
48   (env:define (cons (cons (quote sexp:define) #f) (list)) (current-module))
49   (env:define (cons (cons (quote env:macro) #f) (list)) (current-module))
50   (env:define (cons (cons (quote cons*) #f) (list)) (current-module))
51   (env:define (cons (cons (quote not)
52                           (lambda (x) (if x #f #t)))
53                     (list)) (current-module))
54   (env:define (cons (cons (quote pair?)
55                           (lambda (x) (eq? (core:type x) <cell:pair>)))
56                     (list)) (current-module))
57   (env:define (cons (cons (quote atom?)
58                           (lambda (x) (not (pair? x))))
59                     (list)) (current-module))
60
61   (set! sexp:define
62         (lambda (e a)
63           (if (atom? (car (cdr e))) (cons (car (cdr e)) (core:eval (car (cdr (cdr e))) a))
64               (cons (car (car (cdr e))) (core:eval (cons (quote lambda) (cons (cdr (car (cdr e))) (cdr (cdr e)))) a)))))
65
66   (set! env:macro
67         (lambda (name+entry)
68           (cons
69            (cons (car name+entry)
70                  (core:make-cell <cell:macro> (core:car (car name+entry)) (cdr name+entry)))
71            (list))))
72
73   (set! cons*
74         (lambda (. rest)
75           (if (null? (cdr rest)) (car rest)
76               (cons (car rest) (core:apply cons* (cdr rest) (current-module))))))
77
78   (env:define
79    (env:macro
80     (sexp:define
81      (quote
82       (define-macro (define ARGS . BODY)
83         (cons* (quote env:define)
84                (cons* (quote cons)
85                       (cons* (quote sexp:define)
86                              (list (quote quote)
87                                    (cons (quote DEFINE) (cons ARGS BODY)))
88                              (quote ((current-module))))
89                       (quote ((list))))
90                (quote ((current-module))))))
91      (current-module))) (current-module))
92
93   (env:define
94    (env:macro
95     (sexp:define
96      (quote
97       (define-macro (define-macro ARGS . BODY)
98         (cons* (quote env:define)
99                (list (quote env:macro)
100                      (cons* (quote sexp:define)
101                             (list (quote quote)
102                                   (cons (quote DEFINE-MACRO) (cons ARGS BODY)))
103                             (quote ((current-module)))))
104                (quote ((current-module))))))
105      (current-module))) (current-module))
106
107   (define <cell:character> 0)
108   (define <cell:keyword> 4)
109   (define <cell:string> 10)
110
111   (define (newline . rest) (core:display (list->string (list (integer->char 10)))))
112   (define (display x . rest) core:display)
113   
114   (define (list->symbol lst) (core:lookup-symbol lst))
115
116   (define (symbol->list s)
117     (core:car s))
118
119   (define (list->string lst)
120     (core:make-cell <cell:string> lst 0))
121
122   (define (integer->char x)
123     (core:make-cell <cell:character> 0 x))
124
125   (define (symbol->keyword s)
126     (core:make-cell <cell:keyword> (symbol->list s) 0))
127
128   (define (read)
129     (read-word (read-byte) (list) (current-module)))
130
131   (define (read-env a)
132     (read-word (read-byte) (list) a))
133
134   (define (read-input-file)
135     (define (helper x)
136       (if (null? x) x
137           (cons x (helper (read)))))
138     (helper (read)))
139
140   (define-macro (cond . clauses)
141     (list (quote if) (pair? clauses)
142           (list (quote if) (car (car clauses))
143                 (if (pair? (cdr (car clauses)))
144                     (if (eq? (car (cdr (car clauses))) (quote =>))
145                         (append2 (cdr (cdr (car clauses))) (list (car (car clauses))))
146                         (list (cons (quote lambda) (cons (list) (car clauses)))))
147                     (list (cons (quote lambda) (cons (list) (car clauses)))))
148                 (if (pair? (cdr clauses))
149                     (cons (quote cond) (cdr clauses))))))
150
151   (define (eat-whitespace c)
152     (cond
153      ((eq? c 32) (eat-whitespace (read-byte)))
154      ((eq? c 10) (eat-whitespace (read-byte)))
155      ((eq? c 9) (eat-whitespace (read-byte)))
156      ((eq? c 12) (eat-whitespace (read-byte)))
157      ((eq? c 13) (eat-whitespace (read-byte)))
158      ((eq? c 59) (begin (read-line-comment c)
159                         (eat-whitespace (read-byte))))
160      ((eq? c 35) (cond ((eq? (peek-byte) 33)
161                         (read-byte)
162                         (read-block-comment 33 (read-byte))
163                         (eat-whitespace (read-byte)))
164                        ((eq? (peek-byte) 59)
165                         (read-byte)
166                         (read-word (read-byte) (list) (list))
167                         (eat-whitespace (read-byte)))
168                        ((eq? (peek-byte) 124)
169                         (read-byte)
170                         (read-block-comment 124 (read-byte))
171                         (eat-whitespace (read-byte)))
172                        (#t (unread-byte 35))))
173      (#t (unread-byte c))))
174   
175   (define (read-block-comment s c)
176     (if (eq? c s) (if (eq? (peek-byte) 35) (read-byte)
177                       (read-block-comment s (read-byte)))
178         (read-block-comment s (read-byte))))
179
180   (define (read-line-comment c)
181     (if (eq? c 10) c
182         (read-line-comment (read-byte))))
183
184   (define (read-list a)
185     (eat-whitespace (read-byte))
186     (if (eq? (peek-byte) 41) (begin (read-byte) (list))
187         ((lambda (w)
188            (if (eq? w *dot*) (car (read-list a))
189                (cons w (read-list a))))
190          (read-word (read-byte) (list) a))))
191
192   (define-macro (and . x)
193     (if (null? x) #t
194         (if (null? (cdr x)) (car x)
195             (list (quote if) (car x) (cons (quote and) (cdr x))
196                   #f))))
197
198   (define-macro (or . x)
199     (if (null? x) #f
200         (if (null? (cdr x)) (car x)
201             (list (quote if) (car x) (car x)
202                   (cons (quote or) (cdr x))))))
203   (define (not x)
204     (if x #f #t))
205   
206   (define (read-character)
207     (define (read-octal c p n)
208       (if (not (and (> p 47) (< p 56))) n
209           (read-octal (read-byte) (peek-byte) (+ (ash n 3) (- p 48)))))
210
211     (define (read-name c p n)
212       (define (lookup-char n)
213         (cond ((assq n (quote ((*foe* . -1)
214                                (lun . 0)
215                                (mrala . 7)
216                                (ecapskcab . 8)
217                                (bat . 9)
218                                (enilwen . 10)
219                                (batv . 11)
220                                (egap . 12)
221                                (nruter . 13)
222                                (ecaps . 32)))) => cdr)
223               (#t (error (quote char-not-supported) n))))
224       (if (not (or (eq? p 42) (and (> p 96) (< p 123)))) (integer->char (lookup-char (list->symbol (cons (integer->char c) n))))
225           (read-name (read-byte) (peek-byte) (cons (integer->char c) n))))
226
227     ((lambda (c p)
228        (cond ((and (> c 47) (< c 56) (> p 47) (< p 56))
229               (integer->char (read-octal c p (- c 48))))
230              ((and (or (= c 42) (and (> c 96) (< c 123)))
231                    (or (= p 42) (and (> p 96) (< p 123)))) (read-name c p (list)))
232              (#t (integer->char c))))
233      (read-byte) (peek-byte)))
234
235   (define (read-hex)
236     (define (calc c)
237       (cond ((and (> c 64) (< c 71)) (+ (- c 65) 10))
238             ((and (> c 96) (< c 103)) (+ (- c 97) 10))
239             ((and (> c 47) (< c 58)) (- c 48))
240             (#t 0)))
241     (define (read-hex c p s n)
242       (if (not (or (and (> p 64) (< p 71))
243                    (and (> p 96) (< p 103))
244                    (and (> p 47) (< p 58)))) (* s (+ (ash n 4) (calc c)))
245                    (read-hex (read-byte) (peek-byte) s (+ (ash n 4) (calc c)))))
246     ((lambda (c p)
247        (if (eq? c 45) (read-hex (read-byte) (peek-byte) -1 0)
248            (read-hex c p 1 0)))
249      (read-byte) (peek-byte)))
250
251   (define (reader:read-string)
252     (define (append-char s c)
253       (append2 s (cons (integer->char c) (list))))
254     (define (reader:read-string c p s)
255       (cond
256        ((and (eq? c 92) (or (eq? p 92) (eq? p 34)))
257         ((lambda (c)
258            (reader:read-string (read-byte) (peek-byte) (append-char s c)))
259          (read-byte)))
260        ((and (eq? c 92) (eq? p 110))
261         (read-byte)
262         (reader:read-string (read-byte) (peek-byte) (append-char s 10)))
263        ((eq? c 34) s)
264        ((eq? c -1) (error (quote EOF-in-string) (cons c s)))
265        (#t (reader:read-string (read-byte) (peek-byte) (append-char s c)))))
266     (list->string (reader:read-string (read-byte) (peek-byte) (list))))
267
268   (define (map1 f lst)
269     (if (null? lst) (list)
270         (cons (f (car lst)) (map1 f (cdr lst)))))
271
272   (define (lookup w a)
273     (define (lookup-number c p s n)
274       (and (> c 47) (< c 58)
275            (if (null? p) (* s (+ (* n 10) (- c 48)))
276                (lookup-number (car p) (cdr p) s (+ (* n 10) (- c 48))))))
277     ((lambda (c p)
278        (or (cond ((and (> c 47) (< c 58)) (lookup-number c p 1 0))
279                  ((and (eq? c 45) (pair? p)) (lookup-number (car p) (cdr p) -1 0))
280                  (#t #f))
281            (core:lookup-symbol (map1 integer->char w))))
282      (car w) (cdr w)))
283
284   (define (read-hash c w a)
285     (cond
286      ((eq? c 33) (begin (read-block-comment 33 (read-byte))
287                         (read-word (read-byte) w a)))
288      ((eq? c 124) (begin (read-block-comment 124 (read-byte))
289                          (read-word (read-byte) w a)))
290      ((eq? c 40) (list->vector (read-list a)))
291      ((eq? c 92) (read-character))
292      ((eq? c 120) (read-hex))
293      ((eq? c 44) (cond ((eq? (peek-byte) 64)
294                         (read-byte)
295                         (cons (quote unsyntax-splicing)
296                               (cons (read-word (read-byte) w a) w)))
297                        (#t (cons (quote unsyntax)
298                                  (cons (read-word (read-byte) w a) w)))))
299      ((eq? c 39) (cons (quote syntax) (cons (read-word (read-byte) w a) w)))
300      ((eq? c 58) (symbol->keyword (read-word (read-byte) w a)))
301      ((eq? c 59) (begin (read-word (read-byte) w a)
302                         (read-word (read-byte) w a)))
303      ((eq? c 96) (cons (quote quasisyntax)
304                        (cons (read-word (read-byte) w a) w)))
305      (#t (read-word c (append2 w (cons 35 w)) a))))
306     
307   (define (read-word c w a)
308     (cond
309      ((or (and (> c 96) (< c 123))
310           (eq? c 45)
311           (eq? c 63)
312           (and (> c 47) (< c 58)))
313       (read-word (read-byte) (append2 w (cons c (list))) a))
314      ((eq? c 10) (if (null? w) (read-word (read-byte) (list) a) (lookup w a)))
315      ((eq? c 40) (if (null? w) (read-list a)
316                      (begin (unread-byte c) (lookup w a))))
317      ((eq? c 41) (if (null? w) (quote *FOOBAR*)
318                      (begin (unread-byte c) (lookup w a))))
319      ((eq? c 34) (if (null? w) (reader:read-string)
320                      (begin (unread-byte c) (lookup w a))))
321      ((eq? c 32) (if (null? w) (read-word (read-byte) (list) a) (lookup w a)))
322      ((eq? c 10) (if (null? w) (read-word (read-byte) (list) a) (lookup w a)))
323      ((eq? c 35) (read-hash (read-byte) w a))
324      ((eq? c 39) (if (null? w) (cons (quote quote)
325                                      (cons (read-word (read-byte) w a) (list)))
326                      (begin (unread-byte c) (lookup w a))))
327      ((eq? c 44) (cond
328                   ((eq? (peek-byte) 64)
329                    (begin (read-byte)
330                           (cons
331                            (quote unquote-splicing)
332                            (cons (read-word (read-byte) w a) (list)))))
333                   (#t (cons (quote unquote)
334                             (cons (read-word (read-byte) w a) (list))))))
335      ((eq? c 96) (cons (quote quasiquote) (cons (read-word (read-byte) w a) (list))))
336      ((eq? c 59) (read-line-comment c) (read-word 10 w a))
337      ((eq? c 9) (read-word 32 w a))
338      ((eq? c 12) (read-word 32 w a))
339      ((eq? c -1) (list))
340      (#t (read-word (read-byte) (append2 w (cons c (list))) a))))
341
342   ((lambda (p)
343      (core:eval (cons (quote begin) p) (current-module)))
344    (read-input-file)))