mes: Single environment lookup for variables, SICP chapter 3.
[mes.git] / module / mes / display.mes
1 ;;; -*-scheme-*-
2
3 ;;; Mes --- Maxwell Equations of Software
4 ;;; Copyright © 2016,2017,2018 Jan Nieuwenhuizen <janneke@gnu.org>
5 ;;;
6 ;;; This file is part of Mes.
7 ;;;
8 ;;; Mes is free software; you can redistribute it and/or modify it
9 ;;; under the terms of the GNU General Public License as published by
10 ;;; the Free Software Foundation; either version 3 of the License, or (at
11 ;;; your option) any later version.
12 ;;;
13 ;;; Mes is distributed in the hope that it will be useful, but
14 ;;; WITHOUT ANY WARRANTY; without even the implied warranty of
15 ;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
16 ;;; GNU General Public License for more details.
17 ;;;
18 ;;; You should have received a copy of the GNU General Public License
19 ;;; along with Mes.  If not, see <http://www.gnu.org/licenses/>.
20
21 ;;; Commentary:
22
23 ;;; Code:
24
25 (mes-use-module (mes scm))
26 ;;(mes-use-module (mes srfi srfi-1))
27
28 (define (srfi-1:member x lst eq)
29   (if (null? lst) #f
30       (if (eq x (car lst)) lst
31           (srfi-1:member x (cdr lst) eq))))
32
33 (define (next-xassq x a)
34   (and=> (srfi-1:member x a (lambda (x e) (eq? x (cdr e))))
35          (lambda (a) (xassq x (cdr a)))))
36
37 (define (next-xassq2 x a)
38   (and=> (srfi-1:member x a (lambda (x e) (eq? x (cdr e))))
39          (lambda (a)
40            (and=> (srfi-1:member x (cdr a) (lambda (x e) (eq? x (cdr e))))
41                   (lambda (a) (xassq x (cdr a)))))))
42
43 (define-macro (display-cut f slot n1)
44   `(lambda (slot) (,f slot ,n1)))
45
46 (define-macro (display-cut2 f slot n1 n2)
47   `(lambda (slot) (,f slot ,n1 ,n2)))
48
49 (define (display x . rest)
50   (let* ((port (if (null? rest) (current-output-port) (car rest)))
51          (write? (and (pair? rest) (pair? (cdr rest)) (cadr rest))))
52
53     (define (display-char x port write?)
54       (cond ((and write? (or (eq? x #\") (eq? x #\\)))
55              (write-char #\\ port)
56              (write-char x port))
57             ((and write? (eq? x #\newline))
58              (write-char #\\ port)
59              (write-char #\n port))
60             (#t (write-char x port))))
61
62     (define (d x cont? sep)
63       (for-each (display-cut write-char <> port) (string->list sep))
64       (cond
65        ((eof-object? x)
66         (display "#<eof>" port))
67        ((char? x)
68         (if (not write?) (write-char x port)
69             (let ((name (and=> (assq x '((#\nul . nul)
70                                          (#\alarm . alarm)
71                                          (#\backspace . backspace)
72                                          (#\tab . tab)
73                                          (#\newline . newline)
74                                          (#\vtab . vtab)
75                                          (#\page . page)
76                                          (#\return . return)
77                                          (#\space . space)))
78                                cdr)))
79               (write-char #\# port)
80               (write-char #\\ port)
81               (if name (display name port)
82                   (write-char x port)))))
83        ((closure? x)
84         (display "#<procedure " port)
85         (let ((name (and=> (next-xassq2 x (current-module)) car)))
86           (display name port))
87         (display " " port)
88         (display (cadr (core:cdr x)) port)
89         (display ">" port))
90        ((continuation? x)
91         (display "#<continuation " port)
92         (display (core:car x) port)
93         (display ">" port))
94        ((macro? x)
95         (display "#<macro " port)
96         (display (core:cdr x) port)
97         (display ">" port))
98        ((variable? x)
99         (display "#<variable " port)
100         (if (variable-global? x)
101             (display "*global* " port))
102         (display (car (core:car x)) port)
103         (display ">" port))
104        ((number? x)
105         (display (number->string x) port))
106        ((pair? x)
107         (if (not cont?) (write-char #\( port))
108         (cond ((eq? (car x) '*circular*)
109                (display "*circ* . #-1#)" port))
110               ((eq? (car x) '*closure*)
111                (display "*closure* . #-1#)" port))
112               (#t
113                (display (car x) port write?)
114                (if (pair? (cdr x)) (d (cdr x) #t " ")
115                    (if (and (cdr x) (not (null? (cdr x))))
116                        (begin
117                          (display " . " port)
118                          (display (cdr x) port write?))))))
119         (if (not cont?) (write-char #\) port)))
120        ((or (keyword? x) (special? x) (string? x) (symbol? x))
121         (if (and (string? x) write?) (write-char #\" port))
122         (if (keyword? x) (display "#:" port))
123         (for-each (display-cut2 display-char <> port write?) (string->list x))
124         (if (and (string? x) write?) (write-char #\" port)))
125        ((vector? x)
126         (display "#(" port)
127         (for-each (lambda (i)
128                     (let ((x (vector-ref x i)))
129                       (if (vector? x)
130                           (begin
131                             (display (if (= i 0) "" " ") port)
132                             (display "#(...)" port))
133                           (d x #f (if (= i 0) "" " ")))))
134                   (iota (vector-length x)))
135         (display ")" port))
136        ((function? x)
137         (display "#<procedure " port)
138         (display (core:car x) port)
139         (display " " port)
140         (display
141          (case (core:arity x)
142            ((-1) "_")
143            ((0) "()")
144            ((1) "(_)")
145            ((2) "(_ _)")
146            ((3) "(_ _ _)"))
147          port)
148         (display ">" port))
149        ((broken-heart? x)
150         (display "<3" port))
151        (#t
152         (display "TODO type=") (display (cell:type-name x)) (newline)))
153       *unspecified*)
154     (d x #f "")))
155
156 (define (write-char x . rest)
157   (apply write-byte (cons (char->integer x) rest)))
158
159 (define (write x . rest)
160   (let ((port (if (null? rest) (current-output-port) (car rest))))
161     (display x port #t)))
162
163 (define (newline . rest)
164   (apply display (cons "\n" rest)))
165
166 (define (with-output-to-string thunk)
167   (define save-write-byte write-byte)
168   (let ((stdout '()))
169     (set! write-byte
170           (lambda (x . rest)
171             (let ((out? (or (null? rest) (eq? (car rest) (current-output-port)))))
172               (if (not out?) (apply save-write-byte (cons x rest))
173                   (begin
174                     (set! stdout (append stdout (list (integer->char x))))
175                     x)))))
176     (thunk)
177     (let ((r (apply string stdout)))
178       (set! write-byte save-write-byte)
179       r)))
180
181 (define (simple-format destination format . rest)
182   (let ((port (if (boolean? destination) (current-output-port) destination))
183         (lst (string->list format)))
184     (define (simple-format lst args)
185       (if (pair? lst)
186           (let ((c (car lst)))
187             (if (not (eq? c #\~)) (begin (write-char (car lst) port)
188                                          (simple-format (cdr lst) args))
189                 (let ((c (cadr lst)))
190                   (case c
191                     ((#\A) (display (car args) port))
192                     ((#\a) (display (car args) port))
193                     ((#\S) (write (car args) port))
194                     ((#\s) (write (car args) port))
195                     (else (display (car args) port)))
196                   (simple-format (cddr lst) (cdr args)))))))
197     
198     (if destination (simple-format lst rest)
199         (with-output-to-string
200           (lambda () (simple-format lst rest))))))
201
202 (define format simple-format)