Make guile switchable in GNUmakefile.
[mes.git] / module / mes / base-0.mes
1 ;;; -*-scheme-*-
2
3 ;;; Mes --- Maxwell Equations of Software
4 ;;; Copyright © 2016 Jan Nieuwenhuizen <janneke@gnu.org>
5 ;;;
6 ;;; This file is part of Mes.
7 ;;;
8 ;;; Mes is free software; you can redistribute it and/or modify it
9 ;;; under the terms of the GNU General Public License as published by
10 ;;; the Free Software Foundation; either version 3 of the License, or (at
11 ;;; your option) any later version.
12 ;;;
13 ;;; Mes is distributed in the hope that it will be useful, but
14 ;;; WITHOUT ANY WARRANTY; without even the implied warranty of
15 ;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
16 ;;; GNU General Public License for more details.
17 ;;;
18 ;;; You should have received a copy of the GNU General Public License
19 ;;; along with Mes.  If not, see <http://www.gnu.org/licenses/>.
20
21 ;;; Commentary:
22
23 ;;; base-0.mes is the first file being loaded from the Mes core.  It
24 ;;; provides primitives that use Mes internals to create the illusion
25 ;;; of compatibility with Guile.  It is not safe to be run by Guile.
26
27 ;;; Code:
28
29 (define (effective-version) "0.3")
30 (define mes? #t)
31 (define guile? #f)
32 (define guile-1.8? #f)
33 (define guile-2? #f)
34
35 (define (primitive-eval e) (eval-env e (current-module)))
36 (define eval eval-env)
37 (define (expand-macro e) (expand-macro-env e (current-module)))
38
39 (define quotient /)
40
41 (define-macro (defined? x)
42   (list 'assq x '(cddr (current-module))))
43
44 (if (defined? 'current-input-port) #t
45     (define (current-input-port) 0))
46
47 (define (current-output-port) 1)
48 (define (current-error-port) 2)
49 (define (port-filename port) "<stdin>")
50 (define (port-line port) 0)
51 (define (port-column port) 0)
52 (define (ftell port) 0)
53 (define (false-if-exception x) x)
54
55 (define (cons* x . rest)
56   (define (loop rest)
57     (if (null? (cdr rest)) (car rest)
58         (cons (car rest) (loop (cdr rest)))))
59   (loop (cons x rest)))
60
61 (define (apply f h . t) (apply-env f (cons h t) (current-module)))
62 (define (apply f h . t)
63   (if (null? t) (apply-env f h (current-module))
64       (apply f (apply cons* (cons h t)))))
65
66 (define-macro (cond . clauses)
67   (list 'if (pair? clauses)
68         (list (cons
69                'lambda
70                (cons
71                 '(test)
72                 (list (list 'if 'test
73                             (if (pair? (cdar clauses))
74                                 (if (eq? (cadar clauses) '=>)
75                                     (append2 (cddar clauses) '(test))
76                                     (list (cons 'lambda (cons '() (car clauses)))))
77                                 (list (cons 'lambda (cons '() (car clauses)))))
78                             (if (pair? (cdr clauses))
79                                 (cons 'cond (cdr clauses)))))))
80               (car (car clauses)))))
81
82 (define else #t)
83
84 (define (map f l . r)
85   (if (null? l) '()
86       (if (null? r) (cons (f (car l)) (map f (cdr l)))
87           (if (null? (cdr r))
88               (cons (f (car l) (caar r)) (map f (cdr l) (cdar r)))))))
89
90 (define-macro (simple-let bindings . rest)
91   (cons (cons 'lambda (cons (map car bindings) rest))
92         (map cadr bindings)))
93
94 (define-macro (let bindings . rest)
95   (cons 'simple-let (cons bindings rest)))
96
97 (define *input-ports* '())
98 (define-macro (push! stack o)
99   (cons
100    'begin
101    (list
102     (list 'set! stack (list cons o stack))
103     stack)))
104 (define-macro (pop! stack)
105   (list 'let (list (list 'o (list car stack)))
106         (list 'set! stack (list cdr stack))
107         'o))
108 (define-macro (load file)
109   (list 'begin
110      (list 'push! '*input-ports* (list current-input-port))
111      (list 'set-current-input-port (list open-input-file file))
112      (list 'primitive-load)
113      (list 'set-current-input-port (list 'pop! '*input-ports*))))
114 (define (memq x lst)
115   (if (null? lst) #f
116       (if (eq? x (car lst)) lst
117           (memq x (cdr lst)))))
118
119 (define (string-join lst infix)
120   (if (null? (cdr lst)) (car lst)
121       (string-append (car lst) infix (string-join (cdr lst) infix))))
122
123 (define *mes-prefix* "module/")
124 (define (module->file o)
125   (string-append (string-join (map symbol->string o) "/") ".mes"))
126
127 (define *modules* '(mes/base-0.mes))
128 (define (mes-load-module-env module a)
129   (push! *input-ports* (current-input-port))
130   (set-current-input-port (open-input-file (string-append *mes-prefix* (module->file module))))
131   (let ((x (eval-env (append (cons 'begin (read-input-file-env #f a))
132                              '((current-module)))
133                      a)))
134     (set-current-input-port (pop! *input-ports*))
135     x))
136 (define (not x)
137   (if x #f #t))
138 (define-macro (mes-use-module module)
139   (list
140    'begin
141    (list 'if (list 'not (list 'memq (list string->symbol (module->file module)) '*modules*))
142          (list
143           'begin
144           (list 'set! '*modules* (list cons (list string->symbol (module->file module)) '*modules*))
145           ;; (list display "loading file=" (list current-error-port))
146           ;; (list display (module->file module) (list current-error-port))
147           ;; (list newline (list current-error-port))
148           (list 'load (list string-append '*mes-prefix* (module->file module)))))))
149
150 (mes-use-module (srfi srfi-0))
151 (mes-use-module (mes base))
152 (mes-use-module (mes scm))