build: Refactor.
[mes.git] / build-aux / compile-all.scm
1 ;;; GNU Guix --- Functional package management for GNU
2 ;;; Copyright © 2016 Taylan Ulrich Bayırlı/Kammer <taylanbayirli@gmail.com>
3 ;;; Copyright © 2016, 2017 Ludovic Courtès <ludo@gnu.org>
4 ;;;
5 ;;; This file is part of GNU Guix.
6 ;;;
7 ;;; GNU Guix is free software; you can redistribute it and/or modify it
8 ;;; under the terms of the GNU General Public License as published by
9 ;;; the Free Software Foundation; either version 3 of the License, or (at
10 ;;; your option) any later version.
11 ;;;
12 ;;; GNU Guix is distributed in the hope that it will be useful, but
13 ;;; WITHOUT ANY WARRANTY; without even the implied warranty of
14 ;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
15 ;;; GNU General Public License for more details.
16 ;;;
17 ;;; You should have received a copy of the GNU General Public License
18 ;;; along with GNU Guix.  If not, see <http://www.gnu.org/licenses/>.
19
20 (use-modules (system base target)
21              (system base message)
22              (ice-9 match)
23              (ice-9 threads))
24
25 (define (mkdir-p dir)
26   "Create directory DIR and all its ancestors."
27   (define absolute?
28     (string-prefix? "/" dir))
29
30   (define not-slash
31     (char-set-complement (char-set #\/)))
32
33   (let loop ((components (string-tokenize dir not-slash))
34              (root       (if absolute?
35                              ""
36                              ".")))
37     (match components
38       ((head tail ...)
39        (let ((path (string-append root "/" head)))
40          (catch 'system-error
41            (lambda ()
42              (mkdir path)
43              (loop tail path))
44            (lambda args
45              (if (= EEXIST (system-error-errno args))
46                  (loop tail path)
47                  (apply throw args))))))
48       (() #t))))
49
50 (define warnings
51   '(unsupported-warning format unbound-variable arity-mismatch))
52
53 (define host (getenv "host"))
54
55 (define srcdir (getenv "srcdir"))
56
57 (define (relative-file file)
58   (if (string-prefix? (string-append srcdir "/") file)
59       (string-drop file (+ 1 (string-length srcdir)))
60       file))
61
62 (define (file-mtime<? f1 f2)
63   (< (stat:mtime (stat f1))
64      (stat:mtime (stat f2))))
65
66 (define (scm->go file)
67   (let* ((relative (relative-file file))
68          (without-extension (string-drop-right relative 4)))
69     (string-append without-extension ".go")))
70
71 (define (file-needs-compilation? file)
72   (let ((go (scm->go file)))
73     (or (not (file-exists? go))
74         (file-mtime<? go file))))
75
76 (define (file->module file)
77   (let* ((relative (relative-file file))
78          (module-path (string-drop-right relative 4)))
79     (map string->symbol
80          (string-split module-path #\/))))
81
82 ;;; To work around <http://bugs.gnu.org/15602> (FIXME), we want to load all
83 ;;; files to be compiled first.  We do this via resolve-interface so that the
84 ;;; top-level of each file (module) is only executed once.
85 (define (load-module-file file)
86   (let ((module (file->module file)))
87     (format #t "  LOAD     ~a~%" module)
88     (resolve-interface module)))
89
90 (cond-expand
91  (guile-2.2 (use-modules (language tree-il optimize)
92                          (language cps optimize)))
93  (else #f))
94
95 (define %default-optimizations
96   ;; Default optimization options (equivalent to -O2 on Guile 2.2).
97   (cond-expand
98    (guile-2.2 (append (tree-il-default-optimization-options)
99                       (cps-default-optimization-options)))
100     (else '())))
101
102 (define %lightweight-optimizations
103   ;; Lightweight optimizations (like -O0, but with partial evaluation).
104   (let loop ((opts %default-optimizations)
105              (result '()))
106     (match opts
107       (() (reverse result))
108       ((#:partial-eval? _ rest ...)
109        (loop rest `(#t #:partial-eval? ,@result)))
110       ((kw _ rest ...)
111        (loop rest `(#f ,kw ,@result))))))
112
113 (define (optimization-options file)
114   (if (string-contains file "gnu/packages/")
115       %lightweight-optimizations                  ;build faster
116       '()))
117
118 (define (compile-file* file output-mutex)
119   (let ((go (scm->go file)))
120     (with-mutex output-mutex
121       (format #t "  GUILEC   ~a~%" go)
122       (force-output))
123     (mkdir-p (dirname go))
124     (with-fluids ((*current-warning-prefix* ""))
125       (with-target host
126         (lambda ()
127           (compile-file file
128                         #:output-file go
129                         #:opts `(#:warnings ,warnings
130                                  ,@(optimization-options file))))))))
131
132 ;; Install a SIGINT handler to give unwind handlers in 'compile-file' an
133 ;; opportunity to run upon SIGINT and to remove temporary output files.
134 (sigaction SIGINT
135   (lambda args
136     (exit 1)))
137
138 (match (command-line)
139   ((_ . files)
140    (let ((files (filter file-needs-compilation? files)))
141      (for-each load-module-file files)
142      (let ((mutex (make-mutex)))
143        ;; Make sure compilation related modules are loaded before starting to
144        ;; compile files in parallel.
145        (compile #f)
146        (par-for-each (lambda (file)
147                        (compile-file* file mutex))
148                      files)))))
149
150 ;;; Local Variables:
151 ;;; eval: (put 'with-target 'scheme-indent-function 1)
152 ;;; End: