test: Add syntax tests.
[mes.git] / module / mes / let.mes
1 ;;; -*-scheme-*-
2
3 ;;; Mes --- Maxwell Equations of Software
4 ;;; Copyright © 2016,2018 Jan Nieuwenhuizen <janneke@gnu.org>
5 ;;;
6 ;;; This file is part of Mes.
7 ;;;
8 ;;; Mes is free software; you can redistribute it and/or modify it
9 ;;; under the terms of the GNU General Public License as published by
10 ;;; the Free Software Foundation; either version 3 of the License, or (at
11 ;;; your option) any later version.
12 ;;;
13 ;;; Mes is distributed in the hope that it will be useful, but
14 ;;; WITHOUT ANY WARRANTY; without even the implied warranty of
15 ;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
16 ;;; GNU General Public License for more details.
17 ;;;
18 ;;; You should have received a copy of the GNU General Public License
19 ;;; along with Mes.  If not, see <http://www.gnu.org/licenses/>.
20
21 ;;; Commentary:
22
23 ;;; let.mes is loaded after base and quasiquote.  It provides
24 ;;; let, let* and named let.
25
26 ;;; Code:
27
28 (mes-use-module (mes base))
29 (mes-use-module (mes quasiquote))
30
31 (define-macro (simple-let bindings . rest)
32   (cons (cons 'lambda (cons (map1 car bindings) rest))
33         (map1 cadr bindings)))
34
35 (define-macro (xsimple-let bindings rest)
36   `(,`(lambda ,(map car bindings) ,@rest)
37     ,@(map cadr bindings)))
38
39 (define-macro (xnamed-let name bindings rest)
40   `(simple-let ((,name *unspecified*))
41      (set! ,name (lambda ,(map car bindings) ,@rest))
42      (,name ,@(map cadr bindings))))
43
44 (define-macro (let bindings-or-name . rest)
45   (if (symbol? bindings-or-name)
46       `(xnamed-let ,bindings-or-name ,(car rest) ,(cdr rest))
47       `(xsimple-let ,bindings-or-name ,rest)))
48
49 (define (expand-let* bindings body)
50   (if (null? bindings)
51       `((lambda () ,@body))
52       `((lambda (,(caar bindings))
53           ,(expand-let* (cdr bindings) body))
54         ,@(cdar bindings))))
55
56 (define-macro (let* bindings . body)
57   (expand-let* bindings body))
58
59 (define (unspecified-bindings bindings params)
60   (if (null? bindings) params
61       (unspecified-bindings
62        (cdr bindings)
63        (append params (cons (cons (caar bindings) '(*unspecified*)) '())))))
64
65 (define (letrec-setters bindings setters)
66   (if (null? bindings) setters
67       (letrec-setters (cdr bindings)
68                       (append setters
69                               (cons (cons 'set! (car bindings)) '())))))
70
71 (define-macro (letrec bindings . body)
72   `(let ,(unspecified-bindings bindings '())
73      ,@(letrec-setters bindings '())
74      ,@body))
75