ce372e8529257c36d74db5e35a4320bc06813d4b
[mes.git] / guile / mescc.scm
1 #! /bin/sh
2 # -*-scheme-*-
3 GODIR=${GODIR-@GODIR@}
4 GUILEDIR=${GUILEDIR-@GUILEDIR@}
5 [ "$GODIR" = @"GODIR"@ ] && GODIR=$(dirname $0)
6 [ "$GUILEDIR" = @"GUILEDIR"@ ] && GUILEDIR=$(dirname $0)
7 export GUILE_AUTO_COMPILE=${GUILE_AUTO_COMPILE-0}
8 GUILE_LOAD_COMPILED_PATH=$GODIR:$GUILE_LOAD_COMPILED_PATH
9 exec ${GUILE-guile} -L $GUILEDIR -e '(mescc)' -s "$0" "$@"
10 !#
11
12 ;;; Mes --- The Maxwell Equations of Software
13 ;;; Copyright © 2016,2017,2018 Jan Nieuwenhuizen <janneke@gnu.org>
14 ;;;
15 ;;; This file is part of GNU Guix.
16 ;;;
17 ;;; Mes is free software; you can redistribute it and/or modify it
18 ;;; under the terms of the GNU General Public License as published by
19 ;;; the Free Software Foundation; either version 3 of the License, or (at
20 ;;; your option) any later version.
21 ;;;
22 ;;; Mes is distributed in the hope that it will be useful, but
23 ;;; WITHOUT ANY WARRANTY; without even the implied warranty of
24 ;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
25 ;;; GNU General Public License for more details.
26 ;;;
27 ;;; You should have received a copy of the GNU General Public License
28 ;;; along with Mes.  If not, see <http://www.gnu.org/licenses/>.
29
30 ;; The Maxwell Equations of Software -- John McCarthy page 13
31 ;; http://www.softwarepreservation.org/projects/LISP/book/LISP%201.5%20Programmers%20Manual.pdf
32
33 #!
34 Run with Guile-1.8:
35 GUILE='~/src/guile-1.8/build/pre-inst-guile --debug -q' guile/mescc.scm
36 !#
37
38 (define-module (mescc)
39   #:use-module (language c99 info)
40   #:use-module (language c99 compiler)
41   #:use-module (mes elf)
42   #:use-module (mes M1)
43   #:use-module (ice-9 getopt-long)
44   #:use-module (ice-9 pretty-print)
45   #:use-module (srfi srfi-1)
46   #:use-module (srfi srfi-26)
47   #:export (main))
48
49 (cond-expand
50  (guile-2)
51  (guile
52   (use-modules (ice-9 syncase))))
53
54 (define %prefix (if (string-prefix? "@PREFIX" "@PREFIX@") (or (getenv "MES_PREFIX") "") "@PREFIX@"))
55 (module-define! (resolve-module '(language c99 compiler)) '%prefix %prefix)
56
57 (define (parse-opts args)
58   (let* ((option-spec
59           '((c (single-char #\c))
60             (define (single-char #\D) (value #t))
61             (E (single-char #\E))
62             (g (single-char #\g))
63             (help (single-char #\h))
64             (include (single-char #\I) (value #t))
65             (o (single-char #\o) (value #t))
66             (version (single-char #\V) (value #t))))
67          (options (getopt-long args option-spec))
68          (help? (option-ref options 'help #f))
69          (files (option-ref options '() '()))
70          (usage? (and (not help?) (null? files)))
71          (version? (option-ref options 'version #f)))
72     (or
73      (and version?
74           (format (current-output-port) "mescc.scm (mes) ~a\n" %version))
75      (and (or help? usage?)
76           (format (or (and usage? (current-error-port)) (current-output-port)) "\
77 Usage: mescc.scm [OPTION]... FILE...
78   -c                 compile and assemble, but do not link
79   -D DEFINE          define DEFINE
80   -E                 preprocess only; do not compile, assemble or link
81   -g                 add debug info [GDB, objdump] TODO: hex2 footer
82   -h, --help         display this help and exit
83   -I DIR             append DIR to include path
84   -o FILE            write output to FILE
85   -v, --version      display version and exit
86 ")
87           (exit (or (and usage? 2) 0)))
88      options)))
89
90 (define (read-object file)
91   (let ((char (with-input-from-file file read-char)))
92     (if (eq? char #\#) (error "hex2 format not supported:" file)))
93   (with-input-from-file file read))
94
95 (define (main:ast->info file)
96   (let ((ast (with-input-from-file file read)))
97     (c99-ast->info ast)))
98
99 (define (source->ast defines includes)
100   (lambda (file)
101     (with-input-from-file file
102       (lambda ()
103         (pretty-print (c99-input->ast #:defines defines #:includes includes))))))
104
105 (define (source->info defines includes)
106   (lambda (file)
107     (with-input-from-file file
108       (lambda ()
109         ((c99-input->info #:defines defines #:includes includes))))))
110
111 (define (ast? o)
112   (or (string-suffix? ".E" o)
113       (string-suffix? ".guile-E" o)))
114
115 (define (object? o)
116   (or (string-suffix? ".o" o)
117       (string-suffix? ".guile-o" o)))
118
119 (define (main args)
120   (let* ((options (parse-opts args))
121          (files (option-ref options '() '()))
122          (file (car files))
123          (preprocess? (option-ref options 'E #f))
124          (compile? (option-ref options 'c #f))
125          (debug-info? (option-ref options 'g #f))
126          (asts (filter ast? files))
127          (objects (filter object? files))
128          (sources (filter (cut string-suffix? ".c" <>) files))
129          (base (substring file (1+ (or (string-rindex file #\/) -1)) (- (string-length file) 2)))
130          (out (option-ref options 'o (cond (compile? (string-append base ".o"))
131                                            (preprocess? (string-append base ".E"))
132                                            (else "a.out"))))
133          (multi-opt (lambda (option) (lambda (o) (and (eq? (car o) option) (cdr o)))))
134          (defines (reverse (filter-map (multi-opt 'define) options)))
135          (includes (reverse (filter-map (multi-opt 'include) options))))
136     (when (getenv "MES_DEBUG") (format (current-error-port) "options=~s\n" options)
137           (format (current-error-port) "output: ~a\n" out))
138     (if (and (pair? sources) (pair? objects)) (error "cannot mix source and object files:" files))
139     (with-output-to-file out
140       (lambda ()
141         (if (and (not compile?)
142                  (not preprocess?)) (set-port-encoding! (current-output-port) "ISO-8859-1"))
143         (cond ((pair? objects) (let ((objects (map read-object objects)))
144                                  (if compile? (objects->M1 objects)
145                                      (objects->elf objects))))
146               ((pair? asts) (let* ((infos (map main:ast->info asts))
147                                    (objects (map info->object infos)))
148                               (if compile? (objects->M1 objects)
149                                   (objects->elf objects))))
150               ((pair? sources) (if preprocess? (map (source->ast defines includes) sources)
151                                    (let* ((infos (map (source->info defines includes) sources))
152                                           (objects (map info->object infos)))
153                                      (if compile? (objects->M1 objects)
154                                          (objects->elf objects))))))))
155     (if (and (not compile?)
156              (not preprocess?))
157         (chmod out #o755))))