core: Number based cells.
[mes.git] / build-aux / mes-snarf.scm
1 #! /bin/sh
2 # -*- scheme -*-
3 exec ${GUILE-guile} --no-auto-compile -L $HOME/src/mes/build-aux -L build-aux -e '(@@ (mes-snarf) main)' -s "$0" ${1+"$@"}
4 !#
5
6 ;;; Mes --- Maxwell Equations of Software
7 ;;; Copyright © 2016 Jan Nieuwenhuizen <janneke@gnu.org>
8 ;;;
9 ;;; mes-snarf.scm: This file is part of Mes.
10 ;;;
11 ;;; Mes is free software; you can redistribute it and/or modify it
12 ;;; under the terms of the GNU General Public License as published by
13 ;;; the Free Software Foundation; either version 3 of the License, or (at
14 ;;; your option) any later version.
15 ;;;
16 ;;; Mes is distributed in the hope that it will be useful, but
17 ;;; WITHOUT ANY WARRANTY; without even the implied warranty of
18 ;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
19 ;;; GNU General Public License for more details.
20 ;;;
21 ;;; You should have received a copy of the GNU General Public License
22 ;;; along with Mes.  If not, see <http://www.gnu.org/licenses/>.
23
24 (define-module (mes-snarf)
25   #:use-module (srfi srfi-1)
26   #:use-module (srfi srfi-26)
27   #:use-module (ice-9 curried-definitions)
28   #:use-module (ice-9 rdelim)
29   #:use-module (ice-9 regex)
30   #:use-module (oop goops))
31
32 (define ((regexp-replace regexp replace) string)
33   (or (and=> (string-match regexp string)
34              (cut regexp-substitute #f <> 'pre replace 'post))
35       string))
36
37 ;; (define-record-type function (make-function name formals annotation)
38 ;;   function?
39 ;;   (name .name)
40 ;;   (formals .formals)
41 ;;   (annotation .annotation))
42
43 (define-class <file> ()
44   (name #:accessor .name #:init-keyword #:name)
45   (content #:accessor .content #:init-keyword #:content))
46
47 (define-class <function> ()
48   (name #:accessor .name #:init-keyword #:name)
49   (formals #:accessor .formals #:init-keyword #:formals)
50   (annotation #:accessor .annotation #:init-keyword #:annotation))
51
52 (define (function-scm-name f)
53   (or (assoc-ref (.annotation f) 'name)
54       ((compose
55         (regexp-replace "_" "-")
56         (regexp-replace "_" "-")
57         (regexp-replace "_" "-")
58         (regexp-replace "_" "-")
59         (regexp-replace "^builtin_" "")
60         (regexp-replace "_to_" "->")
61         (regexp-replace "_x$" "!")
62         (regexp-replace "_p$" "?"))
63        (.name f))))
64
65 (define %builtin-prefix% "scm_")
66 (define (function-builtin-name f)
67   (string-append %builtin-prefix% (.name f)))
68
69 (define %cell-prefix% "cell_")
70 (define (function-cell-name f)
71   (string-append %cell-prefix% (.name f)))
72
73 (define (function->source f i)
74   (string-append
75    (format #f "cell_~a = g_free.value++;\n" (.name f))
76    (format #f "g_cells[cell_~a] = ~a;\n" (.name f) (function-builtin-name f))))
77
78 (define (function->environment f i)
79   (string-append
80    (format #f "a = add_environment (a, ~S, ~a);\n" (function-scm-name f) (function-cell-name f))))
81
82 (define %start 1)
83 (define (symbol->header s i)
84   (format #f "SCM cell_~a;\n" s))
85
86 (define (symbol->source s i)
87   (string-append
88    (format #f "cell_~a = g_free.value++;\n" s)
89    (format #f "g_cells[cell_~a] = scm_~a;\n" s s)))
90
91 (define (function->header f i)
92   (let* ((arity (or (assoc-ref (.annotation f) 'arity)
93                     (if (string-null? (.formals f)) 0
94                         (length (string-split (.formals f) #\,)))))
95          (n (if (eq? arity 'n) -1 arity)))
96     (string-append (format #f "SCM ~a (~a);\n" (.name f) (.formals f))
97                    (format #f "function fun_~a = {.function~a=&~a, .arity=~a};\n" (.name f) arity (.name f) n)
98                    (format #f "scm ~a = {FUNCTION, .name=~S, .function=&fun_~a};\n" (function-builtin-name f) (function-scm-name f) (.name f))
99                    (format #f "SCM cell_~a = ~a;\n" (.name f) i))))
100
101 (define (snarf-symbols string)
102   (let* ((matches (append (list-matches "\nscm scm_([a-z_0-9]+) = [{](SPECIAL)," string)
103                           (list-matches "\nscm scm_([a-z_0-9]+) = [{](SYMBOL)," string))))
104     (map (cut match:substring <> 1) matches)))
105
106 (define (snarf-functions string)
107   (let* ((matches (list-matches
108                    "\nSCM[ \n]?([a-z0-9_]+) [(]((SCM ?[^,)]+|, )*)[)][^\n(]*([^\n]*)"
109                    string)))
110     (map (lambda (m)
111            (make <function>
112              #:name (match:substring m 1)
113              #:formals (match:substring m 2)
114              #:annotation (with-input-from-string (match:substring m 4) read)))
115          matches)))
116
117 (define (content? f)
118   ((compose not string-null? .content) f))
119
120 (define (internal? f)
121   ((compose (cut assoc-ref <> 'internal) .annotation) f))
122
123 (define (no-environment? f)
124   ((compose (cut assoc-ref <> 'no-environment) .annotation) f))
125
126 (define (generate-includes file-name)
127   (let* ((string (with-input-from-file file-name read-string))
128          (functions (snarf-functions string))
129          (functions (delete-duplicates functions (lambda (a b) (equal? (.name a) (.name b)))))
130          (functions (sort functions (lambda (a b) (string< (.name a) (.name b)))))
131          (functions (filter (negate internal?) functions))
132          (symbols (snarf-symbols string))
133          (base-name (basename file-name ".c"))
134          (header (make <file>
135                    #:name (string-append base-name ".h")
136                    #:content (string-join (map function->header functions (iota (length functions) (+ %start (length symbols)))) "")))
137          (source (make <file>
138                         #:name (string-append base-name ".i")
139                         #:content (string-join (map function->source (filter (negate no-environment?) functions) (iota (length functions) (+ (length symbols) %start))) "")))
140          (environment (make <file>
141                         #:name (string-append base-name ".environment.i")
142                         #:content (string-join (map function->environment (filter (negate no-environment?) functions) (iota (length functions) (+ (length symbols) %start))) "")))
143          (symbols.h (make <file>
144                       #:name (string-append base-name ".symbols.h")
145                       #:content (string-join (map symbol->header symbols (iota (length symbols) %start)) "")))
146          (symbols.i (make <file>
147                       #:name (string-append base-name ".symbols.i")
148                       #:content (string-join (map symbol->source symbols (iota (length symbols))) ""))))
149     (list header source environment symbols.h symbols.i)))
150
151 (define (file-write file)
152   (with-output-to-file (.name file) (lambda () (display (.content file)))))
153
154 (define (main args)
155   (let* ((files (cdr args)))
156     (map file-write (filter content? (append-map generate-includes files)))))
157
158 ;;(define string (with-input-from-file "../mes.c" read-string))
159