config/zconf.y

   1 %{
   2 /*
   3  * Copyright (C) 2002 Roman Zippel <zippel@linux-m68k.org>
   4  * Released under the terms of the GNU GPL v2.0.
   5  */
   6
   7 #include <ctype.h>
   8 #include <stdarg.h>
   9 #include <stdio.h>
  10 #include <stdlib.h>
  11 #include <string.h>
  12 #include <stdbool.h>
  13
  14 #include "lkc.h"
  15
  16 #define printd(mask, fmt...) if (cdebug & (mask)) printf(fmt)
  17
  18 #define PRINTD          0x0001
  19 #define DEBUG_PARSE     0x0002
  20
  21 int cdebug = PRINTD;
  22
  23 int yylex(void);
  24 static void yyerror(const char *err);
  25 static void zconfprint(const char *err, ...);
  26 static void zconf_error(const char *err, ...);
  27 static bool zconf_endtoken(const struct kconf_id *id, int starttoken, int endtoken);
  28
  29 struct symbol *symbol_hash[SYMBOL_HASHSIZE];
  30
  31 static struct menu *current_menu, *current_entry;
  32
  33 %}
  34
  35 %union
  36 {
  37         char *string;
  38         struct file *file;
  39         struct symbol *symbol;
  40         struct expr *expr;
  41         struct menu *menu;
  42         const struct kconf_id *id;
  43         enum variable_flavor flavor;
  44 }
  45
  46 %token <id>T_MAINMENU
  47 %token <id>T_MENU
  48 %token <id>T_ENDMENU
  49 %token <id>T_SOURCE
  50 %token <id>T_CHOICE
  51 %token <id>T_ENDCHOICE
  52 %token <id>T_COMMENT
  53 %token <id>T_CONFIG
  54 %token <id>T_MENUCONFIG
  55 %token <id>T_HELP
  56 %token <string> T_HELPTEXT
  57 %token <id>T_IF
  58 %token <id>T_ENDIF
  59 %token <id>T_DEPENDS
  60 %token <id>T_OPTIONAL
  61 %token <id>T_PROMPT
  62 %token <id>T_TYPE
  63 %token <id>T_DEFAULT
  64 %token <id>T_SELECT
  65 %token <id>T_IMPLY
  66 %token <id>T_RANGE
  67 %token <id>T_VISIBLE
  68 %token <id>T_OPTION
  69 %token <id>T_ON
  70 %token <string> T_WORD
  71 %token <string> T_WORD_QUOTE
  72 %token T_UNEQUAL
  73 %token T_LESS
  74 %token T_LESS_EQUAL
  75 %token T_GREATER
  76 %token T_GREATER_EQUAL
  77 %token T_CLOSE_PAREN
  78 %token T_OPEN_PAREN
  79 %token T_EOL
  80 %token <string> T_VARIABLE
  81 %token <flavor> T_ASSIGN
  82 %token <string> T_ASSIGN_VAL
  83
  84 %left T_OR
  85 %left T_AND
  86 %left T_EQUAL T_UNEQUAL
  87 %left T_LESS T_LESS_EQUAL T_GREATER T_GREATER_EQUAL
  88 %nonassoc T_NOT
  89
  90 %type <string> prompt
  91 %type <symbol> nonconst_symbol
  92 %type <symbol> symbol
  93 %type <expr> expr
  94 %type <expr> if_expr
  95 %type <id> end
  96 %type <menu> if_entry menu_entry choice_entry
  97 %type <string> symbol_option_arg word_opt assign_val
  98
  99 %destructor {
 100         fprintf(stderr, "%s:%d: missing end statement for this entry\n",
 101                 $$->file->name, $$->lineno);
 102         if (current_menu == $$)
 103                 menu_end_menu();
 104 } if_entry menu_entry choice_entry
 105
 106 %{
 107 /* Include kconf_id.c here so it can see the token constants. */
 108 #include "kconf_id.c"
 109 %}
 110
 111 %%
 112 input: mainmenu_stmt stmt_list | stmt_list;
 113
 114 /* mainmenu entry */
 115
 116 mainmenu_stmt: T_MAINMENU prompt T_EOL
 117 {
 118         menu_add_prompt(P_MENU, $2, NULL);
 119 };
 120
 121 stmt_list:
 122           /* empty */
 123         | stmt_list common_stmt
 124         | stmt_list choice_stmt
 125         | stmt_list menu_stmt
 126         | stmt_list T_WORD error T_EOL  { zconf_error("unknown statement \"%s\"", $2); }
 127         | stmt_list error T_EOL         { zconf_error("invalid statement"); }
 128 ;
 129
 130 common_stmt:
 131           if_stmt
 132         | comment_stmt
 133         | config_stmt
 134         | menuconfig_stmt
 135         | source_stmt
 136         | assignment_stmt
 137 ;
 138
 139 /* config/menuconfig entry */
 140
 141 config_entry_start: T_CONFIG nonconst_symbol T_EOL
 142 {
 143         $2->flags |= SYMBOL_OPTIONAL;
 144         menu_add_entry($2);
 145         printd(DEBUG_PARSE, "%s:%d:config %s\n", zconf_curname(), zconf_lineno(), $2->name);
 146 };
 147
 148 config_stmt: config_entry_start config_option_list
 149 {
 150         printd(DEBUG_PARSE, "%s:%d:endconfig\n", zconf_curname(), zconf_lineno());
 151 };
 152
 153 menuconfig_entry_start: T_MENUCONFIG nonconst_symbol T_EOL
 154 {
 155         $2->flags |= SYMBOL_OPTIONAL;
 156         menu_add_entry($2);
 157         printd(DEBUG_PARSE, "%s:%d:menuconfig %s\n", zconf_curname(), zconf_lineno(), $2->name);
 158 };
 159
 160 menuconfig_stmt: menuconfig_entry_start config_option_list
 161 {
 162         if (current_entry->prompt)
 163                 current_entry->prompt->type = P_MENU;
 164         else
 165                 zconfprint("warning: menuconfig statement without prompt");
 166         printd(DEBUG_PARSE, "%s:%d:endconfig\n", zconf_curname(), zconf_lineno());
 167 };
 168
 169 config_option_list:
 170           /* empty */
 171         | config_option_list config_option
 172         | config_option_list symbol_option
 173         | config_option_list depends
 174         | config_option_list help
 175 ;
 176
 177 config_option: T_TYPE prompt_stmt_opt T_EOL
 178 {
 179         menu_set_type($1->stype);
 180         printd(DEBUG_PARSE, "%s:%d:type(%u)\n",
 181                 zconf_curname(), zconf_lineno(),
 182                 $1->stype);
 183 };
 184
 185 config_option: T_PROMPT prompt if_expr T_EOL
 186 {
 187         menu_add_prompt(P_PROMPT, $2, $3);
 188         printd(DEBUG_PARSE, "%s:%d:prompt\n", zconf_curname(), zconf_lineno());
 189 };
 190
 191 config_option: T_DEFAULT expr if_expr T_EOL
 192 {
 193         menu_add_expr(P_DEFAULT, $2, $3);
 194         if ($1->stype != S_UNKNOWN)
 195                 menu_set_type($1->stype);
 196         printd(DEBUG_PARSE, "%s:%d:default(%u)\n",
 197                 zconf_curname(), zconf_lineno(),
 198                 $1->stype);
 199 };
 200
 201 config_option: T_SELECT nonconst_symbol if_expr T_EOL
 202 {
 203         menu_add_symbol(P_SELECT, $2, $3);
 204         printd(DEBUG_PARSE, "%s:%d:select\n", zconf_curname(), zconf_lineno());
 205 };
 206
 207 config_option: T_IMPLY nonconst_symbol if_expr T_EOL
 208 {
 209         menu_add_symbol(P_IMPLY, $2, $3);
 210         printd(DEBUG_PARSE, "%s:%d:imply\n", zconf_curname(), zconf_lineno());
 211 };
 212
 213 config_option: T_RANGE symbol symbol if_expr T_EOL
 214 {
 215         menu_add_expr(P_RANGE, expr_alloc_comp(E_RANGE,$2, $3), $4);
 216         printd(DEBUG_PARSE, "%s:%d:range\n", zconf_curname(), zconf_lineno());
 217 };
 218
 219 symbol_option: T_OPTION symbol_option_list T_EOL
 220 ;
 221
 222 symbol_option_list:
 223           /* empty */
 224         | symbol_option_list T_WORD symbol_option_arg
 225 {
 226         const struct kconf_id *id = kconf_id_lookup($2, strlen($2));
 227         if (id && id->flags & TF_OPTION) {
 228                 menu_add_option(id->token, $3);
 229                 free($3);
 230         }
 231         else
 232                 zconfprint("warning: ignoring unknown option %s", $2);
 233         free($2);
 234 };
 235
 236 symbol_option_arg:
 237           /* empty */           { $$ = NULL; }
 238         | T_EQUAL prompt        { $$ = $2; }
 239 ;
 240
 241 /* choice entry */
 242
 243 choice: T_CHOICE word_opt T_EOL
 244 {
 245         struct symbol *sym = sym_lookup($2, SYMBOL_CHOICE);
 246         sym->flags |= SYMBOL_NO_WRITE;
 247         menu_add_entry(sym);
 248         menu_add_expr(P_CHOICE, NULL, NULL);
 249         free($2);
 250         printd(DEBUG_PARSE, "%s:%d:choice\n", zconf_curname(), zconf_lineno());
 251 };
 252
 253 choice_entry: choice choice_option_list
 254 {
 255         $$ = menu_add_menu();
 256 };
 257
 258 choice_end: end
 259 {
 260         if (zconf_endtoken($1, T_CHOICE, T_ENDCHOICE)) {
 261                 menu_end_menu();
 262                 printd(DEBUG_PARSE, "%s:%d:endchoice\n", zconf_curname(), zconf_lineno());
 263         }
 264 };
 265
 266 choice_stmt: choice_entry choice_block choice_end
 267 ;
 268
 269 choice_option_list:
 270           /* empty */
 271         | choice_option_list choice_option
 272         | choice_option_list depends
 273         | choice_option_list help
 274 ;
 275
 276 choice_option: T_PROMPT prompt if_expr T_EOL
 277 {
 278         menu_add_prompt(P_PROMPT, $2, $3);
 279         printd(DEBUG_PARSE, "%s:%d:prompt\n", zconf_curname(), zconf_lineno());
 280 };
 281
 282 choice_option: T_TYPE prompt_stmt_opt T_EOL
 283 {
 284         if ($1->stype == S_BOOLEAN || $1->stype == S_TRISTATE) {
 285                 menu_set_type($1->stype);
 286                 printd(DEBUG_PARSE, "%s:%d:type(%u)\n",
 287                         zconf_curname(), zconf_lineno(),
 288                         $1->stype);
 289         } else
 290                 YYERROR;
 291 };
 292
 293 choice_option: T_OPTIONAL T_EOL
 294 {
 295         current_entry->sym->flags |= SYMBOL_OPTIONAL;
 296         printd(DEBUG_PARSE, "%s:%d:optional\n", zconf_curname(), zconf_lineno());
 297 };
 298
 299 choice_option: T_DEFAULT nonconst_symbol if_expr T_EOL
 300 {
 301         if ($1->stype == S_UNKNOWN) {
 302                 menu_add_symbol(P_DEFAULT, $2, $3);
 303                 printd(DEBUG_PARSE, "%s:%d:default\n",
 304                         zconf_curname(), zconf_lineno());
 305         } else
 306                 YYERROR;
 307 };
 308
 309 choice_block:
 310           /* empty */
 311         | choice_block common_stmt
 312 ;
 313
 314 /* if entry */
 315
 316 if_entry: T_IF expr T_EOL
 317 {
 318         printd(DEBUG_PARSE, "%s:%d:if\n", zconf_curname(), zconf_lineno());
 319         menu_add_entry(NULL);
 320         menu_add_dep($2);
 321         $$ = menu_add_menu();
 322 };
 323
 324 if_end: end
 325 {
 326         if (zconf_endtoken($1, T_IF, T_ENDIF)) {
 327                 menu_end_menu();
 328                 printd(DEBUG_PARSE, "%s:%d:endif\n", zconf_curname(), zconf_lineno());
 329         }
 330 };
 331
 332 if_stmt: if_entry stmt_list if_end
 333 ;
 334
 335 /* menu entry */
 336
 337 menu: T_MENU prompt T_EOL
 338 {
 339         menu_add_entry(NULL);
 340         menu_add_prompt(P_MENU, $2, NULL);
 341         printd(DEBUG_PARSE, "%s:%d:menu\n", zconf_curname(), zconf_lineno());
 342 };
 343
 344 menu_entry: menu visibility_list depends_list
 345 {
 346         $$ = menu_add_menu();
 347 };
 348
 349 menu_end: end
 350 {
 351         if (zconf_endtoken($1, T_MENU, T_ENDMENU)) {
 352                 menu_end_menu();
 353                 printd(DEBUG_PARSE, "%s:%d:endmenu\n", zconf_curname(), zconf_lineno());
 354         }
 355 };
 356
 357 menu_stmt: menu_entry menu_block menu_end
 358 ;
 359
 360 menu_block:
 361           /* empty */
 362         | menu_block common_stmt
 363         | menu_block menu_stmt
 364         | menu_block choice_stmt
 365 ;
 366
 367 source_stmt: T_SOURCE prompt T_EOL
 368 {
 369         printd(DEBUG_PARSE, "%s:%d:source %s\n", zconf_curname(), zconf_lineno(), $2);
 370         zconf_nextfile($2);
 371         free($2);
 372 };
 373
 374 /* comment entry */
 375
 376 comment: T_COMMENT prompt T_EOL
 377 {
 378         menu_add_entry(NULL);
 379         menu_add_prompt(P_COMMENT, $2, NULL);
 380         printd(DEBUG_PARSE, "%s:%d:comment\n", zconf_curname(), zconf_lineno());
 381 };
 382
 383 comment_stmt: comment depends_list
 384 ;
 385
 386 /* help option */
 387
 388 help_start: T_HELP T_EOL
 389 {
 390         printd(DEBUG_PARSE, "%s:%d:help\n", zconf_curname(), zconf_lineno());
 391         zconf_starthelp();
 392 };
 393
 394 help: help_start T_HELPTEXT
 395 {
 396         if (current_entry->help) {
 397                 free(current_entry->help);
 398                 zconfprint("warning: '%s' defined with more than one help text -- only the last one will be used",
 399                            current_entry->sym->name ?: "<choice>");
 400         }
 401
 402         /* Is the help text empty or all whitespace? */
 403         if ($2[strspn($2, " \f\n\r\t\v")] == '\0')
 404                 zconfprint("warning: '%s' defined with blank help text",
 405                            current_entry->sym->name ?: "<choice>");
 406
 407         current_entry->help = $2;
 408 };
 409
 410 /* depends option */
 411
 412 depends_list:
 413           /* empty */
 414         | depends_list depends
 415 ;
 416
 417 depends: T_DEPENDS T_ON expr T_EOL
 418 {
 419         menu_add_dep($3);
 420         printd(DEBUG_PARSE, "%s:%d:depends on\n", zconf_curname(), zconf_lineno());
 421 };
 422
 423 /* visibility option */
 424
 425 visibility_list:
 426           /* empty */
 427         | visibility_list visible
 428 ;
 429
 430 visible: T_VISIBLE if_expr T_EOL
 431 {
 432         menu_add_visibility($2);
 433 };
 434
 435 /* prompt statement */
 436
 437 prompt_stmt_opt:
 438           /* empty */
 439         | prompt if_expr
 440 {
 441         menu_add_prompt(P_PROMPT, $1, $2);
 442 };
 443
 444 prompt:   T_WORD
 445         | T_WORD_QUOTE
 446 ;
 447
 448 end:      T_ENDMENU T_EOL       { $$ = $1; }
 449         | T_ENDCHOICE T_EOL     { $$ = $1; }
 450         | T_ENDIF T_EOL         { $$ = $1; }
 451 ;
 452
 453 if_expr:  /* empty */                   { $$ = NULL; }
 454         | T_IF expr                     { $$ = $2; }
 455 ;
 456
 457 expr:     symbol                                { $$ = expr_alloc_symbol($1); }
 458         | symbol T_LESS symbol                  { $$ = expr_alloc_comp(E_LTH, $1, $3); }
 459         | symbol T_LESS_EQUAL symbol            { $$ = expr_alloc_comp(E_LEQ, $1, $3); }
 460         | symbol T_GREATER symbol               { $$ = expr_alloc_comp(E_GTH, $1, $3); }
 461         | symbol T_GREATER_EQUAL symbol         { $$ = expr_alloc_comp(E_GEQ, $1, $3); }
 462         | symbol T_EQUAL symbol                 { $$ = expr_alloc_comp(E_EQUAL, $1, $3); }
 463         | symbol T_UNEQUAL symbol               { $$ = expr_alloc_comp(E_UNEQUAL, $1, $3); }
 464         | T_OPEN_PAREN expr T_CLOSE_PAREN       { $$ = $2; }
 465         | T_NOT expr                            { $$ = expr_alloc_one(E_NOT, $2); }
 466         | expr T_OR expr                        { $$ = expr_alloc_two(E_OR, $1, $3); }
 467         | expr T_AND expr                       { $$ = expr_alloc_two(E_AND, $1, $3); }
 468 ;
 469
 470 /* For symbol definitions, selects, etc., where quotes are not accepted */
 471 nonconst_symbol: T_WORD { $$ = sym_lookup($1, 0); free($1); };
 472
 473 symbol:   nonconst_symbol
 474         | T_WORD_QUOTE  { $$ = sym_lookup($1, SYMBOL_CONST); free($1); }
 475 ;
 476
 477 word_opt: /* empty */                   { $$ = NULL; }
 478         | T_WORD
 479
 480 /* assignment statement */
 481
 482 assignment_stmt:  T_VARIABLE T_ASSIGN assign_val T_EOL  { variable_add($1, $3, $2); free($1); free($3); }
 483
 484 assign_val:
 485         /* empty */             { $$ = xstrdup(""); };
 486         | T_ASSIGN_VAL
 487 ;
 488
 489 %%
 490
 491 void conf_parse(const char *name)
 492 {
 493         struct symbol *sym;
 494         int i;
 495
 496         zconf_initscan(name);
 497
 498         _menu_init();
 499         rootmenu.prompt = menu_add_prompt(P_MENU, "CARL9170 Firmware Configuration", NULL);
 500
 501         if (getenv("ZCONF_DEBUG"))
 502                 yydebug = 1;
 503         yyparse();
 504
 505         /* Variables are expanded in the parse phase. We can free them here. */
 506         variable_all_del();
 507
 508         if (yynerrs)
 509                 exit(1);
 510         if (!modules_sym)
 511                 modules_sym = sym_find( "n" );
 512
 513         if (!menu_has_prompt(&rootmenu)) {
 514                 current_entry = &rootmenu;
 515                 menu_add_prompt(P_MENU, "Main menu", NULL);
 516         }
 517
 518         menu_finalize(&rootmenu);
 519         for_all_symbols(i, sym) {
 520                 if (sym_check_deps(sym))
 521                         yynerrs++;
 522         }
 523         if (yynerrs)
 524                 exit(1);
 525         sym_set_change_count(1);
 526 }
 527
 528 static const char *zconf_tokenname(int token)
 529 {
 530         switch (token) {
 531         case T_MENU:            return "menu";
 532         case T_ENDMENU:         return "endmenu";
 533         case T_CHOICE:          return "choice";
 534         case T_ENDCHOICE:       return "endchoice";
 535         case T_IF:              return "if";
 536         case T_ENDIF:           return "endif";
 537         case T_DEPENDS:         return "depends";
 538         case T_VISIBLE:         return "visible";
 539         }
 540         return "<token>";
 541 }
 542
 543 static bool zconf_endtoken(const struct kconf_id *id, int starttoken, int endtoken)
 544 {
 545         if (id->token != endtoken) {
 546                 zconf_error("unexpected '%s' within %s block",
 547                         id->name, zconf_tokenname(starttoken));
 548                 yynerrs++;
 549                 return false;
 550         }
 551         if (current_menu->file != current_file) {
 552                 zconf_error("'%s' in different file than '%s'",
 553                         id->name, zconf_tokenname(starttoken));
 554                 fprintf(stderr, "%s:%d: location of the '%s'\n",
 555                         current_menu->file->name, current_menu->lineno,
 556                         zconf_tokenname(starttoken));
 557                 yynerrs++;
 558                 return false;
 559         }
 560         return true;
 561 }
 562
 563 static void zconfprint(const char *err, ...)
 564 {
 565         va_list ap;
 566
 567         fprintf(stderr, "%s:%d: ", zconf_curname(), zconf_lineno());
 568         va_start(ap, err);
 569         vfprintf(stderr, err, ap);
 570         va_end(ap);
 571         fprintf(stderr, "\n");
 572 }
 573
 574 static void zconf_error(const char *err, ...)
 575 {
 576         va_list ap;
 577
 578         yynerrs++;
 579         fprintf(stderr, "%s:%d: ", zconf_curname(), zconf_lineno());
 580         va_start(ap, err);
 581         vfprintf(stderr, err, ap);
 582         va_end(ap);
 583         fprintf(stderr, "\n");
 584 }
 585
 586 static void yyerror(const char *err)
 587 {
 588         fprintf(stderr, "%s:%d: %s\n", zconf_curname(), zconf_lineno() + 1, err);
 589 }
 590
 591 static void print_quoted_string(FILE *out, const char *str)
 592 {
 593         const char *p;
 594         int len;
 595
 596         putc('"', out);
 597         while ((p = strchr(str, '"'))) {
 598                 len = p - str;
 599                 if (len)
 600                         fprintf(out, "%.*s", len, str);
 601                 fputs("\\\"", out);
 602                 str = p + 1;
 603         }
 604         fputs(str, out);
 605         putc('"', out);
 606 }
 607
 608 static void print_symbol(FILE *out, struct menu *menu)
 609 {
 610         struct symbol *sym = menu->sym;
 611         struct property *prop;
 612
 613         if (sym_is_choice(sym))
 614                 fprintf(out, "\nchoice\n");
 615         else
 616                 fprintf(out, "\nconfig %s\n", sym->name);
 617         switch (sym->type) {
 618         case S_BOOLEAN:
 619                 fputs("  bool\n", out);
 620                 break;
 621         case S_TRISTATE:
 622                 fputs("  tristate\n", out);
 623                 break;
 624         case S_STRING:
 625                 fputs("  string\n", out);
 626                 break;
 627         case S_INT:
 628                 fputs("  integer\n", out);
 629                 break;
 630         case S_HEX:
 631                 fputs("  hex\n", out);
 632                 break;
 633         default:
 634                 fputs("  ???\n", out);
 635                 break;
 636         }
 637         for (prop = sym->prop; prop; prop = prop->next) {
 638                 if (prop->menu != menu)
 639                         continue;
 640                 switch (prop->type) {
 641                 case P_PROMPT:
 642                         fputs("  prompt ", out);
 643                         print_quoted_string(out, prop->text);
 644                         if (!expr_is_yes(prop->visible.expr)) {
 645                                 fputs(" if ", out);
 646                                 expr_fprint(prop->visible.expr, out);
 647                         }
 648                         fputc('\n', out);
 649                         break;
 650                 case P_DEFAULT:
 651                         fputs( "  default ", out);
 652                         expr_fprint(prop->expr, out);
 653                         if (!expr_is_yes(prop->visible.expr)) {
 654                                 fputs(" if ", out);
 655                                 expr_fprint(prop->visible.expr, out);
 656                         }
 657                         fputc('\n', out);
 658                         break;
 659                 case P_CHOICE:
 660                         fputs("  #choice value\n", out);
 661                         break;
 662                 case P_SELECT:
 663                         fputs( "  select ", out);
 664                         expr_fprint(prop->expr, out);
 665                         fputc('\n', out);
 666                         break;
 667                 case P_IMPLY:
 668                         fputs( "  imply ", out);
 669                         expr_fprint(prop->expr, out);
 670                         fputc('\n', out);
 671                         break;
 672                 case P_RANGE:
 673                         fputs( "  range ", out);
 674                         expr_fprint(prop->expr, out);
 675                         fputc('\n', out);
 676                         break;
 677                 case P_MENU:
 678                         fputs( "  menu ", out);
 679                         print_quoted_string(out, prop->text);
 680                         fputc('\n', out);
 681                         break;
 682                 case P_SYMBOL:
 683                         fputs( "  symbol ", out);
 684                         fprintf(out, "%s\n", prop->sym->name);
 685                         break;
 686                 default:
 687                         fprintf(out, "  unknown prop %d!\n", prop->type);
 688                         break;
 689                 }
 690         }
 691         if (menu->help) {
 692                 int len = strlen(menu->help);
 693                 while (menu->help[--len] == '\n')
 694                         menu->help[len] = 0;
 695                 fprintf(out, "  help\n%s\n", menu->help);
 696         }
 697 }
 698
 699 void zconfdump(FILE *out)
 700 {
 701         struct property *prop;
 702         struct symbol *sym;
 703         struct menu *menu;
 704
 705         menu = rootmenu.list;
 706         while (menu) {
 707                 if ((sym = menu->sym))
 708                         print_symbol(out, menu);
 709                 else if ((prop = menu->prompt)) {
 710                         switch (prop->type) {
 711                         case P_COMMENT:
 712                                 fputs("\ncomment ", out);
 713                                 print_quoted_string(out, prop->text);
 714                                 fputs("\n", out);
 715                                 break;
 716                         case P_MENU:
 717                                 fputs("\nmenu ", out);
 718                                 print_quoted_string(out, prop->text);
 719                                 fputs("\n", out);
 720                                 break;
 721                         default:
 722                                 ;
 723                         }
 724                         if (!expr_is_yes(prop->visible.expr)) {
 725                                 fputs("  depends ", out);
 726                                 expr_fprint(prop->visible.expr, out);
 727                                 fputc('\n', out);
 728                         }
 729                 }
 730
 731                 if (menu->list)
 732                         menu = menu->list;
 733                 else if (menu->next)
 734                         menu = menu->next;
 735                 else while ((menu = menu->parent)) {
 736                         if (menu->prompt && menu->prompt->type == P_MENU)
 737                                 fputs("\nendmenu\n", out);
 738                         if (menu->next) {
 739                                 menu = menu->next;
 740                                 break;
 741                         }
 742                 }
 743         }
 744 }
 745
 746 #include "zconf.lex.c"
 747 #include "util.c"
 748 #include "confdata.c"
 749 #include "expr.c"
 750 #include "symbol.c"
 751 #include "menu.c"
 752 #include "preprocess.c"