25c6ef992d529cd35ffd0a96d99f71fcbf7306f7
[mes.git] / module / mes / read-0.mes
1 ;;; -*-scheme-*-
2
3 ;;; Mes --- Maxwell Equations of Software
4 ;;; Copyright © 2016 Jan Nieuwenhuizen <janneke@gnu.org>
5 ;;;
6 ;;; This file is part of Mes.
7 ;;;
8 ;;; Mes is free software; you can redistribute it and/or modify it
9 ;;; under the terms of the GNU General Public License as published by
10 ;;; the Free Software Foundation; either version 3 of the License, or (at
11 ;;; your option) any later version.
12 ;;;
13 ;;; Mes is distributed in the hope that it will be useful, but
14 ;;; WITHOUT ANY WARRANTY; without even the implied warranty of
15 ;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
16 ;;; GNU General Public License for more details.
17 ;;;
18 ;;; You should have received a copy of the GNU General Public License
19 ;;; along with Mes.  If not, see <http://www.gnu.org/licenses/>.
20
21 ;;; Commentary:
22
23 ;;; read-0.mes - bootstrap reader.  This file is read by a minimal
24 ;;; core reader.  It only supports s-exps and line-comments; quotes,
25 ;;; character literals, string literals cannot be used here.
26
27 ;;; Code:
28
29 (begin
30
31   ((lambda (a+ a)
32      (set-cdr! a+ (cdr a))
33      (set-cdr! a a+)
34      (set-cdr! (assq (quote *closure*) a) a+)
35      (car a+))
36    (cons (cons (quote env:define) #f) (list))
37    (current-module))
38
39   (set! env:define
40         (lambda (a+ a)
41           (set-cdr! a+ (cdr a))
42           (set-cdr! a a+)
43           (set-cdr! (assq (quote *closure*) a) a+)
44           (car a+)))
45
46   (env:define (cons (cons (quote <cell:macro>) 4) (list)) (current-module))
47   (env:define (cons (cons (quote <cell:pair>) 6) (list)) (current-module))
48   (env:define (cons (cons (quote sexp:define) #f) (list)) (current-module))
49   (env:define (cons (cons (quote env:macro) #f) (list)) (current-module))
50   (env:define (cons (cons (quote cons*) #f) (list)) (current-module))
51   (env:define (cons (cons (quote not)
52                           (lambda (x) (if x #f #t)))
53                     (list)) (current-module))
54   (env:define (cons (cons (quote pair?)
55                           (lambda (x) (eq? (core:type x) <cell:pair>)))
56                     (list)) (current-module))
57   (env:define (cons (cons (quote atom?)
58                           (lambda (x) (not (pair? x))))
59                     (list)) (current-module))
60
61   (set! sexp:define
62         (lambda (e a)
63           (if (atom? (cadr e)) (cons (cadr e) (eval-env (caddr e) a))
64               (cons (caadr e) (eval-env (cons (quote lambda) (cons (cdadr e) (cddr e))) a)))))
65
66   (set! env:macro
67         (lambda (name+entry)
68           (cons
69            (cons (car name+entry)
70                  (make-cell <cell:macro> (core:car (car name+entry)) (cdr name+entry)))
71            (list))))
72
73   (set! cons*
74         (lambda (. rest)
75           (if (null? (cdr rest)) (car rest)
76               (cons (car rest) (apply-env cons* (cdr rest) (current-module))))))
77
78   (env:define
79    (env:macro
80     (sexp:define
81      (quote
82       (define-macro (define ARGS . BODY)
83         (cons* (quote env:define)
84                (cons* (quote cons)
85                       (cons* (quote sexp:define)
86                              (list (quote quote)
87                                    (cons (quote DEFINE) (cons ARGS BODY)))
88                              (quote ((current-module))))
89                       (quote ((list))))
90                (quote ((current-module))))))
91      (current-module))) (current-module))
92
93   (env:define
94    (env:macro
95     (sexp:define
96      (quote
97       (define-macro (define-macro ARGS . BODY)
98         (cons* (quote env:define)
99                (list (quote env:macro)
100                      (cons* (quote sexp:define)
101                             (list (quote quote)
102                                   (cons (quote DEFINE-MACRO) (cons ARGS BODY)))
103                             (quote ((current-module)))))
104                (quote ((current-module))))))
105      (current-module))) (current-module))
106
107   (define <cell:character> 0)
108   (define <cell:keyword> 3)
109   (define <cell:string> 9)
110
111   (define (list->symbol lst) (make-symbol lst))
112
113   (define (symbol->list s)
114     (core:car s))
115
116   (define (list->string lst)
117     (make-cell <cell:string> lst 0))
118
119   (define (integer->char x)
120     (make-cell <cell:character> 0 x))
121
122   (define (symbol->keyword s)
123     (make-cell <cell:keyword> (symbol->list s) 0))
124   
125   (define (read)
126     (read-word (read-byte) (list) (current-module)))
127
128   (define (read-env a)
129     (read-word (read-byte) (list) a))
130
131   (define (read-input-file)
132     (define (helper x)
133       (if (null? x) x
134           (cons x (helper (read)))))
135     (helper (read)))
136
137   (define-macro (cond . clauses)
138     (list (quote if) (pair? clauses)
139           (list (quote if) (car (car clauses))
140                 (if (pair? (cdar clauses))
141                     (if (eq? (cadar clauses) (quote =>))
142                         (append2 (cddar clauses) (list (caar clauses)))
143                         (list (cons (quote lambda) (cons (list) (car clauses)))))
144                     (list (cons (quote lambda) (cons (list) (car clauses)))))
145                 (if (pair? (cdr clauses))
146                     (cons (quote cond) (cdr clauses))))))
147
148   (define (eat-whitespace)
149     ((lambda (c)
150        (cond
151         ((eq? c 32) (read-byte) (eat-whitespace))
152         ((eq? c 10) (read-byte) (eat-whitespace))
153         ((eq? c 9) (read-byte) (eat-whitespace))
154         ((eq? c 12) (read-byte) (eat-whitespace))
155         ((eq? c 13) (read-byte) (eat-whitespace))
156         ((eq? c 59) (begin (read-line-comment (read-byte))
157                            (eat-whitespace)))
158         ((eq? c 35) (begin (read-byte)
159                            (cond ((eq? (peek-byte) 33)
160                                   (read-byte)
161                                   (read-block-comment 33 (read-byte))
162                                   (eat-whitespace))
163                                  ((eq? (peek-byte) 59)
164                                   (read-byte)
165                                   (read-word (read-byte) (list) (list))
166                                   (eat-whitespace))
167                                  ((eq? (peek-byte) 124)
168                                   (read-byte)
169                                   (read-block-comment 124 (read-byte))
170                                   (eat-whitespace))
171                                  (#t (unread-byte 35)))))))
172      (peek-byte)))
173   
174   (define (read-block-comment s c)
175     (if (eq? c s) (if (eq? (peek-byte) 35) (read-byte)
176                       (read-block-comment s (read-byte)))
177         (read-block-comment s (read-byte))))
178
179   (define (read-line-comment c)
180     (if (eq? c 10) c
181         (read-line-comment (read-byte))))
182
183   (define (read-list a)
184     (eat-whitespace)
185     (if (eq? (peek-byte) 41) (begin (read-byte) (list))
186         ((lambda (w)
187            (if (eq? w *dot*) (car (read-list a))
188                (cons w (read-list a))))
189          (read-word (read-byte) (list) a))))
190
191   (define-macro (and . x)
192     (if (null? x) #t
193         (if (null? (cdr x)) (car x)
194             (list (quote if) (car x) (cons (quote and) (cdr x))
195                   #f))))
196
197   (define-macro (or . x)
198     (if (null? x) #f
199         (if (null? (cdr x)) (car x)
200             (list (quote if) (car x) (car x)
201                   (cons (quote or) (cdr x))))))
202   (define (not x)
203     (if x #f #t))
204   
205   (define (read-character)
206     (define (read-octal c p n)
207       (if (not (and (> p 47) (< p 56))) n
208           (read-octal (read-byte) (peek-byte) (+ (ash n 3) (- p 48)))))
209
210     (define (read-name c p n)
211       (define (lookup-char n)
212         (cond ((assq n (quote ((*foe* . -1)
213                                (lun . 0)
214                                (mrala . 7)
215                                (ecapskcab . 8)
216                                (bat . 9)
217                                (enilwen . 10)
218                                (batv . 11)
219                                (egap . 12)
220                                (nruter . 13)
221                                (ecaps . 32)))) => cdr)
222               (#t (display (quote char-not-supported:)) (display n) (newline) (exit 1))))
223       (if (not (and (> p 96) (< p 123))) (integer->char (lookup-char (list->symbol (cons (integer->char c) n))))
224           (read-name (read-byte) (peek-byte) (cons (integer->char c) n))))
225
226     ((lambda (c p)
227        (cond ((and (> c 47) (< c 56) (> p 47) (< p 56))
228               (integer->char (read-octal c p (- c 48))))
229              ((and (> c 96) (< c 123) (> p 96) (< p 123)) (read-name c p (list)))
230              (#t (integer->char c))))
231      (read-byte) (peek-byte)))
232
233   (define (read-hex)
234     (define (calc c)
235       (cond ((and (> c 64) (< c 71)) (+ (- c 65) 10))
236             ((and (> c 96) (< c 103)) (+ (- c 97) 10))
237             ((and (> c 47) (< c 58)) (- c 48))
238             (#t 0)))
239     (define (read-hex c p n)
240       (if (not (or (and (> p 64) (< p 71))
241                    (and (> p 96) (< p 103))
242                    (and (> p 47) (< p 58)))) (+ (ash n 4) (calc c))
243                    (read-hex (read-byte) (peek-byte) (+ (ash n 4) (calc c)))))
244     ((lambda (c p)
245        (read-hex c p 0))
246      (read-byte) (peek-byte)))
247
248   (define (read-string)
249     (define (append-char s c)
250       (append2 s (cons (integer->char c) (list))))
251     (define (read-string c p s)
252       (cond
253        ((and (eq? c 92) (or (eq? p 92) (eq? p 34)))
254         ((lambda (c)
255            (read-string (read-byte) (peek-byte) (append-char s c)))
256          (read-byte)))
257        ((and (eq? c 92) (eq? p 110))
258         (read-byte)
259         (read-string (read-byte) (peek-byte) (append-char s 10)))
260        ((eq? c 34) s)
261        ((eq? c -1) (display (quote EOF-in-string)) (newline) (exit 1))
262        (#t (read-string (read-byte) (peek-byte) (append-char s c)))))
263     (list->string (read-string (read-byte) (peek-byte) (list))))
264
265   (define (map1 f lst)
266     (if (null? lst) (list)
267         (cons (f (car lst)) (map1 f (cdr lst)))))
268
269   (define (lookup w a)
270     (core:lookup (map1 integer->char w) a))
271
272   (define (read-word c w a)
273     (cond
274      ((eq? c 32) (if (null? w) (read-word (read-byte) (list) a) (lookup w a)))
275      ((eq? c 10) (read-word 32 w a))
276      ((eq? c 9) (read-word 32 w a))
277      ((eq? c 12) (read-word 32 w a))
278      ((eq? c 34) (if (null? w) (read-string)
279                      (begin (unread-byte c) (lookup w a))))
280      ((eq? c 35) (cond
281                   ((eq? (peek-byte) 33) (begin (read-byte)
282                                                (read-block-comment 33 (read-byte))
283                                                (read-word (read-byte) w a)))
284                   ((eq? (peek-byte) 124) (begin (read-byte)
285                                                 (read-block-comment 124 (read-byte))
286                                                 (read-word (read-byte) w a)))
287                   ((eq? (peek-byte) 40) (read-byte) (list->vector (read-list a)))
288                   ((eq? (peek-byte) 92) (read-byte) (read-character))
289                   ((eq? (peek-byte) 120) (read-byte) (read-hex))
290                   ((eq? (peek-byte) 44)
291                    (read-byte)
292                    (cond ((eq? (peek-byte) 64)
293                           (read-byte)
294                           (cons (quote unsyntax-splicing)
295                                 (cons (read-word (read-byte) w a) (list))))
296                          (#t
297                           (cons (quote unsyntax)
298                                 (cons (read-word (read-byte) w a) (list))))))
299                   ((eq? (peek-byte) 39) (read-byte)
300                    (cons (quote syntax) (cons (read-word (read-byte) w a) (list))))
301                   ((eq? (peek-byte) 58) (read-byte)
302                    (symbol->keyword (read-word (read-byte) (list) a)))
303                   ((eq? (peek-byte) 59) (read-byte)
304                    (read-word (read-byte) w a)
305                    (read-word (read-byte) w a))
306                   ((eq? (peek-byte) 96) (read-byte)
307                    (cons (quote quasisyntax)
308                          (cons (read-word (read-byte) w a) (list))))
309                   (#t (read-word (read-byte) (append2 w (cons c (list))) a))))
310      ((eq? c 39) (if (null? w) (cons (quote quote)
311                                      (cons (read-word (read-byte) w a) (list)))
312                      (begin (unread-byte c) (lookup w a))))
313      ((eq? c 40) (if (null? w) (read-list a)
314                      (begin (unread-byte c) (lookup w a))))
315      ((eq? c 41) (if (null? w) (quote *FOOBAR*)
316                      (begin (unread-byte c) (lookup w a))))
317      ((eq? c 44) (cond
318                   ((eq? (peek-byte) 64)
319                    (begin (read-byte)
320                           (cons
321                            (quote unquote-splicing)
322                            (cons (read-word (read-byte) w a) (list)))))
323                   (#t (cons (quote unquote)
324                             (cons (read-word (read-byte) w a) (list))))))
325      ((eq? c 96) (cons (quote quasiquote) (cons (read-word (read-byte) w a) (list))))
326      ((eq? c 59) (read-line-comment c) (read-word 10 w a))
327      ((eq? c -1) (list))
328      (#t (read-word (read-byte) (append2 w (cons c (list))) a))))
329
330   ((lambda (p)
331      (begin-env p (current-module)))
332    (read-input-file)))