9dcac71dc5a7ec2f7f7b42b75245de919a4d66df
[mes.git] / build-aux / mes-snarf.scm
1 #! /bin/sh
2 # -*-scheme-*-
3 exec ${GUILE-guile} --no-auto-compile -L $(dirname $0) -C $(dirname $0) -e '(mes-snarf)' -s "$0" "$@"
4 !#
5
6 ;;; GNU Mes --- Maxwell Equations of Software
7 ;;; Copyright © 2016,2017,2018 Jan (janneke) Nieuwenhuizen <janneke@gnu.org>
8 ;;;
9 ;;; mes-snarf.scm: This file is part of GNU Mes.
10 ;;;
11 ;;; GNU Mes is free software; you can redistribute it and/or modify it
12 ;;; under the terms of the GNU General Public License as published by
13 ;;; the Free Software Foundation; either version 3 of the License, or (at
14 ;;; your option) any later version.
15 ;;;
16 ;;; GNU Mes is distributed in the hope that it will be useful, but
17 ;;; WITHOUT ANY WARRANTY; without even the implied warranty of
18 ;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
19 ;;; GNU General Public License for more details.
20 ;;;
21 ;;; You should have received a copy of the GNU General Public License
22 ;;; along with GNU Mes.  If not, see <http://www.gnu.org/licenses/>.
23
24 (define-module (mes-snarf)
25   #:use-module (srfi srfi-1)
26   #:use-module (srfi srfi-8)
27   #:use-module (srfi srfi-9)
28   #:use-module (srfi srfi-26)
29   #:use-module (ice-9 rdelim)
30   #:export (main))
31
32 (cond-expand
33  (mes
34   (define %scheme "mes"))
35  (guile-2
36   (define %scheme "guile")
37   (define-macro (mes-use-module . rest) #t))
38  (guile
39   (use-modules (ice-9 syncase))
40   (define %scheme "guile")
41   (define-macro (mes-use-module . rest) #t)))
42
43 (mes-use-module (mes guile))
44 (mes-use-module (srfi srfi-1))
45 (mes-use-module (srfi srfi-8))
46 (mes-use-module (srfi srfi-9))
47 (mes-use-module (srfi srfi-26))
48
49 (when (and=> (getenv "V") (lambda (v) (> (string->number v) 1)))
50   (format (current-error-port) "mes-snarf[~a]...\n" %scheme))
51
52 (define (char->char from to char)
53   (if (eq? char from) to char))
54
55 (define (string-replace-char string from to)
56   (string-map (cut char->char from to <>) string))
57
58 (define (string-replace-suffix string from to)
59   (if (string-suffix? from string)
60       (string-replace string to (- (string-length string) (string-length from)))
61       string))
62
63 (define (string-replace-string string from to)
64   (cond ((string-contains string from) => (lambda (i) (string-replace string to i (+ i (string-length from)))))
65         (else string)))
66
67 (define %gcc? #t)
68
69 (define-record-type <file> (make-file name content)
70   file?
71   (name file.name)
72   (content file.content))
73
74 (define-record-type <function> (make-function name formals annotation)
75   function?
76   (name function.name)
77   (formals function.formals)
78   (annotation function.annotation))
79
80 (define (function-scm-name f)
81   (or (assoc-ref (function.annotation f) 'name)
82       (let ((name ((compose
83                     identity
84                     (cut string-replace-char <> #\_ #\-)
85                     (cut string-replace-string <> "_to_" "->")
86                     (cut string-replace-suffix <> "_x" "!")
87                     (cut string-replace-suffix <> "_x_" "!-")
88                     (cut string-replace-suffix <> "_p" "?")
89                     )
90                    (function.name f))))
91         (if (not (string-suffix? "-" name)) name
92             (string-append "core:" (string-drop-right name 1))))))
93
94 (define %builtin-prefix% "scm_")
95 (define (function-builtin-name f)
96   (string-append %builtin-prefix% (function.name f)))
97
98 (define %cell-prefix% "cell_")
99 (define (function-cell-name f)
100   (string-append %cell-prefix% (function.name f)))
101
102 (define %start 1)
103 (define (symbol->header s i)
104   (string-append
105    (format #f "// CONSTANT ~a ~a\n" s i)
106    (format #f "#define ~a ~a\n" s i)))
107
108 (define (function->header f i)
109   (let* ((arity (or (assoc-ref (function.annotation f) 'arity)
110                     (if (string-null? (function.formals f)) 0
111                         (length (string-split (function.formals f) #\,)))))
112          (n (if (eq? arity 'n) -1 arity)))
113     (format #f "SCM ~a (~a);\n" (function.name f) (function.formals f))))
114
115 (define (function->source f i)
116   (let* ((arity (or (assoc-ref (function.annotation f) 'arity)
117                     (if (string-null? (function.formals f)) 0
118                         (length (string-split (function.formals f) #\,)))))
119          (n (if (eq? arity 'n) -1 arity)))
120     (format #f "  a = init_builtin (builtin_type, ~s, ~a, &~a, a);\n" (function.name f) n (function.name f))))
121
122 (define (disjoin . predicates)
123   (lambda (. arguments)
124     (any (cut apply <> arguments) predicates)))
125
126 (define (snarf-symbols string)
127   (let* ((lines (string-split string #\newline))
128          (symbols (filter (cut string-prefix? "  init_symbol (" <>) lines)))
129     (define (line->symbol line)
130       ((compose
131         (lambda (s) (string-take s (string-index s #\,)))
132         (cut string-drop <> (string-length "  init_symbol (")))
133        line))
134     (map line->symbol symbols)))
135
136 (define (string-split-string string sep)
137   (cond ((string-contains string sep) => (lambda (i) (list (string-take string i) (string-drop string (+ i (string-length sep))))))
138         (else (list string #f))))
139
140 (define (snarf-functions string)
141   (let ((lines (string-split string #\newline)))
142     (filter-map
143      (lambda (line previous)
144        (receive (function rest)
145            (apply values (string-split-string line " "))
146          (and function
147               (equal? (string-trim previous) "SCM")
148               (not (string-null? function))
149               (not (string-prefix? "#" function))
150               (not (string-prefix? "/" function))
151               rest
152               (receive (parameter-list annotation)
153                   (apply values (string-split-string rest " ///"))
154                 (let* ((parameters (string-drop parameter-list 1))
155                        (parameters (string-drop-right parameters 1))
156                        (formals (if (string-null? parameters) '()
157                                     (string-split parameters #\,)))
158                        (formals (map string-trim formals)))
159                   (and parameters
160                        (let* ((non-SCM (filter (negate (cut string-prefix? "SCM" <>)) formals)))
161                          (and (null? non-SCM)
162                               (let ((annotation (and annotation (with-input-from-string annotation read))))
163                                 (make-function function parameters annotation))))))))))
164      lines (cons "\n" lines))))
165
166 (define (content? f)
167   ((compose not string-null? file.content) f))
168
169 (define (internal? f)
170   ((compose (cut assoc-ref <> 'internal) function.annotation) f))
171
172 (define (no-environment? f)
173   ((compose (cut assoc-ref <> 'no-environment) function.annotation) f))
174
175 (define (generate-includes file-name)
176   (let* ((srcdest (or (getenv "srcdest") ""))
177          (string (with-input-from-file (string-append srcdest file-name) read-string))
178          (functions (snarf-functions string))
179          (functions (delete-duplicates functions (lambda (a b) (equal? (function.name a) (function.name b)))))
180          (functions (filter (negate internal?) functions))
181          (symbols (snarf-symbols string))
182          (base-name (basename file-name ".c"))
183          (dir (string-append (dirname file-name)))
184          (base-name (string-append dir "/" base-name))
185          (base-name (if %gcc? base-name
186                         (string-append base-name ".mes")))
187          (header (make-file
188                   (string-append base-name ".h")
189                   (string-join (map function->header functions (iota (length functions) (+ %start (length symbols)))) "")))
190          (source (make-file
191                   (string-append base-name ".i")
192                   (string-join (map function->source (filter (negate no-environment?) functions) (iota (length functions) (+ (length symbols) %start))) "")))
193          (symbols.h (make-file
194                      (string-append base-name ".symbols.h")
195                      (string-join (map symbol->header symbols (iota (length symbols) %start)) ""))))
196     (list header source symbols.h)))
197
198 (define (file-write file)
199   (system* "mkdir" "-p" (dirname (file.name file)))
200   (with-output-to-file (file.name file) (lambda () (display (file.content file)))))
201
202 (define (main args)
203   (let* ((files (cdr args))
204          (files (append-map generate-includes files)))
205     (for-each file-write (filter content? files))))