mes: string->number: Support #x-prefixed hex numbers.
[mes.git] / mes / module / mes / scm.mes
1 ;;; -*-scheme-*-
2
3 ;;; GNU Mes --- Maxwell Equations of Software
4 ;;; Copyright © 2016,2017,2018,2019 Jan (janneke) Nieuwenhuizen <janneke@gnu.org>
5 ;;;
6 ;;; This file is part of GNU Mes.
7 ;;;
8 ;;; GNU Mes is free software; you can redistribute it and/or modify it
9 ;;; under the terms of the GNU General Public License as published by
10 ;;; the Free Software Foundation; either version 3 of the License, or (at
11 ;;; your option) any later version.
12 ;;;
13 ;;; GNU Mes is distributed in the hope that it will be useful, but
14 ;;; WITHOUT ANY WARRANTY; without even the implied warranty of
15 ;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
16 ;;; GNU General Public License for more details.
17 ;;;
18 ;;; You should have received a copy of the GNU General Public License
19 ;;; along with GNU Mes.  If not, see <http://www.gnu.org/licenses/>.
20
21 ;;; Commentary:
22
23 ;;; scm.mes is loaded after base, quasiquote and let.  It provides
24 ;;; basic Scheme functions bringing Mes close to basic RRS Scheme (no
25 ;;; labels, processes, fluids or throw/catch).
26
27 ;;; Code:
28
29 (mes-use-module (mes let))
30
31 (define (cadddr x) (car (cdddr x)))
32
33 (define-macro (case val . args)
34   (if (null? args) #f
35       (let ((clause (car args)))
36         (let ((pred (car clause)))
37           (let ((body (cdr clause)))
38            (if (pair? pred) `(if ,(if (null? (cdr pred))
39                                       `(eq? ,val ',(car pred))
40                                       `(member ,val ',pred))
41                                  (begin ,@body)
42                                  (case ,val ,@(cdr args)))
43                `(begin ,@body)))))))
44
45 (define-macro (when expr . body)
46   `(if ,expr
47        ((lambda () ,@body))))
48
49 (define-macro (unless expr . body)
50   `(if (not ,expr)
51        ((lambda () ,@body))))
52
53 (define-macro (do init test . body)
54   `(let loop ((,(caar init) ,(cadar init)))
55      (when (not ,@test)
56        ,@body
57        (loop ,@(cddar init)))))
58
59 (define (for-each f l . xr)
60   (if (and (pair? l)
61            (or (null? xr)
62                (pair? (car xr))))
63       (if (null? xr) (begin (f (car l)) (for-each f (cdr l)))
64           (if (null? (cdr xr)) (begin (f (car l) (caar xr)) (for-each f (cdr l) (cdar xr)))))))
65
66 (define core:error error)
67
68 (define (error who . rest)
69   (display "error:" (current-error-port))
70   (display who (current-error-port))
71   (display ":" (current-error-port))
72   (display rest (current-error-port))
73   (newline (current-error-port))
74   (display "exiting...\n" (current-error-port))
75   (core:error (if (symbol? who) who 'error) (cons who rest)))
76
77 (define (syntax-error message . rest)
78   (display "syntax-error:" (current-error-port))
79   (display message (current-error-port))
80   (display ":" (current-error-port))
81   (display rest (current-error-port))
82   (newline (current-error-port))
83   (core:error 'syntax-error (cons message rest)))
84
85 \f
86 (define integer? number?)
87
88 (define (read . port)
89   (if (null? port) (read-env (current-module))
90       (let* ((prev (set-current-input-port (car port)))
91              (result (read-env (current-module))))
92         result)))
93
94 (if (not (defined? 'peek-char))
95     (define (peek-char)
96       (integer->char (peek-byte))))
97
98 (if (not (defined? 'read-char))
99     (define (read-char)
100       (integer->char (read-byte))))
101
102 (if (not (defined? 'unread-char))
103     (define (unread-char c)
104       (integer->char (unread-byte (char->integer c)))))
105
106 (define (assq-set! alist key val)
107   (let ((entry (assq key alist)))
108     (if (not entry) (acons key val alist)
109         (let ((entry (set-cdr! entry val)))
110           alist))))
111
112 (define (assq-ref alist key)
113   (and alist
114        (let ((entry (assq key alist)))
115          (if entry (cdr entry)
116              #f))))
117
118 (define assv assq)
119 (define assv-ref assq-ref)
120
121 (define (assoc-ref alist key)
122   (and (pair? alist)
123        (let ((entry (assoc key alist)))
124          (if entry (cdr entry)
125              #f))))
126
127 (define (assoc-set! alist key value)
128   (let ((entry (assoc key alist)))
129     (if (not entry) (acons key value alist)
130         (let ((entry (set-cdr! entry value)))
131           alist))))
132
133 (define memv memq)
134
135 (define (member x lst)
136   (if (null? lst) #f
137       (if (equal? x (car lst)) lst
138           (member x (cdr lst)))))
139
140 \f
141 ;;; Lists
142 (define (make-list n . x)
143   (let ((fill (if (pair? x) (car x) *unspecified*)))
144     (let loop ((n n))
145       (if (= 0 n) '()
146           (cons fill (loop (- n 1)))))))
147
148 (define (list-ref lst k)
149   (let loop ((lst lst) (k k))
150     (if (= 0 k) (car lst)
151         (loop (cdr lst) (- k 1)))))
152
153 (define (list-set! lst k v)
154   (let loop ((lst lst) (k k))
155     (if (= 0 k) (set-car! lst v)
156         (loop (cdr lst) (- k 1)))))
157
158 (define (list-head x n)
159   (if (= 0 n) '()
160       (cons (car x) (list-head (cdr x) (- n 1)))))
161
162 (define (list-tail x n)
163   (if (= 0 n) x
164       (list-tail (cdr x) (- n 1))))
165
166 (define (iota n)
167   (if (<= n 0) '()
168       (append2 (iota (- n 1)) (list (- n 1)))))
169
170 (define (reverse lst)
171   (let loop ((lst lst) (r '()))
172     (if (null? lst) r
173         (loop (cdr lst) (cons (car lst) r)))))
174
175 (define (filter pred lst)
176   (let loop ((lst lst))
177     (if (null? lst) '()
178         (if (pred (car lst))
179             (cons (car lst) (loop (cdr lst)))
180             (loop (cdr lst))))))
181
182 (define (delete x lst)
183   (filter (lambda (e) (not (equal? e x))) lst))
184
185 (define (delq x lst)
186   (filter (lambda (e) (not (eq? e x))) lst))
187
188 (define (compose proc . rest)
189   (if (null? rest) proc
190       (lambda args
191         (proc (apply (apply compose rest) args)))))
192
193 \f
194 ;; Vector
195 (define (vector . rest) (list->vector rest))
196 (define (make-vector n . x)
197   (if (null? x) (core:make-vector n)
198       (list->vector (apply make-list (cons n x)))))
199
200 (define (vector-copy x)
201   (list->vector (vector->list x)))
202
203 \f
204 ;;; Strings/srfi-13
205 (define (make-string n . fill)
206   (list->string (apply make-list n fill)))
207
208 (define (string-set! s k v)
209   (list->string (list-set! (string->list s) k v)))
210
211 (define (substring s start . rest)
212   (let* ((end (and (pair? rest) (car rest)))
213          (lst (list-tail (string->list s) start)))
214     (list->string (if (not end) lst
215                       (list-head lst (- end start))))))
216
217 (define (string-prefix? prefix string)
218   (let ((length (string-length string))
219         (prefix-length (string-length prefix)))
220   (and
221    (>= length prefix-length)
222    (equal? (substring string 0 prefix-length) prefix))))
223
224 (define (string-suffix? suffix string)
225   (let ((length (string-length string))
226         (suffix-length (string-length suffix)))
227     (and
228      (>= length suffix-length)
229      (equal? (substring string (- length suffix-length)) suffix))))
230
231 (define (string->number s . rest)
232   (if (string-prefix? "#x" s) (string->number (string-drop s 2) 16)
233       (let ((lst (string->list s)))
234         (and (pair? lst)
235              (let* ((radix (if (null? rest) 10 (car rest)))
236                     (sign (if (and (pair? lst) (char=? (car lst) #\-)) -1 1))
237                     (lst (if (= sign -1) (cdr lst) lst)))
238                (let loop ((lst lst) (n 0))
239                  (if (null? lst) (* sign n)
240                      (let ((i (char->integer (car lst))))
241                        (cond ((and (>= i (char->integer #\0))
242                                    (<= i (char->integer #\9)))
243                               (let ((d (char->integer #\0)))
244                                 (loop (cdr lst) (+ (* n radix) (- i d)))))
245                              ((and (= radix 16)
246                                    (>= i (char->integer #\a))
247                                    (<= i (char->integer #\f)))
248                               (let ((d (char->integer #\a)))
249                                 (loop (cdr lst) (+ (* n radix) (- i (- d 10))))))
250                              ((and (= radix 16)
251                                    (>= i (char->integer #\A))
252                                    (<= i (char->integer #\F)))
253                               (let ((d (char->integer #\A)))
254                                 (loop (cdr lst) (+ (* n radix) (- i (- d 10))))))
255                              ((= i (char->integer #\.)) ; minimal FLOAT support
256                               (let ((fraction (cdr lst)))
257                                 (if (null? fraction) n
258                                     (let ((fraction ((compose string->number list->string) fraction)))
259                                       (and fraction n))))) ; FLOAT as integer
260                              (else #f))))))))))
261
262 (define inexact->exact identity)
263
264 (define (number->string n . rest)
265   (let* ((radix (if (null? rest) 10 (car rest)))
266          (sign (if (< n 0) '(#\-) '())))
267     (let loop ((n (abs n)) (lst '()))
268       (let* ((i (abs (remainder n radix)))
269              (lst (cons (integer->char (+ i (if (< i 10) (char->integer #\0)
270                                                 (- (char->integer #\a) 10)))) lst))
271              (n (quotient n radix)))
272         (if (= 0 n) (list->string (append sign lst))
273             (loop n lst))))))
274
275 \f
276 ;;; Symbols
277 (define (symbol-prefix? prefix symbol)
278   (string-prefix? (symbol->string prefix) (symbol->string symbol)))
279
280 (define (symbol-append . rest)
281   (string->symbol (apply string-append (map symbol->string rest))))
282
283 (define gensym
284   (let ((counter 0))
285     (lambda (. rest)
286       (let ((value (number->string counter)))
287         (set! counter (+ counter 1))
288         (string->symbol (string-append "g" value))))))
289
290 \f
291 ;;; Keywords
292 (define (keyword->symbol s)
293   (string->symbol (keyword->string s)))
294
295 \f
296 ;;; Characters
297 (define (char=? x y)
298   (and (char? x) (char? y)
299        (eq? x y)))
300
301 (define (char<? a b) (< (char->integer a) (char->integer b)))
302 (define (char>? a b) (> (char->integer a) (char->integer b)))
303 (define (char<=? a b) (<= (char->integer a) (char->integer b)))
304 (define (char>=? a b) (>= (char->integer a) (char->integer b)))
305
306 (define (char-alphabetic? x)
307   (and (char? x)
308        (let ((i (char->integer x)))
309         (or (and (>= i (char->integer #\A)) (<= i (char->integer #\Z)))
310             (and (>= i (char->integer #\a)) (<= i (char->integer #\z)))))))
311
312 (define (char-numeric? x)
313   (and (char? x)
314        (let ((i (char->integer x)))
315          (and (>= i (char->integer #\0)) (<= i (char->integer #\9))))))
316
317 \f
318 ;;; Math
319 (define quotient /)
320
321 (define (<= . rest)
322   (or (apply < rest)
323       (apply = rest)))
324
325 (define (>= . rest)
326   (or (apply > rest)
327       (apply = rest)))
328
329 (define (remainder x y)
330   (- x (* (quotient x y) y)))
331
332 (define (even? x)
333   (= 0 (remainder x 2)))
334
335 (define (odd? x)
336   (= 1 (remainder x 2)))
337
338 (define (negative? x)
339   (< x 0))
340
341 (define (positive? x)
342   (> x 0))
343
344 (define (zero? x)
345   (= x 0))
346
347 (define (1+ x)
348   (+ x 1))
349
350 (define (1- x)
351   (- x 1))
352
353 (define (abs x)
354   (if (>= x 0) x (- x)))
355
356 (define (expt x y)
357   (let loop ((s 1) (count y))
358     (if (= 0 count) s
359         (loop (* s x) (- count 1)))))
360
361 (define (max x . rest)
362   (if (null? rest) x
363       (let ((y (car rest)))
364         (let ((z (if (> x y) x y)))
365           (apply max (cons z (cdr rest)))))))
366
367 (define (min x . rest)
368   (if (null? rest) x
369       (let ((y (car rest)))
370         (let ((z (if (< x y) x y)))
371           (apply min (cons z (cdr rest)))))))
372
373 (define (negate proc)
374   (lambda args
375     (not (apply proc args))))
376
377 (define ceil identity)
378 (define floor identity)
379 (define round identity)
380 (define inexact->exact identity)
381 (define exact->inexact identity)
382
383 (define (const . rest)
384   (lambda (. _)
385     (car rest)))