Resurrect Mes in Guile.
[mes.git] / guile / mes.mes
1 ;;; -*-scheme-*-
2
3 ;;; Mes --- Maxwell Equations of Software
4 ;;; Copyright © 2016 Jan Nieuwenhuizen <janneke@gnu.org>
5 ;;;
6 ;;; mes.mes: This file is part of Mes.
7 ;;;
8 ;;; Mes is free software; you can redistribute it and/or modify it
9 ;;; under the terms of the GNU General Public License as published by
10 ;;; the Free Software Foundation; either version 3 of the License, or (at
11 ;;; your option) any later version.
12 ;;;
13 ;;; Mes is distributed in the hope that it will be useful, but
14 ;;; WITHOUT ANY WARRANTY; without even the implied warranty of
15 ;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
16 ;;; GNU General Public License for more details.
17 ;;;
18 ;;; You should have received a copy of the GNU General Public License
19 ;;; along with Mes.  If not, see <http://www.gnu.org/licenses/>.
20
21 ;; The Maxwell Equations of Software -- John McCarthy page 13
22 ;; http://www.softwarepreservation.org/projects/LISP/book/LISP%201.5%20Programmers%20Manual.pdf
23
24 (define (caar x) (car (car x)))
25 (define (cadr x) (car (cdr x)))
26 (define (cdar x) (cdr (car x)))
27 (define (cddr x) (cdr (cdr x)))
28 (define (caadr x) (car (car (cdr x))))
29 (define (caddr x) (car (cdr (cdr x))))
30 (define (cddar x) (cdr (cdr (car x))))
31 (define (cdadr x) (cdr (car (cdr x))))
32 (define (cadar x) (car (cdr (car x))))
33 (define (cdddr x) (cdr (cdr (cdr x))))
34
35 ;; Page 12
36 (define (pairlis x y a)
37   (cond
38    ((null? x) a)
39    ((atom? x) (cons (cons x y) a))
40    (#t (cons (cons (car x) (car y))
41              (pairlis (cdr x) (cdr y) a)))))
42
43 (define (assq x a)
44   (cond
45    ((null? a) #f)
46    ((eq? (caar a) x) (car a))
47    (#t (assq x (cdr a)))))
48
49 ;; Page 13
50 (define (evcon c a)
51   (cond
52    ((null? c) *unspecified*)
53    ;; single-statement cond
54    ;; ((eval (caar c) a) (eval (cadar c) a))
55    ((eval (caar c) a)
56     (cond ((null? (cddar c)) (eval (cadar c) a))
57           (#t (eval (cadar c) a)
58               (evcon
59                (cons (cons #t (cddar c)) '())
60                a))))
61    (#t (evcon (cdr c) a))))
62
63 (define (evlis m a)
64   (cond
65    ((null? m) '())
66    (#t (cons (eval (car m) a) (evlis (cdr m) a)))))
67
68
69 (define (apply-env fn x a) 
70   (cond
71    ((atom? fn)
72     (cond
73      ((eq? fn 'current-module)
74       (c:apply-env current-module '() a))
75      ((eq? fn 'call-with-values)
76       (c:apply-env 'call-with-values x a))
77      ((builtin? fn)
78       (call fn x))
79      (#t (apply-env (eval fn a) x a))))
80    ((eq? (car fn) 'lambda)
81     (begin-env (cddr fn) (pairlis (cadr fn) x a)))
82    ((eq? (car fn) 'label) (apply-env (caddr fn) x (cons (cons (cadr fn)
83                                                          (caddr fn)) a)))))
84
85 (define (begin-env body a)
86   (cond ((null? body) *unspecified*)
87         ((null? (cdr body)) (eval (car body) a))
88         (#t (eval (car body) a)
89             (begin-env (cdr body) a))))
90
91 (define (set-env! x e a)
92   (set-cdr! (assq x a) e))
93
94 (define (eval e a)
95   (cond
96    ((eq? e #t) #t)
97    ((eq? e #f) #f)
98    ((char? e) e)
99    ((number? e) e)
100    ((string? e) e)
101    ((vector? e) e)
102    ((atom? e) (cdr (assq e a)))
103    ((builtin? e) e)
104    ((atom? (car e))
105     (cond
106      ((eq? (car e) 'quote) (cadr e))
107      ((eq? (car e) 'begin) (begin-env (cdr e) a))
108      ((eq? (car e) 'lambda) e)
109      ((eq? (car e) 'set!) (set-env! (cadr e) (caddr e) a))
110      ((eq? (car e) 'unquote) (eval (cadr e) a))
111      ((eq? (car e) 'quasiquote) (eval-quasiquote (cadr e) a))
112      ((eq? (car e) 'cond) (evcon (cdr e) a))
113      ((pair? (assq (car e) (cdr (assq '*macro* a))))
114       (c:eval
115        (c:apply-env
116         (cdr (assq (car e) (cdr (assq '*macro* a))))
117         (cdr e)
118         a)
119        a))
120      (#t (apply-env (car e) (evlis (cdr e) a) a))))
121    (#t (apply-env (car e) (evlis (cdr e) a) a))))
122
123 (define (eval-quasiquote e a)
124   (cond ((null? e) e)
125         ((atom? e) e)
126         ((atom? (car e)) (cons (car e) (eval-quasiquote (cdr e) a)))
127         ((eq? (caar e) 'unquote) (cons (eval (cadar e) a) '()))
128         ((eq? (caar e) 'quote) (cons (cadar e) '()))
129         ((eq? (caar e) 'quasiquote) (cons (cadar e) '()))
130         (#t (cons (car e) (eval-quasiquote (cdr e) a)))))
131
132 (define (readenv a)
133   (readword (read-byte) '() a))
134
135 (define (readword c w a)
136   (cond ((eq? c -1) ;; eof
137          (cond ((eq? w '()) '())
138                (#t (lookup w a))))
139         ((eq? c 10) ;; \n
140          (cond ((eq? w '()) (readword (read-byte) w a))
141                ;; DOT ((eq? w '(*dot*)) (car (readword (read-byte) '() a)))
142                (#t (lookup w a))))
143         ((eq? c 32) ;; \space
144          (readword 10 w a))
145         ((eq? c 40) ;; (
146          (cond ((eq? w '()) (readlist a))
147                (#t (unread-byte c) (lookup w a))))
148         ((eq? c 41) ;; )
149          (cond ((eq? w '()) (unread-byte c) w)
150                (#t (unread-byte c) (lookup w a))))
151         ((eq? c 39) ;; '
152          (cond ((eq? w '())
153                 (cons (lookup (cons c '()) a)
154                       (cons (readword (read-byte) w a) '())))
155                (#t (unread-byte c) (lookup w a))))
156         ((eq? c 59) ;; ;
157          (readcomment c)
158          (readword 10 w a))
159         ((eq? c 35) ;; #
160          (cond ((eq? (peek-byte) 33) ;; !
161                 (read-byte)
162                 (readblock (read-byte))
163                 (readword 10 w a))
164                ;; TODO: char, vector
165                (#t (readword (read-byte) (append2 w (cons c '())) a))))
166         (#t (readword (read-byte) (append2 w (cons c '())) a))))
167
168 (define (readblock c)
169   (cond ((eq? c 33) (cond ((eq? (peek-byte) 35) (read-byte))
170                          (#t (readblock (read-byte)))))
171         (#t (readblock (read-byte)))))
172
173 (define (eat-whitespace)
174   (cond ((eq? (peek-byte) 10) (read-byte) (eat-whitespace))
175         ((eq? (peek-byte) 32) (read-byte) (eat-whitespace))
176         ((eq? (peek-byte) 35) (read-byte) (eat-whitespace))
177         (#t #t)))
178
179 (define (readlist a)
180   (eat-whitespace)
181   (cond ((eq? (peek-byte) 41) ;; )
182          (read-byte)
183          '())
184         ;; TODO *dot*
185         (#t (cons (readword (read-byte) '() a) (readlist a)))))
186
187 (define (readcomment c)
188   (cond ((eq? c 10) ;; \n
189          c)
190         (#t (readcomment (read-byte)))))