build: Separate Mes and Guile modules.
[mes.git] / mes / module / mes / pmatch.scm
1 ;;; pmatch, a simple matcher
2
3 ;;; Copyright (C) 2009, 2010, 2012 Free Software Foundation, Inc
4 ;;; Copyright (C) 2005,2006,2007 Oleg Kiselyov
5 ;;; Copyright (C) 2007 Daniel P. Friedman
6 ;;; Copyright (C) 2018 Jan (janneke) Nieuwenhuizen <janneke@gnu.org>
7 ;;;
8 ;;; This library is free software; you can redistribute it and/or
9 ;;; modify it under the terms of the GNU Lesser General Public
10 ;;; License as published by the Free Software Foundation; either
11 ;;; version 3 of the License, or (at your option) any later version.
12 ;;;
13 ;;; This library is distributed in the hope that it will be useful,
14 ;;; but WITHOUT ANY WARRANTY; without even the implied warranty of
15 ;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
16 ;;; Lesser General Public License for more details.
17 ;;;
18 ;;; You should have received a copy of the GNU Lesser General Public
19 ;;; License along with this library; if not, write to the Free Software
20 ;;; Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301 USA
21
22 ;;; Originally written by Oleg Kiselyov for LeanTAP in Kanren, which is
23 ;;; available under the MIT license.
24 ;;;
25 ;;; http://kanren.cvs.sourceforge.net/viewvc/kanren/kanren/mini/leanTAP.scm?view=log
26 ;;;
27 ;;; This version taken from:
28 ;;; Î±Kanren: A Fresh Name in Nominal Logic Programming
29 ;;; by William E. Byrd and Daniel P. Friedman
30 ;;; Proceedings of the 2007 Workshop on Scheme and Functional Programming
31 ;;; UniversitĂ© Laval Technical Report DIUL-RT-0701
32
33 ;;; To be clear: the original code is MIT-licensed, and the modifications
34 ;;; made to it by Guile are under Guile's license (currently LGPL v3+).
35
36 ;;; Code:
37
38 ;; (pmatch exp <clause> ...[<else-clause>])
39 ;; <clause> ::= (<pattern> <guard> exp ...)
40 ;; <else-clause> ::= (else exp ...)
41 ;; <guard> ::= boolean exp | ()
42 ;; <pattern> :: =
43 ;;        ,var  -- matches always and binds the var
44 ;;                 pattern must be linear! No check is done
45 ;;         _    -- matches always
46 ;;        'exp  -- comparison with exp (using equal?)    REMOVED (August 8, 2012)
47 ;;        exp   -- comparison with exp (using equal?)
48 ;;        (<pattern1> <pattern2> ...) -- matches the list of patterns
49 ;;        (<pattern1> . <pattern2>)  -- ditto
50 ;;        ()    -- matches the empty list
51
52 (define-module (system base pmatch)
53   #:export-syntax (pmatch))
54
55 (define-syntax pmatch
56   (syntax-rules (else guard)
57     ((_ v) (if #f #f))
58     ((_ v (else e0 e ...)) (let () e0 e ...))
59     ((_ v (pat (guard g ...) e0 e ...) cs ...)
60      (let ((fk (lambda () (pmatch v cs ...))))
61        (ppat v pat
62              (if (and g ...) (let () e0 e ...) (fk))
63              (fk))))
64     ((_ v (pat e0 e ...) cs ...)
65      (let ((fk (lambda () (pmatch v cs ...))))
66        (ppat v pat (let () e0 e ...) (fk))))))
67
68 (define-syntax ppat
69   (syntax-rules (_ quote unquote)
70     ((_ v _ kt kf) kt)
71     ((_ v () kt kf) (if (null? v) kt kf))
72     ((_ v (quote lit) kt kf)
73      (if (equal? v (quote lit)) kt kf))
74     ((_ v (unquote var) kt kf) (let ((var v)) kt))
75     ((_ v (x . y) kt kf)
76      (if (pair? v)
77          (ppat (pmatch-car v) x (ppat (pmatch-cdr v) y kt kf) kf)
78          kf))
79     ((_ v lit kt kf) (if (eq? v (quote lit)) kt kf))))