mescc: Rename symbols to globals.
[mes.git] / module / mes / elf-util.mes
1 ;;; -*-scheme-*-
2
3 ;;; Mes --- Maxwell Equations of Software
4 ;;; Copyright © 2016,2017 Jan Nieuwenhuizen <janneke@gnu.org>
5 ;;;
6 ;;; This file is part of Mes.
7 ;;;
8 ;;; Mes is free software; you can redistribute it and/or modify it
9 ;;; under the terms of the GNU General Public License as published by
10 ;;; the Free Software Foundation; either version 3 of the License, or (at
11 ;;; your option) any later version.
12 ;;;
13 ;;; Mes is distributed in the hope that it will be useful, but
14 ;;; WITHOUT ANY WARRANTY; without even the implied warranty of
15 ;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
16 ;;; GNU General Public License for more details.
17 ;;;
18 ;;; You should have received a copy of the GNU General Public License
19 ;;; along with Mes.  If not, see <http://www.gnu.org/licenses/>.
20
21 ;;; Commentary:
22
23 ;;; compiler.mes produces an i386 binary from the C produced by
24 ;;; Nyacc c99.
25
26 ;;; Code:
27
28 (cond-expand
29  (guile)
30  (guile-2)
31  (mes
32   (mes-use-module (srfi srfi-1))))
33
34 (define (make-function key value)
35   (cons key (cons 'function value)))
36
37 (define (make-data key value)
38   (cons key (cons 'data value)))
39
40 (define (function-symbol? x)
41   (eq? (car x) 'function))
42
43 (define (function-entry? x)
44   (function-symbol? (cdr x)))
45
46 (define (data-symbol? x)
47   (eq? (car x) 'data))
48
49 (define (data-entry? x)
50   (data-symbol? (cdr x)))
51
52 (define (globals->functions globals)
53   (append-map cdr (filter function-symbol? (map cdr globals))))
54
55 (define (globals->text globals t d)
56   (let loop ((functions (globals->functions globals)) (text '()))
57     (if (null? functions) text
58         (loop (cdr functions)
59               (append text ((car functions) globals (- (length text)) d))))))
60
61 (define (function-offset name globals)
62   (let* ((functions (filter function-entry? globals))
63          (prefix (member name (reverse functions)
64                          (lambda (a b)
65                            (equal? (car b) name)))))
66     (if prefix (length (globals->text (cdr prefix) 0 0))
67         0)))
68
69 (define (data-offset name globals)
70   (let* ((globals (filter data-entry? globals))
71          (prefix (member name (reverse globals)
72                          (lambda (a b)
73                            (equal? (car b) name)))))
74     (if prefix (length (globals->data (cdr prefix)))
75         0)))
76
77 (define (globals->data globals)
78   (append-map cdr (filter data-symbol? (map cdr globals))))