core: Cleanup symbol initialization and lookup.
[mes.git] / build-aux / mes-snarf.scm
1 #! /bin/sh
2 # -*- scheme -*-
3 exec ${GUILE-guile} --no-auto-compile -L $HOME/src/mes/build-aux -L build-aux -e '(@@ (mes-snarf) main)' -s "$0" ${1+"$@"}
4 !#
5
6 ;;; Mes --- Maxwell Equations of Software
7 ;;; Copyright © 2016 Jan Nieuwenhuizen <janneke@gnu.org>
8 ;;;
9 ;;; mes-snarf.scm: This file is part of Mes.
10 ;;;
11 ;;; Mes is free software; you can redistribute it and/or modify it
12 ;;; under the terms of the GNU General Public License as published by
13 ;;; the Free Software Foundation; either version 3 of the License, or (at
14 ;;; your option) any later version.
15 ;;;
16 ;;; Mes is distributed in the hope that it will be useful, but
17 ;;; WITHOUT ANY WARRANTY; without even the implied warranty of
18 ;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
19 ;;; GNU General Public License for more details.
20 ;;;
21 ;;; You should have received a copy of the GNU General Public License
22 ;;; along with Mes.  If not, see <http://www.gnu.org/licenses/>.
23
24 (define-module (mes-snarf)
25   #:use-module (srfi srfi-1)
26   #:use-module (srfi srfi-26)
27   #:use-module (ice-9 curried-definitions)
28   #:use-module (ice-9 rdelim)
29   #:use-module (ice-9 regex)
30   #:use-module (oop goops))
31
32 (define ((regexp-replace regexp replace) string)
33   (or (and=> (string-match regexp string)
34              (cut regexp-substitute #f <> 'pre replace 'post))
35       string))
36
37 ;; (define-record-type function (make-function name formals annotation)
38 ;;   function?
39 ;;   (name .name)
40 ;;   (formals .formals)
41 ;;   (annotation .annotation))
42
43 (define-class <file> ()
44   (name #:accessor .name #:init-keyword #:name)
45   (content #:accessor .content #:init-keyword #:content))
46
47 (define-class <function> ()
48   (name #:accessor .name #:init-keyword #:name)
49   (formals #:accessor .formals #:init-keyword #:formals)
50   (annotation #:accessor .annotation #:init-keyword #:annotation))
51
52 (define (function-scm-name f)
53   (or (assoc-ref (.annotation f) 'name)
54       ((compose
55         (regexp-replace "_" "-")
56         (regexp-replace "_" "-")
57         (regexp-replace "_" "-")
58         (regexp-replace "_" "-")
59         (regexp-replace "^builtin_" "")
60         (regexp-replace "_to_" "->")
61         (regexp-replace "_x$" "!")
62         (regexp-replace "_p$" "?"))
63        (.name f))))
64
65 (define %builtin-prefix% "scm_")
66 (define (function-builtin-name f)
67   (string-append %builtin-prefix% (.name f)))
68
69 (define %cell-prefix% "cell_")
70 (define (function-cell-name f)
71   (string-append %cell-prefix% (.name f)))
72
73 (define %start 1)
74 (define (symbol->header s i)
75   (format #f "#define cell_~a ~a\n" s i))
76
77 (define (symbol->source s i)
78   (string-append
79    (format #f "g_free.value++;\n")
80    (format #f "g_cells[cell_~a] = scm_~a;\n\n" s s)))
81
82 (define (symbol->names s i)
83   (string-append
84    (format #f "g_cells[cell_~a].car = cstring_to_list (scm_~a.name);\n" s s)))
85
86 (define (function->header f i)
87   (let* ((arity (or (assoc-ref (.annotation f) 'arity)
88                     (if (string-null? (.formals f)) 0
89                         (length (string-split (.formals f) #\,)))))
90          (n (if (eq? arity 'n) -1 arity)))
91     (string-append
92      (format #f "SCM ~a (~a);\n" (.name f) (.formals f))
93      (format #f "function fun_~a = {.function~a=&~a, .arity=~a};\n" (.name f) arity (.name f) n)
94      (format #f "scm ~a = {FUNCTION, .name=~S, .function=0};\n" (function-builtin-name f) (function-scm-name f))
95      (format #f "SCM cell_~a;\n\n" (.name f)))))
96
97 (define (function->source f i)
98   (string-append
99    (format #f "~a.function = g_function;\n" (function-builtin-name f))
100    (format #f "functions[g_function++] = fun_~a;\n" (.name f))
101    (format #f "cell_~a = g_free.value++;\n" (.name f))
102    (format #f "g_cells[cell_~a] = ~a;\n\n" (.name f) (function-builtin-name f))))
103
104 (define (function->environment f i)
105   (string-append
106    (format #f "scm_~a.string = cstring_to_list (scm_~a.name);\n" (.name f) (.name f))
107    (format #f "a = acons (make_symbol (scm_~a.string), ~a, a);\n" (.name f) (function-cell-name f))
108    ;;(format #f "a = add_environment (a, ~S, ~a);\n" (function-scm-name f) (function-cell-name f))
109    ))
110
111 (define (snarf-symbols string)
112   (let* ((matches (append (list-matches "\nscm scm_([a-z_0-9]+) = [{](SPECIAL)," string)
113                           (list-matches "\nscm scm_([a-z_0-9]+) = [{](SYMBOL)," string))))
114     (map (cut match:substring <> 1) matches)))
115
116 (define (snarf-functions string)
117   (let* ((matches (list-matches
118                    "\nSCM[ \n]?([a-z0-9_]+) [(]((SCM ?[^,)]+|, )*)[)][^\n(]*([^\n]*)"
119                    string)))
120     (map (lambda (m)
121            (make <function>
122              #:name (match:substring m 1)
123              #:formals (match:substring m 2)
124              #:annotation (with-input-from-string (match:substring m 4) read)))
125          matches)))
126
127 (define (content? f)
128   ((compose not string-null? .content) f))
129
130 (define (internal? f)
131   ((compose (cut assoc-ref <> 'internal) .annotation) f))
132
133 (define (no-environment? f)
134   ((compose (cut assoc-ref <> 'no-environment) .annotation) f))
135
136 (define (generate-includes file-name)
137   (let* ((string (with-input-from-file file-name read-string))
138          (functions (snarf-functions string))
139          (functions (delete-duplicates functions (lambda (a b) (equal? (.name a) (.name b)))))
140          (functions (filter (negate internal?) functions))
141          (symbols (snarf-symbols string))
142          (base-name (basename file-name ".c"))
143          (header (make <file>
144                    #:name (string-append base-name ".h")
145                    #:content (string-join (map function->header functions (iota (length functions) (+ %start (length symbols)))) "")))
146          (source (make <file>
147                         #:name (string-append base-name ".i")
148                         #:content (string-join (map function->source (filter (negate no-environment?) functions) (iota (length functions) (+ (length symbols) %start))) ""))) 
149          (environment (make <file>
150                         #:name (string-append base-name ".environment.i")
151                         #:content (string-join (map function->environment (filter (negate no-environment?) functions) (iota (length functions) (+ (length symbols) %start))) "")))
152          (symbols.h (make <file>
153                       #:name (string-append base-name ".symbols.h")
154                       #:content (string-join (map symbol->header symbols (iota (length symbols) %start)) "")))
155          (symbols.i (make <file>
156                       #:name (string-append base-name ".symbols.i")
157                       #:content (string-join (map symbol->source symbols (iota (length symbols))) "")))
158          (symbol-names.i (make <file>
159                           #:name (string-append base-name ".symbol-names.i")
160                           #:content (string-join (map symbol->names symbols (iota (length symbols))) ""))))
161     (list header source environment symbols.h symbols.i symbol-names.i)))
162
163 (define (file-write file)
164   (with-output-to-file (.name file) (lambda () (display (.content file)))))
165
166 (define (main args)
167   (let* ((files (cdr args)))
168     (map file-write (filter content? (append-map generate-includes files)))))
169
170 ;;(define string (with-input-from-file "../mes.c" read-string))