4dfbeb60b3c0b6e8ad7442b236b0ec73a81a3fad
[mes.git] / module / mes / base-0.mes
1 ;;; -*-scheme-*-
2
3 ;;; Mes --- Maxwell Equations of Software
4 ;;; Copyright © 2016 Jan Nieuwenhuizen <janneke@gnu.org>
5 ;;;
6 ;;; This file is part of Mes.
7 ;;;
8 ;;; Mes is free software; you can redistribute it and/or modify it
9 ;;; under the terms of the GNU General Public License as published by
10 ;;; the Free Software Foundation; either version 3 of the License, or (at
11 ;;; your option) any later version.
12 ;;;
13 ;;; Mes is distributed in the hope that it will be useful, but
14 ;;; WITHOUT ANY WARRANTY; without even the implied warranty of
15 ;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
16 ;;; GNU General Public License for more details.
17 ;;;
18 ;;; You should have received a copy of the GNU General Public License
19 ;;; along with Mes.  If not, see <http://www.gnu.org/licenses/>.
20
21 ;;; Commentary:
22
23 ;;; base-0.mes is the first file being loaded from the Mes core.  It
24 ;;; provides primitives that use Mes internals to create the illusion
25 ;;; of compatibility with Guile.  It is not safe to be run by Guile.
26
27 ;;; Code:
28
29 (define (effective-version) "0.3")
30 (define mes? #t)
31 (define guile? #f)
32 (define guile-1.8? #f)
33 (define guile-2? #f)
34
35 (define (primitive-eval e) (eval-env e (current-module)))
36 (define eval eval-env)
37 (define (expand-macro e) (expand-macro-env e (current-module)))
38
39 (define quotient /)
40
41 (define-macro (defined? x)
42   (list 'assq x '(cddr (current-module))))
43
44 (if (defined? 'current-input-port) #t
45     (define (current-input-port) 0))
46
47 (define (current-output-port) 1)
48 (define (current-error-port) 2)
49 (define (port-filename port) "<stdin>")
50 (define (port-line port) 0)
51 (define (port-column port) 0)
52 (define (ftell port) 0)
53 (define (false-if-exception x) x)
54
55 (define (cons* x . rest)
56   (define (loop rest)
57     (if (null? (cdr rest)) (car rest)
58         (cons (car rest) (loop (cdr rest)))))
59   (loop (cons x rest)))
60
61 (define (apply f h . t) (apply-env f (cons h t) (current-module)))
62 (define (apply f h . t)
63   (if (null? t) (apply-env f h (current-module))
64       (apply f (apply cons* (cons h t)))))
65
66 (define-macro (cond . clauses)
67   (list 'if (pair? clauses)
68         (list (cons
69                'lambda
70                (cons
71                 '(test)
72                 (list (list 'if 'test
73                             (if (pair? (cdar clauses))
74                                 (if (eq? (cadar clauses) '=>)
75                                     (append2 (cddar clauses) '(test))
76                                     (list (cons 'lambda (cons '() (car clauses)))))
77                                 (list (cons 'lambda (cons '() (car clauses)))))
78                             (if (pair? (cdr clauses))
79                                 (cons 'cond (cdr clauses)))))))
80               (car (car clauses)))))
81
82 (define else #t)
83
84 (define (map f l . r)
85   (if (null? l) '()
86       (if (null? r) (cons (f (car l)) (map f (cdr l)))
87           (if (null? (cdr r))
88               (cons (f (car l) (caar r)) (map f (cdr l) (cdar r)))
89               (if (null? (cddr r))
90                   (cons (f (car l) (caar r) (caadr r)) (map f (cdr l) (cdar r) (cdadr r)))
91                   '*MAP-4-NOT-SUPPORTED)))))
92
93 (define-macro (simple-let bindings . rest)
94   (cons (cons 'lambda (cons (map car bindings) rest))
95         (map cadr bindings)))
96
97 (define-macro (let bindings . rest)
98   (cons 'simple-let (cons bindings rest)))
99
100 (define *input-ports* '())
101 (define-macro (push! stack o)
102   (cons
103    'begin
104    (list
105     (list 'set! stack (list cons o stack))
106     stack)))
107 (define-macro (pop! stack)
108   (list 'let (list (list 'o (list car stack)))
109         (list 'set! stack (list cdr stack))
110         'o))
111 (define-macro (load file)
112   (list 'begin
113      (list 'push! '*input-ports* (list current-input-port))
114      (list 'set-current-input-port (list open-input-file file))
115      (list 'primitive-load)
116      (list 'set-current-input-port (list 'pop! '*input-ports*))))
117 (define (memq x lst)
118   (if (null? lst) #f
119       (if (eq? x (car lst)) lst
120           (memq x (cdr lst)))))
121
122 (define (string-join lst infix)
123   (if (null? (cdr lst)) (car lst)
124       (string-append (car lst) infix (string-join (cdr lst) infix))))
125
126 (define *mes-prefix* "module/")
127 (define (module->file o)
128   (string-append (string-join (map symbol->string o) "/") ".mes"))
129
130 (define *modules* '(mes/base-0.mes))
131 (define (mes-load-module-env module a)
132   (push! *input-ports* (current-input-port))
133   (set-current-input-port (open-input-file (string-append *mes-prefix* (module->file module))))
134   (let ((x (eval-env (append (cons 'begin (read-input-file-env #f a))
135                              '((current-module)))
136                      a)))
137     (set-current-input-port (pop! *input-ports*))
138     x))
139 (define (not x)
140   (if x #f #t))
141 (define-macro (mes-use-module module)
142   (list
143    'begin
144    (list 'if (list 'not (list 'memq (list string->symbol (module->file module)) '*modules*))
145          (list
146           'begin
147           (list 'set! '*modules* (list cons (list string->symbol (module->file module)) '*modules*))
148           ;; (list display "loading file=" (list current-error-port))
149           ;; (list display (module->file module) (list current-error-port))
150           ;; (list newline (list current-error-port))
151           (list 'load (list string-append '*mes-prefix* (module->file module)))))))
152
153 (define include load)
154 (define-macro (include-from-path file)
155   (list 'load (list string-append "module/" file)))
156
157 (mes-use-module (srfi srfi-0))
158 (mes-use-module (mes base))
159 (mes-use-module (mes scm))