dc5362f95731dc06b42e75b4df3d5a64f07d217d
[mes.git] / guile / guix / make.scm
1 ;;; -*-scheme-*-
2
3 ;;; Mes --- Maxwell Equations of Software
4 ;;; Copyright © 2017 Jan Nieuwenhuizen <janneke@gnu.org>
5 ;;;
6 ;;; This file is part of Mes.
7 ;;;
8 ;;; Mes is free software; you can redistribute it and/or modify it
9 ;;; under the terms of the GNU General Public License as published by
10 ;;; the Free Software Foundation; either version 3 of the License, or (at
11 ;;; your option) any later version.
12 ;;;
13 ;;; Mes is distributed in the hope that it will be useful, but
14 ;;; WITHOUT ANY WARRANTY; without even the implied warranty of
15 ;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
16 ;;; GNU General Public License for more details.
17 ;;;
18 ;;; You should have received a copy of the GNU General Public License
19 ;;; along with Mes.  If not, see <http://www.gnu.org/licenses/>.
20
21 ;;; Commentary:
22
23 ;;; make
24
25 ;;; Code:
26
27 (define-module (guix make)
28   #:use-module (ice-9 curried-definitions)
29   #:use-module (ice-9 format)
30   #:use-module (ice-9 optargs)
31   #:use-module (ice-9 popen)
32   #:use-module (ice-9 pretty-print)
33   #:use-module (ice-9 rdelim)
34   #:use-module (ice-9 receive)
35
36   #:use-module (srfi srfi-1)
37   #:use-module (srfi srfi-26)
38
39   #:use-module (guix records)
40   #:use-module (guix shell-utils)
41
42   #:export (build
43             check
44             clean
45
46             cpp.mescc
47             compile.mescc
48             ld
49
50             bin.mescc
51             bin.gcc
52             snarf
53
54             libc-mes.E
55             mini-libc-mes.E
56             add-target
57             get-target
58
59             system**
60             target-file-name
61
62             target
63             %targets
64             %status))
65
66 (define %status 0)
67 (define %targets '())
68 (define %store-dir ".store")
69 (mkdir-p %store-dir)
70 (define %command-log (open-output-file "script"))
71
72 (define (base-name file-name suffix)
73   (string-drop-right file-name (string-length suffix)))
74
75 (define (system** . command)
76   (format %command-log "~a\n" (string-join command " "))
77   (apply system* command))
78
79 (define (gulp-pipe* . command)
80   (let* ((port (apply open-pipe* (cons OPEN_READ command)))
81          (foo (set-port-encoding! port "ISO-8859-1"))
82          (output (read-string port))
83          (status (close-pipe port)))
84     (format %command-log "~a\n" (string-join command " "))
85     (values output status)))
86
87 (define (assert-gulp-pipe* . command)
88   (receive (output status)
89       (apply gulp-pipe* command)
90     (if (zero? status) (string-trim-right output #\newline)
91         (error (format #f "pipe failed: ~d ~s"
92                        (or (status:exit-val status)
93                            (status:term-sig status)) command)))))
94
95 (define-record-type* <method>
96   method make-method
97   method?
98   (name       method-name)
99   (build      method-build (default (lambda _ #t)))
100   (inputs     method-inputs (default (list))))
101
102 (define-record-type* <target>
103   target make-target
104   target?
105   (file-name  target-file-name (default #f))       ; string
106   (file-names target-file-names (default '()))     ; (string)
107   (hash       target-hash (default #f))            ; string
108   (method     target-method (default method-file)) ; <method>
109   (inputs     target-inputs (default (list)))      ; list
110                                                    ; For check targets
111   (exit       target-exit (default #f))            ; number
112   (signal     target-signal (default #f)))         ; number
113
114 (define method-file (method (name "FILE")))
115 (define method-check
116   (method (name "CHECK")
117           (build (lambda (o t)
118                    (let* ((inputs (target-inputs t))
119                           (file-name (target-file-name (build (car inputs))))
120                           (run file-name)
121                           (exit (target-exit t))
122                           (signal (target-signal t))
123                           (log (string-append file-name "-check.log")))
124                      (format (current-error-port) "  CHECK\t~a" (basename file-name))
125                      (receive (output result)
126                          ;; FIXME: quiet MES tests are not fun
127                          (if (string-prefix? "tests/" run) (values #f (system** run))
128                              (gulp-pipe* run))
129                        (let ((status (if (string? result) 0
130                                          (or (status:term-sig result) (status:exit-val result)))))
131                          (if output (with-output-to-file log (lambda _ (display output))))
132                          (store #:add-file log)
133                          (format (current-error-port) "\t[~a]\n"
134                                  (if (or (and signal (= status signal))
135                                          (and exit (= status exit))) "OK"
136                                          (begin (set! %status 1) "FAIL"))))))))))
137
138 (define (hash-target o)
139   (let ((inputs (target-inputs o)))
140     (if (null? inputs) (or (target-hash o) (target-hash (store #:add o)))
141         (let ((input-shas (map hash-target inputs)))
142           (and (every identity input-shas)
143                (let ((method (target-method o)))
144                  (string-hash (format #f "~s" (cons* (target-file-name o)
145                                                      (method-build method)
146                                                      (map target-hash (method-inputs method))
147                                                      input-shas)))))))))
148
149 (define (string-hash o)
150   (number->string (hash o (expt 2 63))))
151
152 (define (file-hash o)
153   (string-hash (with-input-from-file o read-string)))
154
155 (define (store-file-name o)
156   (string-append %store-dir "/" (if (string? o) o
157                                     (target-hash o))))
158
159 (define (assert-link existing-file new-file)
160   (if (not (file-exists? new-file)) (link existing-file new-file)))
161
162 (define store
163   (let ((*store* '()))
164     (define (prune? o)
165       (let ((t (cdr o)))
166         (pair? (target-inputs t))))
167     (define ((file-name? file-name) o)
168       (let ((t (cdr o)))
169         (equal? (target-file-name t) (target-file-name file-name))))
170     (lambda* (#:key add add-file delete get key print prune)
171       (cond ((and add key) (let ((value (target (inherit add) (hash key))))
172                              (set! *store* (assoc-set! (filter (negate (file-name? add)) *store*) key value))
173                              (let ((file-name (target-file-name value)))
174                                (if (and file-name (file-exists? file-name))
175                                    (assert-link file-name (store-file-name value))))
176                              value))
177             (add (let ((key (if (null? (target-inputs add)) (file-hash (target-file-name add))
178                                 (hash-target add))))
179                    (if (not key) (error "store: no hash for:" add))
180                    (store #:add add #:key key)))
181             (add-file (and (file-exists? add-file)
182                            (store #:add (target (file-name add-file)))))
183             ((and get key)
184              (or (assoc-ref *store* key)
185                  (let ((store-file (store-file-name key))
186                        (file-name (target-file-name get)))
187                    (and (file-exists? store-file)
188                         (if (file-exists? file-name) (delete-file file-name))
189                         (link store-file file-name)
190                         (store #:add get #:key key)))))
191             (get (assoc-ref *store* get))
192             (delete (and (assoc-ref *store* delete)
193                          (set! *store* (filter (lambda (e) (not (equal? (car e) delete))) *store*))))
194             (print (pretty-print (map (lambda (e) (cons (target-file-name (cdr e)) (car e))) *store*)))
195             ((eq? prune 'file-system)
196              (set! *store* (filter prune? *store*)))
197             (else (error "store: dunno"))))))
198
199 (define (build o)
200   (let ((hash (hash-target o)))
201     (or (and hash (store #:get o #:key hash))
202         (begin
203           ;;(format (current-error-port) "must rebuild hash=~s\n" hash)
204           (for-each build (target-inputs o))
205           (let ((method (target-method o)))
206             ((method-build method) method o))
207           (store #:add o #:key hash)))))
208
209 (define* (check name #:key (exit 0) (signal #f) (dependencies '()))
210   (target (file-name (string-append "check-" name))
211                          (method method-check)
212                          (inputs (cons (get-target name) dependencies))
213                          (exit exit)
214                          (signal signal)))
215
216 (define (target->input-files o)
217   (let ((inputs (target-inputs o)))
218     (if (null? inputs) '()
219         (append (cons (target-file-name o) (target-file-names o)) (append-map target->input-files inputs)))))
220
221 (define* (clean #:optional targets)
222   (for-each
223    delete-file
224    (filter file-exists? (delete-duplicates (append-map (cut target->input-files <>) (or targets %targets))))))
225
226 (define (tree o)
227   (let ((inputs (target-inputs o)))
228     (if (null? inputs) o
229         (cons o (append (map tree inputs) (map tree (method-inputs (target-method o))))))))
230
231
232 (define (verbose fmt . o)
233   ;;(apply format (cons* (current-error-port) fmt o))
234   #t
235   )
236
237 (define (PATH-search-path name)
238   (or (search-path (string-split (getenv "PATH") #\:) name)
239       (and (format (current-error-port) "warning: not found: ~a\n" name)
240            name)))
241
242 (define %CC (PATH-search-path "gcc"))
243 (define %CC32 (PATH-search-path "i686-unknown-linux-gnu-gcc"))
244 (define %C-FLAGS
245   '("--std=gnu99"
246     "-O0"
247     "-g"
248     "-D"
249     "POSIX=1"
250     "-I" "src"
251     "-I" "mlibc/include"
252     "--include=mlibc/libc-gcc.c"
253     ))
254 (define %C32-FLAGS
255   '("--std=gnu99"
256     "-O0"
257     "-g"
258     "-I" "src"
259     "-I" "mlibc/include"
260     "--include=mlibc/libc-gcc.c"
261     ))
262
263 (define* (CC.gcc #:key (libc #t) (cc (if libc %CC %CC32)) (c-flags (if libc %C-FLAGS %C32-FLAGS)) (defines '()))
264   (method (name "CC.gcc")
265           (build (lambda (o t)
266                    (let* ((input-files (map target-file-name (target-inputs t)))
267                           (command `(,cc
268                                      "-c"
269                                      ,@(append-map (cut list "-D" <>) defines)
270                                      ,@(if libc '() '("-nostdinc" "-fno-builtin"))
271                                      ,@c-flags
272                                      "-o" ,(target-file-name t)
273                                      ,@input-files)))
274                      (format (current-error-port) "  ~a\t ~a -> ~a\n" (method-name o) (string-join input-files) (target-file-name t))
275                      (unless (zero? (apply system** command))
276                        (format (current-error-port) "FAILED:~s\n" command)
277                        (exit 1)))))
278           (inputs (list (store #:add-file "mlibc/libc-gcc.c"))))) ;; FIXME: FLAGS
279
280 (define* (CPP.mescc #:key (cc %MESCC) (defines '()))
281   (method (name "CPP.mescc")
282           (build (lambda (o t)
283                    (let ((input-files (map target-file-name (target-inputs t))))
284                      (format #t "  ~a\t ~a -> ~a\n" (method-name o) (string-join input-files) (target-file-name t))
285                      (apply system**
286                             `(,cc
287                               "-E"
288                               ,@(append-map (cut list "-D" <>) defines)
289                               "-o" ,(target-file-name t)
290                               ,@input-files)))))))
291
292 (define %MESCC "guile/mescc.scm")
293 (define* (CC.mescc #:key (cc %MESCC))
294   (method (name "CC.mescc")
295           (build (lambda (o t)
296                    (let ((input-files (map target-file-name (target-inputs t))))
297                      (format #t "  ~a\t ~a -> ~a\n" (method-name o) (string-join input-files) (target-file-name t))
298                      (apply system**
299                             `("guile/mescc.scm" "-c"
300                               "-o" ,(target-file-name t)
301                               ,@input-files)))))
302           (inputs (list (store #:add-file "guile/language/c99/compiler.go")
303                         (store #:add-file "guile/mes/as.go")
304                         (store #:add-file "guile/mes/as-i386.go")
305                         (store #:add-file "guile/mes/M1.go")))))
306
307 (define %M1 (PATH-search-path "M1"))
308 (define %M1-FLAGS
309   '("--LittleEndian"
310     "--Architecture=1"
311     ;;"--BaseAddress=0x1000000"
312     ))
313 (define* (M1.asm #:key (m1 %M1) (m1-flags %M1-FLAGS))
314   (method (name "M1")
315           (build (lambda (o t)
316                    (let* ((input-files (map target-file-name (target-inputs t)))
317                           (input-files (filter (lambda (f) (string-suffix? "M1" f))
318                                                input-files)))
319                      (format #t "  ~a\t ~a -> ~a\n" (method-name o) (string-join input-files) (target-file-name t))
320                      (with-output-to-file (target-file-name t)
321                        (lambda _
322                          (display
323                           (apply assert-gulp-pipe*
324                                  `(,m1
325                                    "-f"
326                                    "stage0/x86.M1"
327                                    ,@(append-map (cut list "-f" <>) input-files)
328                                    ,@m1-flags)))
329                          (newline))))))
330           (inputs (list (store #:add-file "stage0/x86.M1")))))
331
332 (define %HEX2-FLAGS
333   '("--LittleEndian"
334     "--Architecture=1"
335     "--BaseAddress=0x1000000"))
336 (define %HEX2 (PATH-search-path "hex2"))
337
338 (define* (LINK.hex2 #:key (hex2 %HEX2) (hex2-flags %HEX2-FLAGS) debug?)
339   (method (name "LINK.hex2")
340           (build (lambda (o t)
341                    (let* ((input-files (map target-file-name (target-inputs t)))
342                           ;; FIXME: snarf inputs
343                           (input-files (filter (lambda (f) (string-suffix? "hex2" f))
344                                                input-files)))
345                      (format #t "  ~a\t ~a -> ~a\n" (method-name o) (string-join input-files) (target-file-name t))
346                      (with-output-to-file (target-file-name t)
347                        (lambda _
348                          (set-port-encoding! (current-output-port) "ISO-8859-1")
349                          (display
350                           (apply assert-gulp-pipe*
351                                  `(,hex2
352                                    ,@hex2-flags
353                                    "-f"
354                                    ,(if (not debug?) "stage0/elf32-0header.hex2"
355                                         "stage0/elf32-header.hex2")
356                                    ,@(append-map (cut list "-f" <>) input-files)
357                                    "-f"
358                                    ,(if (not debug?) "stage0/elf-0footer.hex2"
359                                         "stage0/elf32-footer-single-main.hex2"))))))
360                      (chmod (target-file-name t) #o755))))
361           (inputs (list (store #:add-file "stage0/elf32-0header.hex2")
362                         (store #:add-file "stage0/elf-0footer.hex2")))))
363
364 (define* (LINK.gcc #:key (cc %CC) (c-flags %C-FLAGS) (libc #t))
365   (method (name "LINK.gcc")
366           (build (lambda (o t)
367                    (let* ((input-files (map target-file-name (target-inputs t)))
368                           (command `(,cc
369                                      ,@c-flags
370                                      ,@(if libc '() '("-nostdlib"))
371                                      "-o"
372                                      ,(target-file-name t)
373                                      ,@input-files)))
374                      (format #t "  ~a\t ~a -> ~a\n" (method-name o) (string-join input-files) (target-file-name t))
375                      (unless (zero? (apply system** command))
376                        (format (current-error-port) "FAILED:~s\n" command)
377                        (exit 1)))))))
378
379 (define SNARF "build-aux/mes-snarf.scm")
380 (define (SNARF.mes mes?)
381   (method (name "SNARF.mes")
382           (build (lambda (o t)
383                    (let* ((input-files (map target-file-name (target-inputs t)))
384                           (command `(,SNARF
385                                      ,@(if mes? '("--mes") '())
386                                      ,@input-files)))
387                      (format #t "  ~a\t ~a -> ~a\n" (method-name o) (string-join input-files) (target-file-name t))
388                      (unless (zero? (apply system** command))
389                        (format (current-error-port) "FAILED:~s\n" command)
390                        (exit 1)))))))
391
392 (define* (cpp.mescc input-file-name #:key (cc %MESCC) (defines '()))
393   (let* ((c-target (target (file-name input-file-name)))
394          (base-name (base-name input-file-name ".c"))
395          (suffix ".E")
396          (target-file-name (string-append base-name suffix)))
397     (target (file-name target-file-name)
398             (inputs (list c-target))
399             (method (CPP.mescc #:cc cc #:defines defines)))))
400
401 (define mini-libc-mes.E (cpp.mescc "mlibc/mini-libc-mes.c"))
402 (define libc-mes.E (cpp.mescc "mlibc/libc-mes.c"))
403
404 (define* (compile.gcc input-file-name #:key (libc #t) (cc (if libc %CC %CC32)) (defines '()))
405   (let* ((base-name (base-name input-file-name ".c"))
406          (cross (if libc "" "mlibc-"))
407          (suffix (string-append "." cross "o"))
408          (target-file-name (string-append base-name suffix))
409          (c-target (target (file-name input-file-name))))
410     (target (file-name target-file-name)
411             (inputs (list c-target))
412             (method (CC.gcc #:cc cc #:libc libc #:defines defines)))))
413
414 (define* (compile.mescc input-file-name #:key (cc %CC) (libc libc-mes.E) (defines '()))
415   (let* ((base-name (base-name input-file-name ".c"))
416          ;;(foo (format (current-error-port) "COMPILE[~s .c] base=~s\n" input-file-name base-name))
417          (suffix (cond ((not libc) ".0-M1")
418                        ((eq? libc libc-mes.E) ".M1")
419                        (else ".mini-M1")))
420          (target-file-name (string-append base-name suffix))
421          (E-target (cpp.mescc input-file-name #:cc cc #:defines defines)))
422     (target (file-name target-file-name)
423             (inputs `(,@(if libc (list libc) '()) ,E-target))
424             (method (CC.mescc #:cc cc)))))
425
426 (define* (m1-asm input-file-name #:key (cc %MESCC) (m1 %M1) (libc libc-mes.E) (defines '()))
427   (let* ((base-name (base-name input-file-name ".c"))
428          ;;(foo (format (current-error-port) "m1-asm[~s .m1] base=~s\n" input-file-name base-name))
429          (suffix (cond ((not libc) ".0-hex2")
430                        ((eq? libc libc-mes.E) ".hex2")
431                        (else ".mini-hex2")))
432          (target-file-name (string-append base-name suffix))
433          (m1-target (compile.mescc input-file-name #:cc cc #:libc libc #:defines defines))
434          (libc.m1 (cond ((eq? libc libc-mes.E)
435                          (compile.mescc "mlibc/libc-mes.c" #:libc #f #:defines defines))
436                         ((eq? libc mini-libc-mes.E)
437                          (compile.mescc "mlibc/mini-libc-mes.c" #:libc #f #:defines defines))
438                         (else #f))))
439     (target (file-name target-file-name)
440             ;;(inputs `(,@(if libc (list libc.m1) '()) ,m1-target))
441             (inputs `(,m1-target))
442             (method (M1.asm #:m1 m1)))))
443
444 (define* (bin.mescc input-file-name #:key (cc %MESCC) (hex2 %HEX2) (m1 %M1) (libc libc-mes.E) (dependencies '()) (defines '()))
445   (let* ((base-name (base-name input-file-name ".c"))
446          ;;(foo (format (current-error-port) "bin[~s .c] base=~s\n" input-file-name base-name))
447          (suffix (cond ((not libc) ".0-guile")
448                        ((eq? libc libc-mes.E) ".guile")
449                        (else ".mini-guile")))
450          (target-file-name (string-append base-name suffix))
451          (hex2-target (m1-asm input-file-name #:m1 m1 #:cc cc #:libc libc #:defines defines)))
452     (target (file-name target-file-name)
453             (inputs (cons hex2-target dependencies))
454             (method (LINK.hex2 #:hex2 hex2 #:debug? (eq? libc libc-mes.E))))))
455
456 (define* (bin.gcc input-file-name #:key (libc #t) (cc (if libc %CC %CC32)) (dependencies '()) (defines '()))
457   (let* ((base-name (base-name input-file-name ".c"))
458          (suffix (if libc ".gcc" ".mlibc-gcc"))
459          (target-file-name (string-append base-name suffix))
460          (o-target (compile.gcc input-file-name #:cc cc #:libc libc #:defines defines)))
461     (target (file-name target-file-name)
462             (inputs (list o-target))
463             (method (LINK.gcc #:cc cc #:libc libc)))))
464
465 (define* (snarf input-file-name #:key (dependencies '()) (mes? #t))
466   (let* ((base-name (base-name input-file-name ".c"))
467          (suffixes '(".h" ".i" ".environment.i" ".symbol-names.i" ".symbols.i"  ".symbols.h"))
468          (suffixes (if mes? (map (cut string-append ".mes" <>) suffixes) suffixes))
469          (target-file-names (map (cut string-append base-name <>) suffixes))
470          (snarf-target (target (file-name input-file-name))))
471     (target (file-name (car target-file-names))
472             (file-names (cdr target-file-names))
473             (inputs (cons snarf-target dependencies))
474             ;;(inputs (list snarf-target))
475             (method (SNARF.mes mes?)))))
476
477 (define (add-target o)
478   (set! %targets (append %targets (list o)))
479   o)
480 (define (get-target o)
481   (find (lambda (t)
482           (equal? (target-file-name t) o)) %targets))