f45c3cea49bce77debf10e51fdbc5b8873980f41
[mes.git] / module / mes / base-0.mes
1 ;;; -*-scheme-*-
2
3 ;;; Mes --- Maxwell Equations of Software
4 ;;; Copyright © 2016,2017 Jan Nieuwenhuizen <janneke@gnu.org>
5 ;;;
6 ;;; This file is part of Mes.
7 ;;;
8 ;;; Mes is free software; you can redistribute it and/or modify it
9 ;;; under the terms of the GNU General Public License as published by
10 ;;; the Free Software Foundation; either version 3 of the License, or (at
11 ;;; your option) any later version.
12 ;;;
13 ;;; Mes is distributed in the hope that it will be useful, but
14 ;;; WITHOUT ANY WARRANTY; without even the implied warranty of
15 ;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
16 ;;; GNU General Public License for more details.
17 ;;;
18 ;;; You should have received a copy of the GNU General Public License
19 ;;; along with Mes.  If not, see <http://www.gnu.org/licenses/>.
20
21 ;;; Commentary:
22
23 ;;; base-0.mes is the first file being loaded from the Mes core.  It
24 ;;; provides primitives that use Mes internals to create the illusion
25 ;;; of compatibility with Guile.  It is not safe to be run by Guile.
26
27 ;;; Code:
28
29 (define mes? #t)
30 (define guile? #f)
31 (define guile-1.8? #f)
32 (define guile-2? #f)
33
34 (define (primitive-eval e) (core:eval e (current-module)))
35 (define eval core:eval)
36
37 (define-macro (defined? x)
38   (list 'assq x '(cdr (cdr (current-module)))))
39
40 (if (defined? 'current-input-port) #t
41     (define (current-input-port) 0))
42
43 (define (current-output-port) 1)
44 (define (current-error-port) 2)
45 (define (port-filename port) "<stdin>")
46 (define (port-line port) 0)
47 (define (port-column port) 0)
48 (define (ftell port) 0)
49 (define (false-if-exception x) x)
50
51 (define (cons* . rest)
52   (if (null? (cdr rest)) (car rest)
53       (cons (car rest) (core:apply cons* (cdr rest) (current-module)))))
54
55 (define (apply f h . t)
56   (if (null? t) (core:apply f h (current-module))
57       (apply f (apply cons* (cons h t)))))
58
59 (define-macro (cond . clauses)
60   (list 'if (pair? clauses)
61         (list (cons
62                'lambda
63                (cons
64                 '(test)
65                 (list (list 'if 'test
66                             (if (pair? (cdr (car clauses)))
67                                 (if (eq? (car (cdr (car clauses))) '=>)
68                                     (append2 (cdr (cdr (car clauses))) '(test))
69                                     (list (cons 'lambda (cons '() (car clauses)))))
70                                 (list (cons 'lambda (cons '() (car clauses)))))
71                             (if (pair? (cdr clauses))
72                                 (cons 'cond (cdr clauses)))))))
73               (car (car clauses)))))
74
75 (define else #t)
76
77 (define (cadr x) (car (cdr x)))
78 (define-macro (simple-let bindings . rest)
79   (cons (cons 'lambda (cons (map1 car bindings) rest))
80         (map1 cadr bindings)))
81
82 (define-macro (let bindings . rest)
83   (cons 'simple-let (cons bindings rest)))
84
85 (define *input-ports* '())
86 (define-macro (push! stack o)
87   (cons
88    'begin
89    (list
90     (list 'set! stack (list cons o stack))
91     stack)))
92 (define-macro (pop! stack)
93   (list 'let (list (list 'o (list car stack)))
94         (list 'set! stack (list cdr stack))
95         'o))
96 (define-macro (load file)
97   (list 'begin
98         (list 'if (list getenv "MES_DEBUG")
99               (list 'begin
100                     (list core:display-error "read ")
101                     (list core:display-error file)
102                     (list core:display-error "\n")))
103      (list 'push! '*input-ports* (list current-input-port))
104      (list 'set-current-input-port (list open-input-file file))
105      (list 'primitive-load)
106      (list 'set-current-input-port (list 'pop! '*input-ports*))))
107
108 (define include load)
109
110 (define (append . rest)
111   (if (null? rest) '()
112       (if (null? (cdr rest)) (car rest)
113           (append2 (car rest) (apply append (cdr rest))))))
114
115 (include "module/mes/type-0.mes")
116
117 (define (symbol->string s)
118   (apply string (symbol->list s)))
119
120 (define (string-append . rest)
121   (apply string (apply append (map1 string->list rest))))
122
123 (define %moduledir "module/")
124 (define %version (if (eq? (car (string->list "@VERSION@")) #\@) "git" "@VERSION@"))
125 (define (effective-version) %version)
126
127 (if (getenv "MES_DEBUG")
128     (begin
129       (core:display-error "%moduledir=")
130       (core:display-error %moduledir)
131       (core:display-error "\n")))
132
133 (define-macro (include-from-path file)
134   (list 'load (list string-append %moduledir file)))
135
136 (define (memq x lst)
137   (if (null? lst) #f
138       (if (eq? x (car lst)) lst
139           (memq x (cdr lst)))))
140
141 (define (string-join lst infix)
142   (if (null? (cdr lst)) (car lst)
143       (string-append (car lst) infix (string-join (cdr lst) infix))))
144
145 (define (module->file o)
146   (string-append (string-join (map1 symbol->string o) "/") ".mes"))
147
148 (define *modules* '(mes/base-0.mes))
149 (define (mes-load-module-env module a)
150   (push! *input-ports* (current-input-port))
151   (set-current-input-port (open-input-file (string-append %moduledir (module->file module))))
152   (let ((x (core:eval (append2 (cons 'begin (read-input-file-env a))
153                                '((current-module)))
154                       a)))
155     (set-current-input-port (pop! *input-ports*))
156     x))
157 (define (not x)
158   (if x #f #t))
159 (define-macro (mes-use-module module)
160   (list
161    'begin
162    (list 'if (list 'not (list 'memq (list string->symbol (module->file module)) '*modules*))
163          (list
164           'begin
165           (list 'set! '*modules* (list cons (list string->symbol (module->file module)) '*modules*))
166           (list 'load (list string-append '%moduledir (module->file module)))))))
167
168 (mes-use-module (mes base))
169 (mes-use-module (srfi srfi-0))
170 (mes-use-module (mes quasiquote))
171 (mes-use-module (mes let))
172 (mes-use-module (mes scm))
173 (mes-use-module (srfi srfi-13))
174 (mes-use-module (mes display))
175 (mes-use-module (mes catch))