config/zconf.y

   1 %{
   2 /*
   3  * Copyright (C) 2002 Roman Zippel <zippel@linux-m68k.org>
   4  * Released under the terms of the GNU GPL v2.0.
   5  */
   6
   7 #include <ctype.h>
   8 #include <stdarg.h>
   9 #include <stdio.h>
  10 #include <stdlib.h>
  11 #include <string.h>
  12 #include <stdbool.h>
  13
  14 #include "lkc.h"
  15
  16 #define printd(mask, fmt...) if (cdebug & (mask)) printf(fmt)
  17
  18 #define PRINTD          0x0001
  19 #define DEBUG_PARSE     0x0002
  20
  21 int cdebug = PRINTD;
  22
  23 int yylex(void);
  24 static void yyerror(const char *err);
  25 static void zconfprint(const char *err, ...);
  26 static void zconf_error(const char *err, ...);
  27 static bool zconf_endtoken(const struct kconf_id *id, int starttoken, int endtoken);
  28
  29 struct symbol *symbol_hash[SYMBOL_HASHSIZE];
  30
  31 static struct menu *current_menu, *current_entry;
  32
  33 %}
  34 %expect 32
  35
  36 %union
  37 {
  38         char *string;
  39         struct file *file;
  40         struct symbol *symbol;
  41         struct expr *expr;
  42         struct menu *menu;
  43         const struct kconf_id *id;
  44 }
  45
  46 %token <id>T_MAINMENU
  47 %token <id>T_MENU
  48 %token <id>T_ENDMENU
  49 %token <id>T_SOURCE
  50 %token <id>T_CHOICE
  51 %token <id>T_ENDCHOICE
  52 %token <id>T_COMMENT
  53 %token <id>T_CONFIG
  54 %token <id>T_MENUCONFIG
  55 %token <id>T_HELP
  56 %token <string> T_HELPTEXT
  57 %token <id>T_IF
  58 %token <id>T_ENDIF
  59 %token <id>T_DEPENDS
  60 %token <id>T_OPTIONAL
  61 %token <id>T_PROMPT
  62 %token <id>T_TYPE
  63 %token <id>T_DEFAULT
  64 %token <id>T_SELECT
  65 %token <id>T_IMPLY
  66 %token <id>T_RANGE
  67 %token <id>T_VISIBLE
  68 %token <id>T_OPTION
  69 %token <id>T_ON
  70 %token <string> T_WORD
  71 %token <string> T_WORD_QUOTE
  72 %token T_UNEQUAL
  73 %token T_LESS
  74 %token T_LESS_EQUAL
  75 %token T_GREATER
  76 %token T_GREATER_EQUAL
  77 %token T_CLOSE_PAREN
  78 %token T_OPEN_PAREN
  79 %token T_EOL
  80
  81 %left T_OR
  82 %left T_AND
  83 %left T_EQUAL T_UNEQUAL
  84 %left T_LESS T_LESS_EQUAL T_GREATER T_GREATER_EQUAL
  85 %nonassoc T_NOT
  86
  87 %type <string> prompt
  88 %type <symbol> nonconst_symbol
  89 %type <symbol> symbol
  90 %type <expr> expr
  91 %type <expr> if_expr
  92 %type <id> end
  93 %type <id> option_name
  94 %type <menu> if_entry menu_entry choice_entry
  95 %type <string> symbol_option_arg word_opt
  96
  97 %destructor {
  98         fprintf(stderr, "%s:%d: missing end statement for this entry\n",
  99                 $$->file->name, $$->lineno);
 100         if (current_menu == $$)
 101                 menu_end_menu();
 102 } if_entry menu_entry choice_entry
 103
 104 %{
 105 /* Include kconf_id.c here so it can see the token constants. */
 106 #include "kconf_id.c"
 107 %}
 108
 109 %%
 110 input: nl start | start;
 111
 112 start: mainmenu_stmt stmt_list | stmt_list;
 113
 114 /* mainmenu entry */
 115
 116 mainmenu_stmt: T_MAINMENU prompt nl
 117 {
 118         menu_add_prompt(P_MENU, $2, NULL);
 119 };
 120
 121 stmt_list:
 122           /* empty */
 123         | stmt_list common_stmt
 124         | stmt_list choice_stmt
 125         | stmt_list menu_stmt
 126         | stmt_list end                 { zconf_error("unexpected end statement"); }
 127         | stmt_list T_WORD error T_EOL  { zconf_error("unknown statement \"%s\"", $2); }
 128         | stmt_list option_name error T_EOL
 129 {
 130         zconf_error("unexpected option \"%s\"", $2->name);
 131 }
 132         | stmt_list error T_EOL         { zconf_error("invalid statement"); }
 133 ;
 134
 135 option_name:
 136         T_DEPENDS | T_PROMPT | T_TYPE | T_SELECT | T_IMPLY | T_OPTIONAL | T_RANGE | T_DEFAULT | T_VISIBLE
 137 ;
 138
 139 common_stmt:
 140           T_EOL
 141         | if_stmt
 142         | comment_stmt
 143         | config_stmt
 144         | menuconfig_stmt
 145         | source_stmt
 146 ;
 147
 148 option_error:
 149           T_WORD error T_EOL            { zconf_error("unknown option \"%s\"", $1); }
 150         | error T_EOL                   { zconf_error("invalid option"); }
 151 ;
 152
 153
 154 /* config/menuconfig entry */
 155
 156 config_entry_start: T_CONFIG nonconst_symbol T_EOL
 157 {
 158         $2->flags |= SYMBOL_OPTIONAL;
 159         menu_add_entry($2);
 160         printd(DEBUG_PARSE, "%s:%d:config %s\n", zconf_curname(), zconf_lineno(), $2->name);
 161 };
 162
 163 config_stmt: config_entry_start config_option_list
 164 {
 165         printd(DEBUG_PARSE, "%s:%d:endconfig\n", zconf_curname(), zconf_lineno());
 166 };
 167
 168 menuconfig_entry_start: T_MENUCONFIG nonconst_symbol T_EOL
 169 {
 170         $2->flags |= SYMBOL_OPTIONAL;
 171         menu_add_entry($2);
 172         printd(DEBUG_PARSE, "%s:%d:menuconfig %s\n", zconf_curname(), zconf_lineno(), $2->name);
 173 };
 174
 175 menuconfig_stmt: menuconfig_entry_start config_option_list
 176 {
 177         if (current_entry->prompt)
 178                 current_entry->prompt->type = P_MENU;
 179         else
 180                 zconfprint("warning: menuconfig statement without prompt");
 181         printd(DEBUG_PARSE, "%s:%d:endconfig\n", zconf_curname(), zconf_lineno());
 182 };
 183
 184 config_option_list:
 185           /* empty */
 186         | config_option_list config_option
 187         | config_option_list symbol_option
 188         | config_option_list depends
 189         | config_option_list help
 190         | config_option_list option_error
 191         | config_option_list T_EOL
 192 ;
 193
 194 config_option: T_TYPE prompt_stmt_opt T_EOL
 195 {
 196         menu_set_type($1->stype);
 197         printd(DEBUG_PARSE, "%s:%d:type(%u)\n",
 198                 zconf_curname(), zconf_lineno(),
 199                 $1->stype);
 200 };
 201
 202 config_option: T_PROMPT prompt if_expr T_EOL
 203 {
 204         menu_add_prompt(P_PROMPT, $2, $3);
 205         printd(DEBUG_PARSE, "%s:%d:prompt\n", zconf_curname(), zconf_lineno());
 206 };
 207
 208 config_option: T_DEFAULT expr if_expr T_EOL
 209 {
 210         menu_add_expr(P_DEFAULT, $2, $3);
 211         if ($1->stype != S_UNKNOWN)
 212                 menu_set_type($1->stype);
 213         printd(DEBUG_PARSE, "%s:%d:default(%u)\n",
 214                 zconf_curname(), zconf_lineno(),
 215                 $1->stype);
 216 };
 217
 218 config_option: T_SELECT nonconst_symbol if_expr T_EOL
 219 {
 220         menu_add_symbol(P_SELECT, $2, $3);
 221         printd(DEBUG_PARSE, "%s:%d:select\n", zconf_curname(), zconf_lineno());
 222 };
 223
 224 config_option: T_IMPLY nonconst_symbol if_expr T_EOL
 225 {
 226         menu_add_symbol(P_IMPLY, $2, $3);
 227         printd(DEBUG_PARSE, "%s:%d:imply\n", zconf_curname(), zconf_lineno());
 228 };
 229
 230 config_option: T_RANGE symbol symbol if_expr T_EOL
 231 {
 232         menu_add_expr(P_RANGE, expr_alloc_comp(E_RANGE,$2, $3), $4);
 233         printd(DEBUG_PARSE, "%s:%d:range\n", zconf_curname(), zconf_lineno());
 234 };
 235
 236 symbol_option: T_OPTION symbol_option_list T_EOL
 237 ;
 238
 239 symbol_option_list:
 240           /* empty */
 241         | symbol_option_list T_WORD symbol_option_arg
 242 {
 243         const struct kconf_id *id = kconf_id_lookup($2, strlen($2));
 244         if (id && id->flags & TF_OPTION) {
 245                 menu_add_option(id->token, $3);
 246                 free($3);
 247         }
 248         else
 249                 zconfprint("warning: ignoring unknown option %s", $2);
 250         free($2);
 251 };
 252
 253 symbol_option_arg:
 254           /* empty */           { $$ = NULL; }
 255         | T_EQUAL prompt        { $$ = $2; }
 256 ;
 257
 258 /* choice entry */
 259
 260 choice: T_CHOICE word_opt T_EOL
 261 {
 262         struct symbol *sym = sym_lookup($2, SYMBOL_CHOICE);
 263         sym->flags |= SYMBOL_AUTO;
 264         menu_add_entry(sym);
 265         menu_add_expr(P_CHOICE, NULL, NULL);
 266         free($2);
 267         printd(DEBUG_PARSE, "%s:%d:choice\n", zconf_curname(), zconf_lineno());
 268 };
 269
 270 choice_entry: choice choice_option_list
 271 {
 272         $$ = menu_add_menu();
 273 };
 274
 275 choice_end: end
 276 {
 277         if (zconf_endtoken($1, T_CHOICE, T_ENDCHOICE)) {
 278                 menu_end_menu();
 279                 printd(DEBUG_PARSE, "%s:%d:endchoice\n", zconf_curname(), zconf_lineno());
 280         }
 281 };
 282
 283 choice_stmt: choice_entry choice_block choice_end
 284 ;
 285
 286 choice_option_list:
 287           /* empty */
 288         | choice_option_list choice_option
 289         | choice_option_list depends
 290         | choice_option_list help
 291         | choice_option_list T_EOL
 292         | choice_option_list option_error
 293 ;
 294
 295 choice_option: T_PROMPT prompt if_expr T_EOL
 296 {
 297         menu_add_prompt(P_PROMPT, $2, $3);
 298         printd(DEBUG_PARSE, "%s:%d:prompt\n", zconf_curname(), zconf_lineno());
 299 };
 300
 301 choice_option: T_TYPE prompt_stmt_opt T_EOL
 302 {
 303         if ($1->stype == S_BOOLEAN || $1->stype == S_TRISTATE) {
 304                 menu_set_type($1->stype);
 305                 printd(DEBUG_PARSE, "%s:%d:type(%u)\n",
 306                         zconf_curname(), zconf_lineno(),
 307                         $1->stype);
 308         } else
 309                 YYERROR;
 310 };
 311
 312 choice_option: T_OPTIONAL T_EOL
 313 {
 314         current_entry->sym->flags |= SYMBOL_OPTIONAL;
 315         printd(DEBUG_PARSE, "%s:%d:optional\n", zconf_curname(), zconf_lineno());
 316 };
 317
 318 choice_option: T_DEFAULT nonconst_symbol if_expr T_EOL
 319 {
 320         if ($1->stype == S_UNKNOWN) {
 321                 menu_add_symbol(P_DEFAULT, $2, $3);
 322                 printd(DEBUG_PARSE, "%s:%d:default\n",
 323                         zconf_curname(), zconf_lineno());
 324         } else
 325                 YYERROR;
 326 };
 327
 328 choice_block:
 329           /* empty */
 330         | choice_block common_stmt
 331 ;
 332
 333 /* if entry */
 334
 335 if_entry: T_IF expr nl
 336 {
 337         printd(DEBUG_PARSE, "%s:%d:if\n", zconf_curname(), zconf_lineno());
 338         menu_add_entry(NULL);
 339         menu_add_dep($2);
 340         $$ = menu_add_menu();
 341 };
 342
 343 if_end: end
 344 {
 345         if (zconf_endtoken($1, T_IF, T_ENDIF)) {
 346                 menu_end_menu();
 347                 printd(DEBUG_PARSE, "%s:%d:endif\n", zconf_curname(), zconf_lineno());
 348         }
 349 };
 350
 351 if_stmt: if_entry if_block if_end
 352 ;
 353
 354 if_block:
 355           /* empty */
 356         | if_block common_stmt
 357         | if_block menu_stmt
 358         | if_block choice_stmt
 359 ;
 360
 361 /* menu entry */
 362
 363 menu: T_MENU prompt T_EOL
 364 {
 365         menu_add_entry(NULL);
 366         menu_add_prompt(P_MENU, $2, NULL);
 367         printd(DEBUG_PARSE, "%s:%d:menu\n", zconf_curname(), zconf_lineno());
 368 };
 369
 370 menu_entry: menu visibility_list depends_list
 371 {
 372         $$ = menu_add_menu();
 373 };
 374
 375 menu_end: end
 376 {
 377         if (zconf_endtoken($1, T_MENU, T_ENDMENU)) {
 378                 menu_end_menu();
 379                 printd(DEBUG_PARSE, "%s:%d:endmenu\n", zconf_curname(), zconf_lineno());
 380         }
 381 };
 382
 383 menu_stmt: menu_entry menu_block menu_end
 384 ;
 385
 386 menu_block:
 387           /* empty */
 388         | menu_block common_stmt
 389         | menu_block menu_stmt
 390         | menu_block choice_stmt
 391 ;
 392
 393 source_stmt: T_SOURCE prompt T_EOL
 394 {
 395         printd(DEBUG_PARSE, "%s:%d:source %s\n", zconf_curname(), zconf_lineno(), $2);
 396         zconf_nextfile($2);
 397         free($2);
 398 };
 399
 400 /* comment entry */
 401
 402 comment: T_COMMENT prompt T_EOL
 403 {
 404         menu_add_entry(NULL);
 405         menu_add_prompt(P_COMMENT, $2, NULL);
 406         printd(DEBUG_PARSE, "%s:%d:comment\n", zconf_curname(), zconf_lineno());
 407 };
 408
 409 comment_stmt: comment depends_list
 410 ;
 411
 412 /* help option */
 413
 414 help_start: T_HELP T_EOL
 415 {
 416         printd(DEBUG_PARSE, "%s:%d:help\n", zconf_curname(), zconf_lineno());
 417         zconf_starthelp();
 418 };
 419
 420 help: help_start T_HELPTEXT
 421 {
 422         if (current_entry->help) {
 423                 free(current_entry->help);
 424                 zconfprint("warning: '%s' defined with more than one help text -- only the last one will be used",
 425                            current_entry->sym->name ?: "<choice>");
 426         }
 427
 428         /* Is the help text empty or all whitespace? */
 429         if ($2[strspn($2, " \f\n\r\t\v")] == '\0')
 430                 zconfprint("warning: '%s' defined with blank help text",
 431                            current_entry->sym->name ?: "<choice>");
 432
 433         current_entry->help = $2;
 434 };
 435
 436 /* depends option */
 437
 438 depends_list:
 439           /* empty */
 440         | depends_list depends
 441         | depends_list T_EOL
 442         | depends_list option_error
 443 ;
 444
 445 depends: T_DEPENDS T_ON expr T_EOL
 446 {
 447         menu_add_dep($3);
 448         printd(DEBUG_PARSE, "%s:%d:depends on\n", zconf_curname(), zconf_lineno());
 449 };
 450
 451 /* visibility option */
 452
 453 visibility_list:
 454           /* empty */
 455         | visibility_list visible
 456         | visibility_list T_EOL
 457 ;
 458
 459 visible: T_VISIBLE if_expr
 460 {
 461         menu_add_visibility($2);
 462 };
 463
 464 /* prompt statement */
 465
 466 prompt_stmt_opt:
 467           /* empty */
 468         | prompt if_expr
 469 {
 470         menu_add_prompt(P_PROMPT, $1, $2);
 471 };
 472
 473 prompt:   T_WORD
 474         | T_WORD_QUOTE
 475 ;
 476
 477 end:      T_ENDMENU T_EOL       { $$ = $1; }
 478         | T_ENDCHOICE T_EOL     { $$ = $1; }
 479         | T_ENDIF T_EOL         { $$ = $1; }
 480 ;
 481
 482 nl:
 483           T_EOL
 484         | nl T_EOL
 485 ;
 486
 487 if_expr:  /* empty */                   { $$ = NULL; }
 488         | T_IF expr                     { $$ = $2; }
 489 ;
 490
 491 expr:     symbol                                { $$ = expr_alloc_symbol($1); }
 492         | symbol T_LESS symbol                  { $$ = expr_alloc_comp(E_LTH, $1, $3); }
 493         | symbol T_LESS_EQUAL symbol            { $$ = expr_alloc_comp(E_LEQ, $1, $3); }
 494         | symbol T_GREATER symbol               { $$ = expr_alloc_comp(E_GTH, $1, $3); }
 495         | symbol T_GREATER_EQUAL symbol         { $$ = expr_alloc_comp(E_GEQ, $1, $3); }
 496         | symbol T_EQUAL symbol                 { $$ = expr_alloc_comp(E_EQUAL, $1, $3); }
 497         | symbol T_UNEQUAL symbol               { $$ = expr_alloc_comp(E_UNEQUAL, $1, $3); }
 498         | T_OPEN_PAREN expr T_CLOSE_PAREN       { $$ = $2; }
 499         | T_NOT expr                            { $$ = expr_alloc_one(E_NOT, $2); }
 500         | expr T_OR expr                        { $$ = expr_alloc_two(E_OR, $1, $3); }
 501         | expr T_AND expr                       { $$ = expr_alloc_two(E_AND, $1, $3); }
 502 ;
 503
 504 /* For symbol definitions, selects, etc., where quotes are not accepted */
 505 nonconst_symbol: T_WORD { $$ = sym_lookup($1, 0); free($1); };
 506
 507 symbol:   nonconst_symbol
 508         | T_WORD_QUOTE  { $$ = sym_lookup($1, SYMBOL_CONST); free($1); }
 509 ;
 510
 511 word_opt: /* empty */                   { $$ = NULL; }
 512         | T_WORD
 513
 514 %%
 515
 516 void conf_parse(const char *name)
 517 {
 518         struct symbol *sym;
 519         int i;
 520
 521         zconf_initscan(name);
 522
 523         _menu_init();
 524         rootmenu.prompt = menu_add_prompt(P_MENU, "CARL9170 Firmware Configuration", NULL);
 525
 526         if (getenv("ZCONF_DEBUG"))
 527                 yydebug = 1;
 528         yyparse();
 529         if (yynerrs)
 530                 exit(1);
 531         if (!modules_sym)
 532                 modules_sym = sym_find( "n" );
 533
 534         if (!menu_has_prompt(&rootmenu)) {
 535                 current_entry = &rootmenu;
 536                 menu_add_prompt(P_MENU, "Linux Kernel Configuration", NULL);
 537         }
 538
 539         menu_finalize(&rootmenu);
 540         for_all_symbols(i, sym) {
 541                 if (sym_check_deps(sym))
 542                         yynerrs++;
 543         }
 544         if (yynerrs)
 545                 exit(1);
 546         sym_set_change_count(1);
 547 }
 548
 549 static const char *zconf_tokenname(int token)
 550 {
 551         switch (token) {
 552         case T_MENU:            return "menu";
 553         case T_ENDMENU:         return "endmenu";
 554         case T_CHOICE:          return "choice";
 555         case T_ENDCHOICE:       return "endchoice";
 556         case T_IF:              return "if";
 557         case T_ENDIF:           return "endif";
 558         case T_DEPENDS:         return "depends";
 559         case T_VISIBLE:         return "visible";
 560         }
 561         return "<token>";
 562 }
 563
 564 static bool zconf_endtoken(const struct kconf_id *id, int starttoken, int endtoken)
 565 {
 566         if (id->token != endtoken) {
 567                 zconf_error("unexpected '%s' within %s block",
 568                         id->name, zconf_tokenname(starttoken));
 569                 yynerrs++;
 570                 return false;
 571         }
 572         if (current_menu->file != current_file) {
 573                 zconf_error("'%s' in different file than '%s'",
 574                         id->name, zconf_tokenname(starttoken));
 575                 fprintf(stderr, "%s:%d: location of the '%s'\n",
 576                         current_menu->file->name, current_menu->lineno,
 577                         zconf_tokenname(starttoken));
 578                 yynerrs++;
 579                 return false;
 580         }
 581         return true;
 582 }
 583
 584 static void zconfprint(const char *err, ...)
 585 {
 586         va_list ap;
 587
 588         fprintf(stderr, "%s:%d: ", zconf_curname(), zconf_lineno());
 589         va_start(ap, err);
 590         vfprintf(stderr, err, ap);
 591         va_end(ap);
 592         fprintf(stderr, "\n");
 593 }
 594
 595 static void zconf_error(const char *err, ...)
 596 {
 597         va_list ap;
 598
 599         yynerrs++;
 600         fprintf(stderr, "%s:%d: ", zconf_curname(), zconf_lineno());
 601         va_start(ap, err);
 602         vfprintf(stderr, err, ap);
 603         va_end(ap);
 604         fprintf(stderr, "\n");
 605 }
 606
 607 static void yyerror(const char *err)
 608 {
 609         fprintf(stderr, "%s:%d: %s\n", zconf_curname(), zconf_lineno() + 1, err);
 610 }
 611
 612 static void print_quoted_string(FILE *out, const char *str)
 613 {
 614         const char *p;
 615         int len;
 616
 617         putc('"', out);
 618         while ((p = strchr(str, '"'))) {
 619                 len = p - str;
 620                 if (len)
 621                         fprintf(out, "%.*s", len, str);
 622                 fputs("\\\"", out);
 623                 str = p + 1;
 624         }
 625         fputs(str, out);
 626         putc('"', out);
 627 }
 628
 629 static void print_symbol(FILE *out, struct menu *menu)
 630 {
 631         struct symbol *sym = menu->sym;
 632         struct property *prop;
 633
 634         if (sym_is_choice(sym))
 635                 fprintf(out, "\nchoice\n");
 636         else
 637                 fprintf(out, "\nconfig %s\n", sym->name);
 638         switch (sym->type) {
 639         case S_BOOLEAN:
 640                 fputs("  bool\n", out);
 641                 break;
 642         case S_TRISTATE:
 643                 fputs("  tristate\n", out);
 644                 break;
 645         case S_STRING:
 646                 fputs("  string\n", out);
 647                 break;
 648         case S_INT:
 649                 fputs("  integer\n", out);
 650                 break;
 651         case S_HEX:
 652                 fputs("  hex\n", out);
 653                 break;
 654         default:
 655                 fputs("  ???\n", out);
 656                 break;
 657         }
 658         for (prop = sym->prop; prop; prop = prop->next) {
 659                 if (prop->menu != menu)
 660                         continue;
 661                 switch (prop->type) {
 662                 case P_PROMPT:
 663                         fputs("  prompt ", out);
 664                         print_quoted_string(out, prop->text);
 665                         if (!expr_is_yes(prop->visible.expr)) {
 666                                 fputs(" if ", out);
 667                                 expr_fprint(prop->visible.expr, out);
 668                         }
 669                         fputc('\n', out);
 670                         break;
 671                 case P_DEFAULT:
 672                         fputs( "  default ", out);
 673                         expr_fprint(prop->expr, out);
 674                         if (!expr_is_yes(prop->visible.expr)) {
 675                                 fputs(" if ", out);
 676                                 expr_fprint(prop->visible.expr, out);
 677                         }
 678                         fputc('\n', out);
 679                         break;
 680                 case P_CHOICE:
 681                         fputs("  #choice value\n", out);
 682                         break;
 683                 case P_SELECT:
 684                         fputs( "  select ", out);
 685                         expr_fprint(prop->expr, out);
 686                         fputc('\n', out);
 687                         break;
 688                 case P_IMPLY:
 689                         fputs( "  imply ", out);
 690                         expr_fprint(prop->expr, out);
 691                         fputc('\n', out);
 692                         break;
 693                 case P_RANGE:
 694                         fputs( "  range ", out);
 695                         expr_fprint(prop->expr, out);
 696                         fputc('\n', out);
 697                         break;
 698                 case P_MENU:
 699                         fputs( "  menu ", out);
 700                         print_quoted_string(out, prop->text);
 701                         fputc('\n', out);
 702                         break;
 703                 default:
 704                         fprintf(out, "  unknown prop %d!\n", prop->type);
 705                         break;
 706                 }
 707         }
 708         if (menu->help) {
 709                 int len = strlen(menu->help);
 710                 while (menu->help[--len] == '\n')
 711                         menu->help[len] = 0;
 712                 fprintf(out, "  help\n%s\n", menu->help);
 713         }
 714 }
 715
 716 void zconfdump(FILE *out)
 717 {
 718         struct property *prop;
 719         struct symbol *sym;
 720         struct menu *menu;
 721
 722         menu = rootmenu.list;
 723         while (menu) {
 724                 if ((sym = menu->sym))
 725                         print_symbol(out, menu);
 726                 else if ((prop = menu->prompt)) {
 727                         switch (prop->type) {
 728                         case P_COMMENT:
 729                                 fputs("\ncomment ", out);
 730                                 print_quoted_string(out, prop->text);
 731                                 fputs("\n", out);
 732                                 break;
 733                         case P_MENU:
 734                                 fputs("\nmenu ", out);
 735                                 print_quoted_string(out, prop->text);
 736                                 fputs("\n", out);
 737                                 break;
 738                         default:
 739                                 ;
 740                         }
 741                         if (!expr_is_yes(prop->visible.expr)) {
 742                                 fputs("  depends ", out);
 743                                 expr_fprint(prop->visible.expr, out);
 744                                 fputc('\n', out);
 745                         }
 746                 }
 747
 748                 if (menu->list)
 749                         menu = menu->list;
 750                 else if (menu->next)
 751                         menu = menu->next;
 752                 else while ((menu = menu->parent)) {
 753                         if (menu->prompt && menu->prompt->type == P_MENU)
 754                                 fputs("\nendmenu\n", out);
 755                         if (menu->next) {
 756                                 menu = menu->next;
 757                                 break;
 758                         }
 759                 }
 760         }
 761 }
 762
 763 #include "zconf.lex.c"
 764 #include "util.c"
 765 #include "confdata.c"
 766 #include "expr.c"
 767 #include "symbol.c"
 768 #include "menu.c"
 769 #include "preprocess.c"