boot: support apply.
[mes.git] / module / mes / loop-0.mes
1 ;;; -*-scheme-*-
2
3 ;;; Mes --- Maxwell Equations of Software
4 ;;; Copyright © 2016 Jan Nieuwenhuizen <janneke@gnu.org>
5 ;;;
6 ;;; loop-0.mes: This file is part of Mes.
7 ;;;
8 ;;; Mes is free software; you can redistribute it and/or modify it
9 ;;; under the terms of the GNU General Public License as published by
10 ;;; the Free Software Foundation; either version 3 of the License, or (at
11 ;;; your option) any later version.
12 ;;;
13 ;;; Mes is distributed in the hope that it will be useful, but
14 ;;; WITHOUT ANY WARRANTY; without even the implied warranty of
15 ;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
16 ;;; GNU General Public License for more details.
17 ;;;
18 ;;; You should have received a copy of the GNU General Public License
19 ;;; along with Mes.  If not, see <http://www.gnu.org/licenses/>.
20
21 ;;; Commentary:
22
23 ;;; loop-0.mes - bootstrap into Scheme from minimal -DBOOT=1 core.
24
25 ;;; When compiling mes.c with -DBOOT=1, eval/apply et al. are lacking
26 ;;; features wrt the fat-c variant, e.g., define and define-macro are
27 ;;; not available; instead label is supplied.  Before loading
28 ;;; boot-0.mes, loop-0.mes is loaded to provide a richer eval/apply.
29
30 ;;; This might enable moving more functionality from C to Scheme,
31 ;;; making the entirely-from-source bootstrap process more feasible.
32 ;;; However, currently performance is 400x worse.  Also several tests
33 ;;; in the test suite fail and the REPL does not work yet.
34
35 ;;; Code:
36
37 ((label loop-0
38         (lambda (r e a)
39           ;; (display "***LOOP-0*** ... e=") (display e) (newline)
40           (if (null? e) (eval (read-file (read-env a) a) a)
41               (if (atom? e) (loop-0 (eval e a) (read-env a) a)
42                   (if (eq? (car e) 'define)
43                       ((lambda (aa)     ; env:define
44                          ;; (display "0DEFINE name=") (display (cadr e)) (newline)
45                          (set-cdr! aa (cdr a))
46                          (set-cdr! a aa)
47                          (set-cdr! (assq '*closure* a) a)
48                          (loop-0 *unspecified* (read-env a) a))
49                        (cons            ; sexp:define
50                         (if (atom? (cadr e)) (cons (cadr e) (eval (caddr e) a))
51                             (cons (caadr e) (eval (cons 'lambda (cons (cdadr e) (cddr e))) a)))
52                         '()))
53                       (if (eq? (car e) 'define-macro)
54                           ((lambda (name+entry) ; env:macro
55                              ;; (display "0MACRO name=") (display (car name+entry)) (newline)
56                              ((lambda (aa) ; env:define
57                                 (set-cdr! aa (cdr a))
58                                 (set-cdr! a aa)
59                                 (set-cdr! (assq '*closure* a) a)
60                                 (loop-0 *unspecified* (read-env a) a))
61                               (cons
62                                (cons (car name+entry)
63                                      (make-macro (car name+entry)
64                                                  (cdr name+entry)))
65                                '())))
66                                         ; sexp:define
67                            (if (atom? (cadr e)) (cons (cadr e) (eval (caddr e) a))
68                                (cons (caadr e) (eval (cons 'lambda (cons (cdadr e) (cddr e))) a)))
69                            '())
70                           (loop-0 (eval e a) (read-env a) a)))))))
71  *unspecified* (read-env '()) (current-module))
72
73 ()
74 ;; enter reading loop-0
75 (display "loop-0 ...\n")
76
77 (define-macro (cond . clauses)
78   (list 'if (null? clauses) *unspecified*
79         (if (null? (cdr clauses))
80             (list 'if (car (car clauses))
81                   (list (cons 'lambda (cons '() (cons (car (car clauses)) (cdr (car clauses))))))
82                   *unspecified*)
83             (if (eq? (car (cadr clauses)) 'else)
84                 (list 'if (car (car clauses))
85                       (list (cons 'lambda (cons '() (car clauses))))
86                       (list (cons 'lambda (cons '() (cons *unspecified* (cdr (cadr clauses)))))))
87                 (list 'if (car (car clauses))
88                       (list (cons 'lambda (cons '() (car clauses))))
89                       (cons 'cond (cdr clauses)))))))
90
91 (define (map f l . r)
92   (if (null? l) '()
93       (if (null? r) (cons (f (car l)) (map f (cdr l)))
94           (if (null? (cdr r))
95               (cons (f (car l) (caar r)) (map f (cdr l) (cdar r)))))))
96
97 (define-macro (simple-let bindings . rest)
98   (cons (cons 'lambda (cons (map car bindings) rest))
99         (map cadr bindings)))
100
101 (define-macro (let bindings . rest)
102   (cons 'simple-let (cons bindings rest)))
103
104 (define-macro (or . x)
105   (if (null? x) #f
106       (if (null? (cdr x)) (car x)
107           (list 'if (car x) (car x)
108                 (cons 'or (cdr x))))))
109
110 (define-macro (and . x)
111   (if (null? x) #t
112       (if (null? (cdr x)) (car x)
113           (list 'if (car x) (cons 'and (cdr x))
114                 #f))))
115
116 (define (not x)
117   (if x #f #t))
118
119 (define (evlis-env m a)
120   (cond
121    ((null? m) '())
122    ((not (pair? m)) (eval m a))
123    (#t (cons (eval (car m) a) (evlis-env (cdr m) a)))))
124
125 (define (apply-env fn x a) 
126   (cond
127    ((atom? fn)
128     (cond
129      ((builtin? fn) (call fn x))
130      ((eq? fn 'call-with-values) (c:apply-env 'call-with-values x a))
131      ((eq? fn 'current-module) a)
132      (#t (apply-env (eval fn a) x a))))
133    ((eq? (car fn) 'lambda)
134     (let ((p (pairlis (cadr fn) x a)))
135       (cache-invalidate-range p (cdr a))
136       (let ((r (eval (cons 'begin (cddr fn)) (cons (cons '*closure* p) p))))
137         (cache-invalidate-range p (cdr a))
138         r)))
139    ((eq? (car fn) '*closure*)
140     (let ((args (caddr fn))
141           (body (cdddr fn))
142           (a (cddr (cadr fn))))
143       (let ((p (pairlis args x a)))
144         (cache-invalidate-range p (cdr a))
145         (let ((r (eval (cons 'begin body) (cons (cons '*closure* p) p))))
146           (cache-invalidate-range p (cdr a))
147           r))))
148    ;;((eq? (car fn) 'label) (apply-env (caddr fn) x (cons (cons (cadr fn) (caddr fn)) a)))
149    (#t (apply-env (eval fn a) x a))))
150
151 (define (eval-expand e a)
152   (cond
153    ((internal? e) e)
154    ((builtin? e) e)
155    ((char? e) e)
156    ((number? e) e)
157    ((string? e) e)
158    ((vector? e) e)
159    ((symbol? e) (assq-ref-cache e a))
160    ((atom? (car e))
161     (cond
162      ((eq? (car e) 'quote) (cadr e))
163      ((eq? (car e) 'syntax) (cadr e))
164      ((eq? (car e) 'begin) (eval-begin-env e a))
165      ((eq? (car e) 'lambda) (make-closure (cadr e) (cddr e) (assq '*closure* a)))
166      ((eq? (car e) '*closure*) e)
167      ((eq? (car e) 'if) (eval-if-env (cdr e) a))
168      ((eq? (car e) 'define) (env:define (cons (sexp:define e a) '()) a))
169      ((eq? (car e) 'define-macro) (env:define (env:macro (sexp:define e a)) a))
170      ((eq? (car e) 'set!) (set-env! (cadr e) (eval (caddr e) a) a))
171      ((eq? (car e) 'apply-env) (apply-env (eval (cadr e) a) (evlis-env (caddr e) a) a))
172      ((eq? (car e) 'unquote) (eval (cadr e) a))
173      ((eq? (car e) 'quasiquote) (eval-quasiquote (cadr e) (add-unquoters a)))
174      (#t (apply-env (car e) (evlis-env (cdr e) a) a))))
175    (#t (apply-env (car e) (evlis-env (cdr e) a) a))))
176
177 (define (unquote x) (cons 'unquote x))
178 (define (unquote-splicing x) (cons 'quasiquote x))
179
180 (define (add-unquoters a)
181   (cons (cons 'unquote unquote)
182         (cons (cons 'unquote-splicing unquote-splicing) a)))
183
184 (define (eval e a)
185   (eval-expand (expand-macro-env e a) a))
186
187 (define (expand-macro-env e a)
188   (if (pair? e) ((lambda (macro)
189                    (if macro (expand-macro-env (apply-env macro (cdr e) a) a)
190                        e))
191                  (lookup-macro (car e) a))
192       e))
193
194 (define (eval-begin-env e a)
195   (if (null? e) *unspecified*
196       (if (null? (cdr e)) (eval (car e) a)
197           (begin
198             (eval (car e) a)
199             (eval-begin-env (cdr e) a)))))
200
201 (define (eval-if-env e a)
202   (if (eval (car e) a) (eval (cadr e) a)
203       (if (pair? (cddr e)) (eval (caddr e) a))))
204
205 (define (eval-quasiquote e a)
206   (cond ((null? e) e)
207         ((atom? e) e)
208         ((eq? (car e) 'unquote) (eval (cadr e) a))
209         ((and (pair? (car e))
210               (eq? (caar e) 'unquote-splicing))
211          (append2 (eval (cadar e) a) (eval-quasiquote (cdr e) a)))
212         (#t (cons (eval-quasiquote (car e) a) (eval-quasiquote (cdr e) a)))))
213
214 (define (sexp:define e a)
215   (if (atom? (cadr e)) (cons (cadr e) (eval (caddr e) a))
216       (cons (caadr e) (eval (cons 'lambda (cons (cdadr e) (cddr e))) a))))
217
218 (define (env:define a+ a)
219   (set-cdr! a+ (cdr a))
220   (set-cdr! a a+)
221   (set-cdr! (assq '*closure* a) a))
222
223 (define (env:macro name+entry)
224   (cons
225    (cons (car name+entry)
226          (make-macro (car name+entry)
227                      (cdr name+entry)))
228    '()))
229
230 ;; boot into loop-0
231 (cache-invalidate-range (current-module) '())
232 ()
233 ignored