ath9k_htc/sboot/magpie_1_1/sboot/athos/src/xtos/memep-initrams.S

   1 // memep-initrams.S  --  Initialize local memory ECC/parity
   2 // $Id: //depot/rel/Cottonwood/Xtensa/OS/xtos/memep-initrams.S#3 $
   3
   4 // Copyright (c) 2006-2010 Tensilica Inc.
   5 //
   6 // Permission is hereby granted, free of charge, to any person obtaining
   7 // a copy of this software and associated documentation files (the
   8 // "Software"), to deal in the Software without restriction, including
   9 // without limitation the rights to use, copy, modify, merge, publish,
  10 // distribute, sublicense, and/or sell copies of the Software, and to
  11 // permit persons to whom the Software is furnished to do so, subject to
  12 // the following conditions:
  13 //
  14 // The above copyright notice and this permission notice shall be included
  15 // in all copies or substantial portions of the Software.
  16 //
  17 // THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,
  18 // EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF
  19 // MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.
  20 // IN NO EVENT SHALL THE AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY
  21 // CLAIM, DAMAGES OR OTHER LIABILITY, WHETHER IN AN ACTION OF CONTRACT,
  22 // TORT OR OTHERWISE, ARISING FROM, OUT OF OR IN CONNECTION WITH THE
  23 // SOFTWARE OR THE USE OR OTHER DEALINGS IN THE SOFTWARE.
  24
  25 #include <xtensa/coreasm.h>
  26
  27
  28         /*
  29          *  void  _xtos_memep_initrams(void);
  30          *
  31          *  Most reset vectors initialize caches, leaving only the local memories
  32          *  (instruction and data RAMs) with potentially some words that have
  33          *  not been written to and thus have uninitialized ECC/parity bits.
  34          *  Loading such a word after enabling ECC/parity checking would result
  35          *  in an exception (or memory error reported in MESR).  To avoid this,
  36          *  an application must either carefully avoid loading from uninitialized
  37          *  words, or ensure it writes to every instruction and data RAM word.
  38          *  The latter is what this function does.  It reads and writes every
  39          *  word of every local instruction and data RAM.  It should normally
  40          *  be called with interrupts disabled.  An interrupt might come in
  41          *  between a load and store, in which case any modification made by the
  42          *  interrupt handler to that local memory location is lost when this
  43          *  function resumes and does the store.  If no interrupt handler makes
  44          *  any persistent modification to local memories, disabling them around
  45          *  a call to this function may be unnecessary.
  46          *
  47          * On the simulator (ISS), everything comes up zeroed, so no there is
  48          * no need for this initialization.
  49          */
  50         .text
  51         .align  4
  52         .global _xtos_memep_initrams
  53 _xtos_memep_initrams:
  54         abi_entry
  55
  56         // Local Memory ECC/Parity option initialization
  57 #if XCHAL_HAVE_MEM_ECC_PARITY && (XCHAL_NUM_DATARAM || XCHAL_NUM_INSTRAM /*|| XCHAL_NUM_URAM || XCHAL_NUM_XLMI*/) && !defined(SIMULATOR)
  58         .section .rodata, "a"
  59         .align  4
  60 .L_locmemep_start:
  61 #  if XCHAL_NUM_DATARAM >= 1 && XCHAL_DATARAM0_ECC_PARITY
  62         .long   XCHAL_DATARAM0_VADDR, XCHAL_DATARAM0_VADDR+XCHAL_DATARAM0_SIZE
  63 #  endif
  64 #  if XCHAL_NUM_DATARAM >= 2 && XCHAL_DATARAM1_ECC_PARITY
  65         .long   XCHAL_DATARAM1_VADDR, XCHAL_DATARAM1_VADDR+XCHAL_DATARAM1_SIZE
  66 #  endif
  67 #  if XCHAL_NUM_INSTRAM >= 1 && XCHAL_INSTRAM0_ECC_PARITY
  68         .long   XCHAL_INSTRAM0_VADDR, XCHAL_INSTRAM0_VADDR+XCHAL_INSTRAM0_SIZE
  69 #  endif
  70 #  if XCHAL_NUM_INSTRAM >= 2 && XCHAL_INSTRAM1_ECC_PARITY
  71         .long   XCHAL_INSTRAM1_VADDR, XCHAL_INSTRAM1_VADDR+XCHAL_INSTRAM1_SIZE
  72 #  endif
  73 .L_locmemep_end:
  74         .text
  75         movi    a5, .L_locmemep_start   // start of table of local memory ranges
  76         movi    a6, .L_locmemep_end     // end of table ...
  77 2:      l32i    a3, a5, 0               // start of local memory
  78         l32i    a4, a5, 4               // end of local memory
  79         addi    a5, a5, 8               // (next entry in table)
  80 1:      l32i    a2, a3, 0               // load and store every word of local memory...
  81         s32i    a2, a3, 0               //  ... to initialize all parity and/or ECC bits
  82         addi    a3, a3, 4
  83         bltu    a3, a4, 1b              // loop until whole memory initialized
  84         bltu    a5, a6, 2b              // loop until all memories initialized
  85         //  ECC/parity bits are now initialized, checking can be turned on.
  86 #endif /* ECC/parity on instruction or data RAM(s) */
  87
  88         abi_return
  89
  90         .size   _xtos_memep_initrams, . - _xtos_memep_initrams
  91