core: Add string-length.
[mes.git] / mes / module / mes / scm.mes
1 ;;; -*-scheme-*-
2
3 ;;; GNU Mes --- Maxwell Equations of Software
4 ;;; Copyright © 2016,2017,2018 Jan (janneke) Nieuwenhuizen <janneke@gnu.org>
5 ;;;
6 ;;; This file is part of GNU Mes.
7 ;;;
8 ;;; GNU Mes is free software; you can redistribute it and/or modify it
9 ;;; under the terms of the GNU General Public License as published by
10 ;;; the Free Software Foundation; either version 3 of the License, or (at
11 ;;; your option) any later version.
12 ;;;
13 ;;; GNU Mes is distributed in the hope that it will be useful, but
14 ;;; WITHOUT ANY WARRANTY; without even the implied warranty of
15 ;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
16 ;;; GNU General Public License for more details.
17 ;;;
18 ;;; You should have received a copy of the GNU General Public License
19 ;;; along with GNU Mes.  If not, see <http://www.gnu.org/licenses/>.
20
21 ;;; Commentary:
22
23 ;;; scm.mes is loaded after base, quasiquote and let.  It provides
24 ;;; basic Scheme functions bringing Mes close to basic RRS Scheme (no
25 ;;; labels, processes, fluids or throw/catch).
26
27 ;;; Code:
28
29 (mes-use-module (mes let))
30
31 (define (cadddr x) (car (cdddr x)))
32
33 (define-macro (case val . args)
34   (if (null? args) #f
35       (let ((clause (car args)))
36         (let ((pred (car clause)))
37           (let ((body (cdr clause)))
38            (if (pair? pred) `(if ,(if (null? (cdr pred))
39                                       `(eq? ,val ',(car pred))
40                                       `(member ,val ',pred))
41                                  (begin ,@body)
42                                  (case ,val ,@(cdr args)))
43                `(begin ,@body)))))))
44
45 (define-macro (when expr . body)
46   `(if ,expr
47        ((lambda () ,@body))))
48
49 (define-macro (unless expr . body)
50   `(if (not ,expr)
51        ((lambda () ,@body))))
52
53 (define-macro (do init test . body)
54   `(let loop ((,(caar init) ,(cadar init)))
55      (when (not ,@test)
56        ,@body
57        (loop ,@(cddar init)))))
58
59 (define (for-each f l . r)
60   (if (pair? l) (if (null? r) (begin (f (car l)) (for-each f (cdr l)))
61                     (if (null? (cdr r)) (begin (f (car l) (caar r)) (for-each f (cdr l) (cdar r)))))))
62
63 (define core:error error)
64
65 (define (error who . rest)
66   (display "error:" (current-error-port))
67   (display who (current-error-port))
68   (display ":" (current-error-port))
69   (display rest (current-error-port))
70   (newline (current-error-port))
71   (display "exiting...\n" (current-error-port))
72   (core:error (if (symbol? who) who 'error) (cons who rest)))
73
74 (define (syntax-error message . rest)
75   (display "syntax-error:" (current-error-port))
76   (display message (current-error-port))
77   (display ":" (current-error-port))
78   (display rest (current-error-port))
79   (newline (current-error-port))
80   (core:error 'syntax-error (cons message rest)))
81
82 \f
83 (define integer? number?)
84
85 (if (not (defined? 'peek-char))
86     (define (peek-char)
87       (integer->char (peek-byte))))
88
89 (if (not (defined? 'read-char))
90     (define (read-char)
91       (integer->char (read-byte))))
92
93 (if (not (defined? 'unread-char))
94     (define (unread-char c)
95       (integer->char (unread-byte (char->integer c)))))
96
97 (define (assq-set! alist key val)
98   (let ((entry (assq key alist)))
99     (if (not entry) (acons key val alist)
100         (let ((entry (set-cdr! entry val)))
101           alist))))
102
103 (define (assq-ref alist key)
104   (let ((entry (assq key alist)))
105     (if entry (cdr entry)
106         #f)))
107
108 (define assv assq)
109 (define assv-ref assq-ref)
110
111 (define (assoc-ref alist key)
112   (let ((entry (assoc key alist)))
113     (if entry (cdr entry)
114         #f)))
115
116 (define (assoc-set! alist key value)
117   (let ((entry (assoc key alist)))
118     (if (not entry) (acons key value alist)
119         (let ((entry (set-cdr! entry value)))
120           alist))))
121
122 (define memv memq)
123
124 (define (member x lst)
125   (if (null? lst) #f
126       (if (equal? x (car lst)) lst
127           (member x (cdr lst)))))
128
129 \f
130 ;;; Lists
131 (define (make-list n . x)
132   (let ((fill (if (pair? x) (car x) *unspecified*)))
133     (let loop ((n n))
134       (if (= 0 n) '()
135           (cons fill (loop (- n 1)))))))
136
137 (define (list-ref lst k)
138   (let loop ((lst lst) (k k))
139     (if (= 0 k) (car lst)
140         (loop (cdr lst) (- k 1)))))
141
142 (define (list-set! lst k v)
143   (let loop ((lst lst) (k k))
144     (if (= 0 k) (set-car! lst v)
145         (loop (cdr lst) (- k 1)))))
146
147 (define (list-head x n)
148   (if (= 0 n) '()
149       (cons (car x) (list-head (cdr x) (- n 1)))))
150
151 (define (list-tail x n)
152   (if (= 0 n) x
153       (list-tail (cdr x) (- n 1))))
154
155 (define (iota n)
156   (if (<= n 0) '()
157       (append2 (iota (- n 1)) (list (- n 1)))))
158
159 (define (reverse lst)
160   (let loop ((lst lst) (r '()))
161     (if (null? lst) r
162         (loop (cdr lst) (cons (car lst) r)))))
163
164 (define (filter pred lst)
165   (let loop ((lst lst))
166     (if (null? lst) '()
167         (if (pred (car lst))
168             (cons (car lst) (loop (cdr lst)))
169             (loop (cdr lst))))))
170
171 (define (delete x lst)
172   (filter (lambda (e) (not (equal? e x))) lst))
173
174 (define (delq x lst)
175   (filter (lambda (e) (not (eq? e x))) lst))
176
177 (define (compose proc . rest)
178   (if (null? rest) proc
179       (lambda args
180         (proc (apply (apply compose rest) args)))))
181
182 \f
183 ;; Vector
184 (define (vector . rest) (list->vector rest))
185 (define (make-vector n . x)
186   (if (null? x) (core:make-vector n)
187       (list->vector (apply make-list (cons n x)))))
188
189 (define (vector-copy x)
190   (list->vector (vector->list x)))
191
192 \f
193 ;;; Strings/srfi-13
194 (define (make-string n . fill)
195   (list->string (apply make-list n fill)))
196
197 (define (string-ref s k)
198   (list-ref (string->list s) k))
199
200 (define (string-set! s k v)
201   (list->string (list-set! (string->list s) k v)))
202
203 (define (substring s start . rest)
204   (let* ((end (and (pair? rest) (car rest)))
205          (lst (list-tail (string->list s) start)))
206     (list->string (if (not end) lst
207                       (list-head lst (- end start))))))
208
209 (define (string-prefix? prefix string)
210   (let ((length (string-length string))
211         (prefix-length (string-length prefix)))
212   (and
213    (>= length prefix-length)
214    (equal? (substring string 0 prefix-length) prefix))))
215
216 (define (string-suffix? suffix string)
217   (let ((length (string-length string))
218         (suffix-length (string-length suffix)))
219     (and
220      (>= length suffix-length)
221      (equal? (substring string (- length suffix-length)) suffix))))
222
223 (define (string->number s . rest)
224   (let ((lst (string->list s)))
225     (and (pair? lst)
226          (let* ((radix (if (null? rest) 10 (car rest)))
227                 (sign (if (and (pair? lst) (char=? (car lst) #\-)) -1 1))
228                 (lst (if (= sign -1) (cdr lst) lst)))
229            (let loop ((lst lst) (n 0))
230              (if (null? lst) (* sign n)
231                  (let ((i (char->integer (car lst))))
232                    (cond ((and (>= i (char->integer #\0))
233                                (<= i (char->integer #\9)))
234                           (let ((d (char->integer #\0)))
235                             (loop (cdr lst) (+ (* n radix) (- i d)))))
236                          ((and (= radix 16)
237                                (>= i (char->integer #\a))
238                                (<= i (char->integer #\f)))
239                           (let ((d (char->integer #\a)))
240                             (loop (cdr lst) (+ (* n radix) (- i (- d 10))))))
241                          ((and (= radix 16)
242                                (>= i (char->integer #\A))
243                                (<= i (char->integer #\F)))
244                           (let ((d (char->integer #\A)))
245                             (loop (cdr lst) (+ (* n radix) (- i (- d 10))))))
246                          ((= i (char->integer #\.)) ; minimal FLOAT support
247                           (let ((fraction (cdr lst)))
248                             (if (null? fraction) n
249                                 (let ((fraction ((compose string->number list->string) fraction)))
250                                   (and fraction n))))) ; FLOAT as integer
251                          (else #f)))))))))
252
253 (define inexact->exact identity)
254
255 (define (number->string n . rest)
256   (let* ((radix (if (null? rest) 10 (car rest)))
257          (sign (if (< n 0) '(#\-) '())))
258     (let loop ((n (abs n)) (lst '()))
259       (let* ((i (remainder n radix))
260              (lst (cons (integer->char (+ i (if (< i 10) (char->integer #\0)
261                                                 (- (char->integer #\a) 10)))) lst))
262              (n (quotient n radix)))
263         (if (= 0 n) (list->string (append sign lst))
264             (loop n lst))))))
265
266 \f
267 ;;; Symbols
268 (define (symbol-prefix? prefix symbol)
269   (string-prefix? (symbol->string prefix) (symbol->string symbol)))
270
271 (define (symbol-append . rest)
272   (string->symbol (apply string-append (map symbol->string rest))))
273
274 (define gensym
275   (let ((counter 0))
276     (lambda (. rest)
277       (let ((value (number->string counter)))
278         (set! counter (+ counter 1))
279         (string->symbol (string-append "g" value))))))
280
281 \f
282 ;;; Keywords
283 (define (keyword->symbol s)
284   (string->symbol (keyword->string s)))
285
286 \f
287 ;;; Characters
288 (define (char=? x y)
289   (and (char? x) (char? y)
290        (eq? x y)))
291
292 (define (char<? a b) (< (char->integer a) (char->integer b)))
293 (define (char>? a b) (> (char->integer a) (char->integer b)))
294 (define (char<=? a b) (<= (char->integer a) (char->integer b)))
295 (define (char>=? a b) (>= (char->integer a) (char->integer b)))
296
297 (define (char-alphabetic? x)
298   (and (char? x)
299        (let ((i (char->integer x)))
300         (or (and (>= i (char->integer #\A)) (<= i (char->integer #\Z)))
301             (and (>= i (char->integer #\a)) (<= i (char->integer #\z)))))))
302
303 (define (char-numeric? x)
304   (and (char? x)
305        (let ((i (char->integer x)))
306          (and (>= i (char->integer #\0)) (<= i (char->integer #\9))))))
307
308 \f
309 ;;; Math
310 (define quotient /)
311
312 (define (<= . rest)
313   (or (apply < rest)
314       (apply = rest)))
315
316 (define (>= . rest)
317   (or (apply > rest)
318       (apply = rest)))
319
320 (define (remainder x y)
321   (- x (* (quotient x y) y)))
322
323 (define (even? x)
324   (= 0 (remainder x 2)))
325
326 (define (odd? x)
327   (= 1 (remainder x 2)))
328
329 (define (negative? x)
330   (< x 0))
331
332 (define (positive? x)
333   (> x 0))
334
335 (define (zero? x)
336   (= x 0))
337
338 (define (1+ x)
339   (+ x 1))
340
341 (define (1- x)
342   (- x 1))
343
344 (define (abs x)
345   (if (>= x 0) x (- x)))
346
347 (define (expt x y)
348   (let loop ((s 1) (count y))
349     (if (= 0 count) s
350         (loop (* s x) (- count 1)))))
351
352 (define (max x . rest)
353   (if (null? rest) x
354       (let ((y (car rest)))
355         (let ((z (if (> x y) x y)))
356           (apply max (cons z (cdr rest)))))))
357
358 (define (min x . rest)
359   (if (null? rest) x
360       (let ((y (car rest)))
361         (let ((z (if (< x y) x y)))
362           (apply min (cons z (cdr rest)))))))
363
364 (define (negate proc)
365   (lambda args
366     (not (apply proc args))))
367
368 (define ceil identity)
369 (define floor identity)
370 (define round identity)
371 (define inexact->exact identity)
372 (define exact->inexact identity)
373
374 (define (const . rest)
375   (lambda (. _)
376     (car rest)))