guix.scm

   1 ;;; guix.scm -- Guix package definition
   2
   3 ;;; Mes --- Maxwell Equations of Software
   4 ;;; Copyright © 2016,2017,2018 Jan (janneke) Nieuwenhuizen <janneke@gnu.org>
   5
   6 ;;; Also borrowing code from:
   7 ;;; guile-sdl2 --- FFI bindings for SDL2
   8 ;;; Copyright © 2015 David Thompson <davet@gnu.org>
   9
  10 ;;;
  11 ;;; guix.scm: This file is part of Mes.
  12 ;;;
  13 ;;; Mes is free software; you can redistribute it and/or modify it
  14 ;;; under the terms of the GNU General Public License as published by
  15 ;;; the Free Software Foundation; either version 3 of the License, or (at
  16 ;;; your option) any later version.
  17 ;;;
  18 ;;; Mes is distributed in the hope that it will be useful, but
  19 ;;; WITHOUT ANY WARRANTY; without even the implied warranty of
  20 ;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  21 ;;; GNU General Public License for more details.
  22 ;;;
  23 ;;; You should have received a copy of the GNU General Public License
  24 ;;; along with Mes.  If not, see <http://www.gnu.org/licenses/>.
  25
  26 ;;; Commentary:
  27 ;;
  28 ;; GNU Guix development package.  To build and install, run:
  29 ;;
  30 ;;   guix package -f guix.scm
  31 ;;
  32 ;; To build it, but not install it, run:
  33 ;;
  34 ;;   guix build -f guix.scm
  35 ;;
  36 ;; To use as the basis for a development environment, run:
  37 ;;
  38 ;;   guix environment -l guix.scm
  39 ;;
  40 ;;; Code:
  41
  42 (use-modules (srfi srfi-1)
  43              (srfi srfi-26)
  44              (ice-9 match)
  45              (ice-9 popen)
  46              (ice-9 rdelim)
  47              (gnu packages)
  48              (gnu packages base)
  49              (gnu packages commencement)
  50              (gnu packages cross-base)
  51              (gnu packages gcc)
  52              (gnu packages guile)
  53              (gnu packages mes)
  54              (gnu packages package-management)
  55              (gnu packages perl)
  56              ((guix build utils) #:select (with-directory-excursion))
  57              (guix build-system gnu)
  58              (guix build-system trivial)
  59              (guix gexp)
  60              (guix download)
  61              (guix git-download)
  62              (guix licenses)
  63              (guix packages))
  64
  65 (define %source-dir (dirname (current-filename)))
  66
  67 (define git-file?
  68   (let* ((pipe (with-directory-excursion %source-dir
  69                  (open-pipe* OPEN_READ "git" "ls-files")))
  70          (files (let loop ((lines '()))
  71                   (match (read-line pipe)
  72                     ((? eof-object?)
  73                      (reverse lines))
  74                     (line
  75                      (loop (cons line lines))))))
  76          (status (close-pipe pipe)))
  77     (lambda (file stat)
  78       (match (stat:type stat)
  79         ('directory #t)
  80         ((or 'regular 'symlink)
  81          (any (cut string-suffix? <> file) files))
  82         (_ #f)))))
  83
  84 (define-public nyacc-for-mes
  85   (package
  86     (inherit nyacc)
  87     (version "0.80.42")
  88       (source (origin
  89                 (method url-fetch)
  90                 (uri (string-append "https://gitlab.com/janneke/nyacc"
  91                                     "/-/archive/v" version
  92                                     "/nyacc-" version ".tar.gz"))
  93                 (sha256
  94                  (base32
  95                   "0c8c8kxir0h2d4nxr131xbkfs7c80haipmkp2g6677sh14wn0b3y"))))))
  96
  97 (define-public mescc-tools
  98   (package
  99     (name "mescc-tools")
 100     (version "0.5.1")
 101     (source (origin
 102               (method url-fetch)
 103               (uri (string-append
 104                     "https://github.com/oriansj/mescc-tools/archive/Release_"
 105                     version
 106                     ".tar.gz"))
 107               (file-name (string-append name "-" version ".tar.gz"))
 108               (sha256
 109                (base32
 110                 "0rsxbjc3bg0jl3h7ai4hndxx2iyyk8bvwj9nd3xv2vgz3bmypnah"))))
 111     (build-system gnu-build-system)
 112     (supported-systems '("i686-linux" "x86_64-linux"))
 113     (arguments
 114      `(#:make-flags (list (string-append "PREFIX=" (assoc-ref %outputs "out")))
 115        #:test-target "test"
 116        #:phases (modify-phases %standard-phases
 117                   (delete 'configure))))
 118     (synopsis "Tools for the full source bootstrapping process")
 119     (description
 120      "Mescc-tools is a collection of tools for use in a full source
 121 bootstrapping process.  Currently consists of the M1 macro assembler and the
 122 hex2 linker.")
 123     (home-page "https://github.com/oriansj/mescc-tools")
 124     (license gpl3+)))
 125
 126 (define-public mes
 127   (let ((commit "f9a4e219727bedd504ea49885c3260c38755c1d0")
 128         (revision "0")
 129         (triplet "i686-unknown-linux-gnu")
 130         (version "0.16"))
 131     (package
 132       (name "mes")
 133       (version (string-append version "-" revision "." (string-take commit 7)))
 134       (source (origin
 135                 (method git-fetch)
 136                 (uri (git-reference
 137                       (url "https://gitlab.com/janneke/mes")
 138                       (commit commit)))
 139                 (file-name (string-append name "-" version))
 140                 (sha256
 141                  (base32 "0dsilpm9bzsz5cprvlxjf86xk7zhihr7vkm5svi5rjyavig0s644"))))
 142       (build-system gnu-build-system)
 143       (supported-systems '("i686-linux" "x86_64-linux"))
 144       (propagated-inputs
 145        `(("mescc-tools" ,mescc-tools)
 146          ("nyacc" ,nyacc-for-mes)))
 147       (native-inputs
 148        `(("guile" ,guile-2.2)
 149          ,@(if (string-prefix? "x86_64-linux" (or (%current-target-system)
 150                                                   (%current-system)))
 151                ;; Use cross-compiler rather than #:system "i686-linux" to get
 152                ;; MesCC 64 bit .go files installed ready for use with Guile.
 153                `(("i686-linux-binutils" ,(cross-binutils triplet))
 154                  ("i686-linux-gcc" ,(cross-gcc triplet)))
 155                '())
 156          ("perl" ,perl)))               ;build-aux/gitlog-to-changelog
 157       (arguments
 158        `(#:phases
 159          (modify-phases %standard-phases
 160            (add-before 'build 'make-git-source-writable
 161            (lambda* (#:key outputs #:allow-other-keys)
 162              (for-each make-file-writable
 163                        (find-files "." ".*\\.M1"))))
 164            (add-before 'install 'generate-changelog
 165              (lambda _
 166                (with-output-to-file "ChangeLog"
 167                  (lambda ()
 168                    (display "Please run
 169     build-aux/gitlog-to-changelog --srcdir=<git-checkout> > ChangeLog\n")))
 170                #t))
 171            (delete 'strip)))) ; binutil's strip b0rkes Mescc/M1/hex2 binaries
 172       (synopsis "Scheme interpreter and C compiler for full source bootstrapping")
 173       (description
 174        "Mes [Maxwell Equations of Software] aims to create full source
 175 bootstrapping for GuixSD.  It consists of a mutual self-hosting [close to
 176 Guile-] Scheme interpreter prototype in C and a Nyacc-based C compiler in
 177 [Guile] Scheme.")
 178       (home-page "https://gitlab.com/janneke/mes")
 179       (license gpl3+))))
 180
 181 (define-public mes.git
 182  (let ((version "0.16")
 183         (revision "0")
 184         (commit (read-string (open-pipe "git show HEAD | head -1 | cut -d ' ' -f 2" OPEN_READ))))
 185     (package
 186       (inherit mes)
 187       (name "mes.git")
 188       (version (string-append version "-" revision "." (string-take commit 7)))
 189       (source (local-file %source-dir #:recursive? #t #:select? git-file?)))))
 190
 191 ;; Return it here so `guix build/environment/package' can consume it directly.
 192 mes.git